web-dev-qa-db-ja.com

最高のAutoHotKeyマクロ？

AutoHotKey forWindowsマクロを使用しています。最も一般的には、特定のアプリを起動/フォーカスするホットキーを定義するために使用し、ToDoリストにインスタントメールメッセージを送信するために使用します。また、メモリを大量に消費する大きなアプリ（Outlook、Firefoxなど）をすべて強制終了する緊急アプリもあります。

それで、誰かが共有するのに良いAHKマクロを持っていますか？

automationmacros
22
leeborkman

非常にシンプルで便利なスニペット：

SetTitleMatchMode RegEx ;
; Stuff to do when Windows Explorer is open
;
#IfWinActive ahk_class ExploreWClass|CabinetWClass
    ; create new folder
    ;
    ^!n::Send !fwf

    ; create new text file
    ;
    ^!t::Send !fwt

    ; open 'cmd' in the current directory
    ;
    ^!c::
        OpenCmdInCurrent()
    return
#IfWinActive

; Opens the command Shell 'cmd' in the directory browsed in Explorer.
; Note: expecting to be run when the active window is Explorer.
;
OpenCmdInCurrent()
{
    WinGetText, full_path, A  ; This is required to get the full path of the file from the address bar

    ; Split on newline (`n)
    StringSplit, Word_array, full_path, `n
    full_path = %Word_array1%   ; Take the first element from the array

    ; Just in case - remove all carriage returns (`r)
    StringReplace, full_path, full_path, `r, , all  
    full_path := RegExReplace(full_path, "^Address: ", "") ;

    IfInString full_path, \
    {
        Run, cmd /K cd /D "%full_path%"
    }
    else
    {
        Run, cmd /K cd /D "C:\ "
    }
}
14
Eli Bendersky

これはとてもシンプルですが便利なスクリプトです：

^SPACE::  Winset, Alwaysontop, , A

Ctrl +スペースを使用して、ウィンドウを常に一番上に設定します。

9
EvanBlack

選択したテキスト/単語に周囲の引用符を追加します
メールを書くときやコーディング中に便利です...

Wordをダブルクリックし、Win + Xを押して、引用符を付けます

; Win + X
#x:: ; Attention:  Strips formatting from the clipboard too!
Send ^c
clipboard = "%clipboard%"
; Remove space introduced by Word
StringReplace, clipboard, clipboard,%A_SPACE%",", All
Send ^v
return
9
Peter Gfader

;コンピュータを再起動した後にヘッドホンを装着したときに耳を傷つけないように、これをスタートメニューに入れています

sleep, 5000
SoundSet, 1.5 ; really low volume
6
Bård

AutoHotKeyで新しいOutlookオブジェクトを作成します

; Win + Shift + M =新着メール

#+m::  Run "mailto:"

;見通し

#^M::  Run "%ProgramFiles%\Microsoft Office\Office12\Outlook.EXE" /recycle

; Win + Shift + A =新しいカレンダーの予定を作成する

#+A::  Run "%ProgramFiles%\Microsoft Office\Office12\Outlook.EXE"/c ipm.appointment

; Win + Shift + T =新しいタスクを作成します; Win + Shift + K =新しいタスク

#+T::  Run "%ProgramFiles%\Microsoft Office\Office12\Outlook.EXE"/c ipm.task
#+K::  Run "%ProgramFiles%\Microsoft Office\Office12\Outlook.EXE"/c ipm.task
4
Peter Gfader

これは、マウスボタンを使用して現在のウィンドウをすばやく閉じるための非常に単純なスニペットです。

これは、Windowsで最も頻繁に実行するアクションの1つであり、その小さなXを撮影する必要がなくなるため、どれだけの時間を節約できるかに驚かれることでしょう。5ボタンのマウスを使用すると、これは非常に便利な再割り当てになります。 「進む」ボタン。

#IfWinActive  ;Close active window when mouse button 5 is pressed
  XButton2::
    SendInput {Alt Down}{F4}{Alt Up}
    Return
#IfWinActive

タブ付きドキュメント（Webブラウザなど）を使用するプログラムを考慮に入れるために、より包括的なバージョンを次に示します。

;-----------------------------------------------------------------------------
; Bind Mouse Button 5 to Close Tab / Close Window command
;-----------------------------------------------------------------------------

; Create a group to hold windows which will use Ctrl+F4 instead of Alt+F4
GroupAdd, CtrlCloseGroup, ahk_class IEFrame             ; Internet Explorer
GroupAdd, CtrlCloseGroup, ahk_class Chrome_WidgetWin_0  ; Google Chrome
; (Add more programs that use tabbed documents here)
Return

; For windows in above group, bind mouse button to Ctrl+F4
#IfWinActive, ahk_group CtrlCloseGroup
  XButton2::
    SendInput {Ctrl Down}{F4}{Ctrl Up}
    Return
#IfWinActive  

; For everything else, bind mouse button to Alt+F4
#IfWinActive
  XButton2::
    SendInput {Alt Down}{F4}{Alt Up}
    Return
#IfWinActive  

; In FireFox, bind to Ctrl+W instead, so that the close command also works
; on the Downloads window.
#IfWinActive, ahk_class MozillaUIWindowClass
  XButton2::
    SendInput {Ctrl Down}w{Ctrl Up}
    Return
#IfWinActive

Visual Studio 2010は、ウィンドウクラス/タイトルを簡単に予測できないため、上記のCtrlCloseGroupに簡単に追加することはできません（私は思います）。これは、私がそれを処理するために使用するスニペットであり、いくつかの追加の役立つバインディングが含まれています。

SetTitleMatchMode, 2  ; Move this line to the top of your script

;-----------------------------------------------------------------------------
; Visual Studio 2010
;-----------------------------------------------------------------------------

#IfWinActive, Microsoft Visual Studio

  ; Make the middle mouse button jump to the definition of any token
  MButton::
    Click Left  ; put the cursor where you clicked
    Send {Shift Down}{F2}{Shift Up}
    Return

  ; Make the Back button on the mouse jump you back to the previous area
  ; of code you were working on.
  XButton1::
    Send {Ctrl Down}{Shift Down}{F2}{Shift Up}{Ctrl Up}
    Return

  ; Bind the Forward button to close the current tab
  XButton2::
    SendInput {Ctrl Down}{F4}{Ctrl Up}
    Return

#IfWinActive

また、Outlookで、ALT + 1、ALT + 2などを、現在選択されているメッセージを特定のフォルダー（「個人用ファイル」、「作業用ファイル」など）に移動する自分で作成したマクロにマップすると便利です。しかし、それはもう少し複雑です。

3
rkagerer

私はいつもこれを使用していますが、通常はMySQLコマンドラインにすばやくアクセスするためです。

http://lifehacker.com/software/featured-windows-download/make-a-quake+style-command-Prompt-with-autohotkey-297607.php

2
Feet

[ファイル置換の確認]ダイアログの上に[コピー]ダイアログが表示されたときにFTPサーバーにファイルをコピーするときの問題を修正します（非常に煩わしい）。

SetTimer, FocusOnWindow, 500
return

FocusOnWindow:
IfWinExist, Confirm File Replace
    WinActivate
return

役に立たないCapsLockキーを無効にするための1つ：

Capslock::
return

CTRL + shift + cは、カーソルの下の色をクリップボードにコピーします（16進数）

^+c::
MouseGetPos,x,y
PixelGetColor,rgb,x,y,RGB
StringTrimLeft,rgb,rgb,2
Clipboard=%rgb%
Return

アクティブなフィールドにメールアドレスを入力します（Winキー+ m）

#m::
Send, [email protected]{LWINUP}
Sleep, 100
Send, {TAB}
return
2
Johann

AutoHotKeyフォーラムにはたくさんの良いものがあります：

http://www.autohotkey.com/forum/forum-2.html&sid=8149586e9d533532ea76e71e8c9e5b7b

どのように良いです？本当にあなたが望む/必要とするものに依存します。

2
scunliffe