MSバッチファイルを使用してプログラムの出力を変数に割り当てている
MSバッチファイルを使用してプログラムの出力を変数に割り当てる必要があります。
それでGNU Bashシェルで私はVAR=$(application arg0 arg1)を使います。 Windowsでもバッチファイルを使用して同様の動作が必要です。
set VAR=application arg0 arg1のようなもの。
一つの方法は：
application arg0 arg1 > temp.txt
set /p VAR=<temp.txt
もう一つは：
for /f %%i in ('application arg0 arg1') do set VAR=%%i
%の最初の%%iは、その後の%をエスケープするために使用され、コマンドラインではなくバッチファイルで上記のコードを使用するときに必要です。想像してみてください、あなたのtest.batは次のようなものを持っています：
for /f %%i in ('c:\cygwin64\bin\date.exe +"%%Y%%m%%d%%H%%M%%S"') do set datetime=%%i
echo %datetime%
この前の回答 に加えて、キャレット記号でエスケープしたパイプをforステートメントの中で使用することができます。
for /f "tokens=*" %%i in ('tasklist ^| grep "Explorer"') do set VAR=%%i
@OP、 ループ用 を使用して、プログラムが数値以外の何かを出力する場合は、その戻り状況をキャプチャーすることができます。
アプリケーションの出力が数値のリターンコードであると仮定すると、次のことができます。
application arg0 arg1
set VAR=%errorlevel%
実行中：for /f %%i in ('application arg0 arg1') do set VAR=%%i私はエラーを得ていました：%%私は現時点では予想外でした。修正として、私はfor /f %i in ('application arg0 arg1') do set VAR=%iとして上で実行しなければなりませんでした
答えに加えて、forループのset部分で出力リダイレクト演算子を直接使用することはできません（例えば、stderror出力をユーザーとより良いエラーメッセージを提供します。代わりに、キャレット文字（^）でそれらをエスケープする必要があります。
for /f %%O in ('some-erroring-command 2^> nul') do (echo %%O)
@echo off
SETLOCAL ENABLEDELAYEDEXPANSION
REM Prefer backtick usage for command output reading:
REM ENABLEDELAYEDEXPANSION is required for actualized
REM outer variables within for's scope;
REM within for's scope, access to modified
REM outer variable is done via !...! syntax.
SET CHP=C:\Windows\System32\chcp.com
FOR /F "usebackq tokens=1,2,3" %%i IN (`%CHP%`) DO (
IF "%%i" == "Aktive" IF "%%j" == "Codepage:" (
SET SELCP=%%k
SET SELCP=!SELCP:~0,-1!
)
)
echo actual codepage [%SELCP%]
ENDLOCAL
あなたは、bashシェルの振る舞いに少し似ている、コマンド出力の単純なキャプチャーのためにバッチマクロを使うことができます。
マクロの使い方は簡単で、次のようになります。
%$set% VAR=application arg1 arg2
そしてそれはパイプでも動作します
%$set% allDrives="wmic logicaldisk get name /value | findstr "Name""
このマクロは配列のように変数を使用し、各行を別々のインデックスに格納します。%$set% allDrives="wmic logicaldiskのサンプルでは、以下の変数が作成されます。
allDrives.Len=5
allDrives.Max=4
allDrives[0]=Name=C:
allDrives[1]=Name=D:
allDrives[2]=Name=F:
allDrives[3]=Name=G:
allDrives[4]=Name=Z:
allDrives=<contains the complete text with line feeds>
それを使用するためには、マクロ自体がどのように機能するかを理解することは重要ではありません。
完全な例
@echo off
setlocal
call :initMacro
%$set% ipOutput="ipconfig"
call :ShowVariable ipOutput
echo First line is %ipOutput[0]%
echo(
%$set% driveNames="wmic logicaldisk get name /value | findstr "Name""
call :ShowVariable driveNames
exit /b
:ShowVariable
setlocal EnableDelayedExpansion
for /L %%n in (0 1 !%~1.max!) do (
echo %%n: !%~1[%%n]!
)
echo(
exit /b
:initMacro
if "!!"=="" (
echo ERROR: Delayed Expansion must be disabled while defining macros
(goto) 2>nul
(goto) 2>nul
)
(set LF=^
%=empty=%
)
(set \n=^^^
%=empty=%
)
set $set=FOR /L %%N in (1 1 2) dO IF %%N==2 ( %\n%
setlocal EnableDelayedExpansion %\n%
for /f "tokens=1,* delims== " %%1 in ("!argv!") do ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1.Len=0" %\n%
set "%%~1=" %\n%
if "!!"=="" ( %\n%
%= Used if delayed expansion is enabled =% %\n%
setlocal DisableDelayedExpansion %\n%
for /F "delims=" %%O in ('"%%~2 | findstr /N ^^"') do ( %\n%
if "!!" NEQ "" ( %\n%
endlocal %\n%
) %\n%
setlocal DisableDelayedExpansion %\n%
set "line=%%O" %\n%
setlocal EnableDelayedExpansion %\n%
set pathExt=: %\n%
set path=; %\n%
set "line=!line:^=^^!" %\n%
set "line=!line:"=q"^""!" %\n%
call set "line=%%line:^!=q""^!%%" %\n%
set "line=!line:q""=^!" %\n%
set "line="!line:*:=!"" %\n%
for /F %%C in ("!%%~1.Len!") do ( %\n%
FOR /F "delims=" %%L in ("!line!") Do ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1[%%C]=%%~L" ! %\n%
if %%C == 0 ( %\n%
set "%%~1=%%~L" ! %\n%
) ELSE ( %\n%
set "%%~1=!%%~1!!LF!%%~L" ! %\n%
) %\n%
) %\n%
set /a %%~1.Len+=1 %\n%
) %\n%
) %\n%
) ELSE ( %\n%
%= Used if delayed expansion is disabled =% %\n%
for /F "delims=" %%O in ('"%%~2 | findstr /N ^^"') do ( %\n%
setlocal DisableDelayedExpansion %\n%
set "line=%%O" %\n%
setlocal EnableDelayedExpansion %\n%
set "line="!line:*:=!"" %\n%
for /F %%C in ("!%%~1.Len!") DO ( %\n%
FOR /F "delims=" %%L in ("!line!") DO ( %\n%
endlocal %\n%
endlocal %\n%
set "%%~1[%%C]=%%~L" %\n%
) %\n%
set /a %%~1.Len+=1 %\n%
) %\n%
) %\n%
) %\n%
set /a %%~1.Max=%%~1.Len-1 %\n%
) %\n%
) else setlocal DisableDelayedExpansion^&set argv=
goto :eof
私は5秒ごとにgoogle.comにpingを実行し、現在の時間で結果を記録するスクリプトを書きました。ここでは、変数 "commandLineStr"（インデックス付き）への出力を見つけることができます。
@echo off
:LOOPSTART
echo %DATE:~0% %TIME:~0,8% >> Pingtest.log
SETLOCAL ENABLEDELAYEDEXPANSION
SET scriptCount=1
FOR /F "tokens=* USEBACKQ" %%F IN (`ping google.com -n 1`) DO (
SET commandLineStr!scriptCount!=%%F
SET /a scriptCount=!scriptCount!+1
)
@ECHO %commandLineStr1% >> PingTest.log
@ECHO %commandLineStr2% >> PingTest.log
ENDLOCAL
timeout 5 > nul
GOTO LOOPSTART