web-dev-qa-db-ja.com

ARMで整数（符号付きまたは符号なし）除算を行う方法を教えてください。

特にCortex-A8とCortex-A9に取り組んでいます。一部のアーキテクチャには整数除算が付属していないことを知っていますが、浮動小数点数に変換、除算、整数に変換する以外にそれを行うための最良の方法は何ですか？それとも、それは本当に最良の解決策ですか？

乾杯！ =）

assemblyarminteger-divisioninstruction-setcortex-a8
17
Phonon

コンパイラーは通常、ライブラリーに除算を含めます。たとえば、gcclibをgccから抽出して直接使用します。

https://github.com/dwelch67/stm32vld/ 次にstm32f4d/adventure/gcclib

フロートして戻ることはおそらく最良の解決策ではありません。あなたはそれを試して、それがどれくらい速いかを見ることができます...これは乗算ですが、それを簡単に分割することができます：

https://github.com/dwelch67/stm32vld/ 次にstm32f4d/float01/vectors.s

私はそれがどれほど速いか遅いかを見るためにそれを計時しなかった。私は上記のcortex-mを使用していることを理解し、あなたはcortex-a、スペクトルの異なる端、同様のfloat命令、およびgcc libものについて話しているので、cortex-mは親指用に構築する必要がありますが、あなたはできます腕のために構築するのと同じくらい簡単です。実際にはgccを使用すれば、すべてが自動的に機能するはずです。私が行った方法で行う必要はありません。他のコンパイラーも、上記のアドベンチャーゲームで行った方法で行う必要はありません。

4
old_timer

定数値による除算は、たとえば次のように64ビットの乗算と右シフトを行うことですばやく実行できます。

LDR     R3, =0xA151C331
UMULL   R3, R2, R1, R3
MOV     R0, R2,LSR#10

ここで、R1は1625で除算されます。計算は次のように行われます：64bitreg（R2：R3）= R1 * 0xA151C331、その結果、上位32ビットが右に10シフトされます。

R1*0xA151C331/2^(32+10) = R1*0.00061538461545751488 = R1/1624.99999980

この式から独自の定数を計算できます。

x / N ==  (x*A)/2^(32+n)   -->       A = 2^(32+n)/N

a <2 ^ 32である最大のnを選択する

10
Willem Hengeveld

整数除算のための他の場所からのコピーパスタ：基本的に、ビットごとに3つの命令。 this ウェブサイトから。他にもたくさんの場所を見てきました。 This サイトには、一般的に高速である可能性があるNiceバージョンもあります。


@ Entry  r0: numerator (lo) must be signed positive
@        r2: deniminator (den) must be non-zero and signed negative
idiv:
        lo .req r0; hi .req r1; den .req r2
        mov hi, #0 @ hi = 0
        adds lo, lo, lo
        .rept 32 @ repeat 32 times
          adcs hi, den, hi, lsl #1
          subcc hi, hi, den
          adcs lo, lo, lo
        .endr
        mov pc, lr @ return
@ Exit   r0: quotient (lo)
@        r1: remainder (hi)
7
Michael Dorgan

署名のないバージョンをWeb上で見つけることができなかったため、署名のない除算を実行するための独自のルーチンを作成しました。 32ビットの結果を得るために、64ビット値を32ビット値で除算する必要がありました。

内側のループは、上記の符号付きソリューションほど効率的ではありませんが、これは符号なし演算をサポートしています。このルーチンは、分子の上位部分（hi）が分母（den）より小さい場合は32ビット除算を実行し、そうでない場合は完全な64ビット除算を実行します（hi：lo/den）。結果はloです。

  cmp     hi, den                   // if hi < den do 32 bits, else 64 bits
  bpl     do64bits
  REPT    32
    adds    lo, lo, lo              // shift numerator through carry
    adcs    hi, hi, hi
    subscc  work, hi, den           // if carry not set, compare        
    subcs   hi, hi, den             // if carry set, subtract
    addcs   lo, lo, #1              // if carry set, and 1 to quotient
  ENDR

  mov     r0, lo                    // move result into R0
  mov     pc, lr                    // return

