web-dev-qa-db-ja.com

Terraformを使用してAWSでネットワークロードバランサー（NLB）でAutoScalingグループを作成する際の問題

Terraform v0.11.0を使用してNLBを作成しようとしています（私のアプリケーションはHTTPを使用していないため、ALBを使用できません）。 Hashcorpのドキュメントを見ると、次のコードを作成できます。

resource "aws_lb" "lb" {
  name = "test"
  internal = false
  enable_deletion_protection = true
  load_balancer_type = "network"
  ip_address_type = "ipv4"
  subnet_mapping {
    subnet_id = "${data.aws_subnet.sn-app-1.id}"
    allocation_id = "${aws_eip.eip-1.id}"
  }
  subnet_mapping {
    subnet_id = "${data.aws_subnet.sn-app-2.id}"
    allocation_id = "${aws_eip.eip-2.id}"
  }
}

resource "aws_lb_target_group" "lbtg" {
  name     = "test"
  port     = "8080"
  protocol = "TCP"
  vpc_id   = "${data.aws_vpc.vpc.id}"
  deregistration_delay = "300"
  health_check {
    interval = "300"
    port = "8080"
    protocol = "TCP"
    timeout = "10"
    healthy_threshold = "10" 
    unhealthy_threshold= "10" 
  }
}

resource "aws_lb_listener" "front_end" {
  load_balancer_arn = "${aws_lb.lb.arn}"
  port              = "8080"
  protocol          = "TCP"
  default_action {
    target_group_arn = "${aws_lb_target_group.lbtg.arn}"
    type             = "forward"
  }
}

resource "aws_autoscaling_group" "asg" {
  name  = "test"
  vpc_zone_identifier = ["${data.aws_subnet.sn-app-1.id}","${data.aws_subnet.sn-app-2.id}"]
  min_size  = 1
  desired_capacity  = 1
  max_size  = 3
  launch_configuration = "${aws_launch_configuration.lc.name}"
  load_balancers  = ["${aws_lb.lb.name}"]
  default_cooldown= 180
  health_check_grace_period = 180
  termination_policies = ["ClosestToNextInstanceHour", "NewestInstance"]
}

走る terraform initおよびterraform plan -out=plan.jsonとすべてがうまくいきますが、実行後terraform apply plan.json、TerraformはAutoScalingグループの作成に少し時間を費やし、次のようなものをスローします。

aws_ecs_service.ecss：1エラーが発生しました：

  • aws_ecs_service.ecss：InvalidParameterException：targetGroupArnのターゲットグループ：arn：aws：elasticloadbalancing：us-east-1：xxxxxx：targetgroup/test/xxxxxxには、関連付けられたロードバランサーがありません。ステータスコード：400、リクエストID：b2565334-da9a-11e7-ab5a-8f0bfc9ecd99 "test"

  • aws_autoscaling_group.asg：1エラーが発生しました：

  • aws_autoscaling_group.asg：AutoScalingグループの作成中にエラーが発生しました：ValidationError：指定されたロードバランサーが有効でない可能性があります。それらが存在することを確認して、再試行してください。ステータスコード：400、リクエストID：cf2d4ac6-da9a-11e7-950f-050f1f0711f8

ターゲットグループをLBに関連付けるにはどうすればよいですか？また、提供されたロードバランサーがAutoScalingグループに対して有効でない場合があるのはなぜですか？

amazon-web-servicesload-balancingterraform
3
Tales Morais

ASGでtarget_group_arnsオプションを使用してみてください。

resource "aws_autoscaling_group" "asg" {
    name  = "test"
    vpc_zone_identifier = ["${data.aws_subnet.sn-app-1.id}","${data.aws_subnet.sn-app-2.id}"]
    min_size  = 1
    desired_capacity  = 1
    max_size  = 3
    launch_configuration = "${aws_launch_configuration.lc.name}"
    target_group_arns = ["${aws_lb_target_group.lbtg.arn}"]
    default_cooldown= 180
    health_check_grace_period = 180
    termination_policies = ["ClosestToNextInstanceHour", "NewestInstance"]
}
5
Matt Cooper