do64bits:
  mov     top, #0
  REPT    64
    adds    lo, lo, lo              // shift numerator through carry
    adcs    hi, hi, hi
    adcs    top, top, top
    subscc  work, top, den          // if carry not set, compare        
    subcs   top, top, den           // if carry set, subtract
    addcs   lo, lo, #1              // if carry set, and 1 to quotient
  ENDR
  mov     r0, lo                    // move result into R0
  mov     pc, lr                    // return

境界条件と2のべき乗の追加チェックを追加できます。詳細は http://www.idwiz.co.za/Tips%20and%20Tricks/Divide.htm にあります。

2
selwyn

ARM GNUアセンブラー用に以下の関数を作成しました。 udiv/sdivマシンをサポートするCPUがない場合は、どちらの関数でも「0：」ラベルまでの最初の数行を切り取ってください。

.arm
.cpu    cortex-a7
.syntax unified

.type   udiv,%function
.globl  udiv
udiv:   tst     r1,r1
        bne     0f
        udiv    r3,r0,r2
        mls     r1,r2,r3,r0
        mov     r0,r3
        bx      lr
0:      cmp     r1,r2
        movhs   r1,r2
        bxhs    lr
        mvn     r3,0
1:      adds    r0,r0
        adcs    r1,r1
        cmpcc   r1,r2
        subcs   r1,r2
        orrcs   r0,1
        lsls    r3,1
        bne     1b
        bx      lr
.size   udiv,.-udiv

.type   sdiv,%function
.globl  sdiv
sdiv:   teq     r1,r0,ASR 31
        bne     0f
        sdiv    r3,r0,r2
        mls     r1,r2,r3,r0
        mov     r0,r3
        bx      lr
0:      mov     r3,2
        adds    r0,r0
        and     r3,r3,r1,LSR 30
        adcs    r1,r1
        orr     r3,r3,r2,LSR 31
        movvs   r1,r2
        ldrvc   pc,[pc,r3,LSL 2]
        bx      lr
        .int    1f
        .int    3f
        .int    5f
        .int    11f
1:      cmp     r1,r2
        movge   r1,r2
        bxge    lr
        mvn     r3,1
2:      adds    r0,r0
        adcs    r1,r1
        cmpvc   r1,r2
        subge   r1,r2
        orrge   r0,1
        lsls    r3,1
        bne     2b
        bx      lr
3:      cmn     r1,r2
        movge   r1,r2
        bxge    lr
        mvn     r3,1
4:      adds    r0,r0
        adcs    r1,r1
        cmnvc   r1,r2
        addge   r1,r2
        orrge   r0,1
        lsls    r3,1
        bne     4b
        rsb     r0,0
        bx      lr
5:      cmn     r1,r2
        blt     6f
        tsteq   r0,r0
        bne     7f
6:      mov     r1,r2
        bx      lr
7:      mvn     r3,1
8:      adds    r0,r0
        adcs    r1,r1
        cmnvc   r1,r2
        blt     9f
        tsteq   r0,r3
        bne     10f
9:      add     r1,r2
        orr     r0,1
10:     lsls    r3,1
        bne     8b
        rsb     r0,0
        bx      lr
11:     cmp     r1,r2
        blt     12f
        tsteq   r0,r0
        bne     13f
12:     mov     r1,r2
        bx      lr
13:     mvn     r3,1
14:     adds    r0,r0
        adcs    r1,r1
        cmpvc   r1,r2
        blt     15f
        tsteq   r0,r3
        bne     16f
15:     sub     r1,r2
        orr     r0,1
16:     lsls    r3,1
        bne     14b
        bx      lr

符号なし整数除算用のudivと符号付き整数除算用のsdivの2つの関数があります。どちらも、r1（上位ワード）およびr0（下位ワード）の64ビットの被除数（符号付きまたは符号なし）、およびr2の32ビット除数を期待しています。それらは商をr0で返し、残りをr1で返すため、C headerでexternとして定義し、64ビット整数を返し、商をマスクすることができます。そして残りはその後。エラー（0による除算またはオーバーフロー）は、除数の絶対値以上の絶対値を持つ剰余によって示されます。符号付き除算アルゴリズムは、被除数と除数の両方の符号による大文字小文字の区別を使用します。最初は正の整数に変換されません。すべてのオーバーフロー状態を適切に検出できないためです。

1
user371416