web-dev-qa-db-ja.com

XSLTを介してXMLで日付をフォーマットする

XMLシリアライザーを使用してDateTimeをシリアル化すると、次の形式で記述されます。

<Date>2007-11-14T12:01:00</Date>

これをXSLTスタイルシートに渡してHTMLを出力する場合、どのようにフォーマットできますか？ほとんどの場合、日付が必要なだけで、時間が必要なときはもちろん「面白いT」をそこに入れたくありません。

c#.netxmldatetimexslt
36
peterchen

使用できる1.0のテンプレートがいくつかあります：

<xsl:template name="formatDate">
    <xsl:param name="dateTime" />
    <xsl:variable name="date" select="substring-before($dateTime, 'T')" />
    <xsl:variable name="year" select="substring-before($date, '-')" />
    <xsl:variable name="month" select="substring-before(substring-after($date, '-'), '-')" />
    <xsl:variable name="day" select="substring-after(substring-after($date, '-'), '-')" />
    <xsl:value-of select="concat($day, ' ', $month, ' ', $year)" />
</xsl:template>

<xsl:template name="formatTime">
    <xsl:param name="dateTime" />
    <xsl:value-of select="substring-after($dateTime, 'T')" />
</xsl:template>

でそれらを呼び出します-

    <xsl:call-template name="formatDate">
        <xsl:with-param name="dateTime" select="xpath" />
    </xsl:call-template>

そして

    <xsl:call-template name="formatTime">
        <xsl:with-param name="dateTime" select="xpath" />
    </xsl:call-template>

ここで、xpathは、標準の日時形式を持つ要素または属性へのパスです。

65
AnthonyWJones

XSLT 1.0では、日付の書式設定は簡単ではありません。おそらく最もエレガントな方法は、日付の書式設定のためにC＃で短いXSLT拡張関数を記述することです。次に例を示します。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
                xmlns:msxsl="urn:schemas-Microsoft-com:xslt"
                xmlns:myExtension="urn:myExtension"
                exclude-result-prefixes="msxsl myExtension">
  <xsl:output method="xml" indent="yes"/>

  <msxsl:script implements-prefix="myExtension" language="C#">
    <![CDATA[
      public string FormatDateTime(string xsdDateTime, string format)
      {
          DateTime date = DateTime.Parse(xsdDateTime);
          return date.ToString(format); 
      }

    ]]>
  </msxsl:script>

  <xsl:template match="date">
    <formattedDate>
      <xsl:value-of select="myExtension:FormatDateTime(self::node(), 'd')"/>
    </formattedDate>
  </xsl:template>
</xsl:stylesheet>

この入力文書で

<?xml version="1.0" encoding="utf-8"?>
<date>2007-11-14T12:01:00</date>

あなたは得るでしょう

<?xml version="1.0" encoding="utf-8"?>
<formattedDate>14.11.2007</formattedDate>

日付をフォーマットする関数は、文字列としての日付値と DateTime.ToString Method で説明されているフォーマットを受け取ります。 .NETのDateTime構造体を使用すると、任意のXSD日時値（タイムゾーン指定子を含む）、タイムゾーン計算、およびローカライズされた出力を無料で解析できます。

ただし、 注意（http://support.Microsoft.com/kb/316775) msxmlスクリプト拡張機能があることに注意してください。XSLTを読み込むたびに、スクリプトコードを含むアセンブリが生成されます。動的にメモリにロードされます。 .NETランタイムの設計により、このアセンブリはアンロードできません。そのため、XSLTが一度だけ読み込まれるようにしなければなりません（さらに再利用するためにキャッシュされます）。これは、IIS内で実行する場合に特に重要です。

25
Dirk Vollmar

ジョン・ワークマンはこの問題を詳細に議論し、これにいくつかの解決策を示します discussion[1] 彼のブログで。基本的に、個々の日付コンポーネントを解析し、希望する順序で再結合します。あなたの場合、純粋なXSLT 1.0+バージョンは次のようになります。

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="date">
<!-- converts FROM <date>2001-12-31T12:00:00</date> TO some new format (DEFINED below) -->
<xsl:template name="FormatDate">
<xsl:param name="DateTime" />

<xsl:variable name="year" select="substring($DateTime,1,4)" />
<xsl:variable name="month-temp" select="substring-after($DateTime,'-')" />
<xsl:variable name="month" select="substring-before($month-temp,'-')" />
<xsl:variable name="day-temp" select="substring-after($month-temp,'-')" />
<xsl:variable name="day" select="substring($day-temp,1,2)" />
<xsl:variable name="time" select="substring-after($DateTime,'T')" />
<xsl:variable name="hh" select="substring($time,1,2)" />
<xsl:variable name="mm" select="substring($time,4,2)" />
<xsl:variable name="ss" select="substring($time,7,2)" />

<!-- EUROPEAN FORMAT -->
<xsl:value-of select="$day"/>
<xsl:value-of select="'.'"/> <!--18.-->
<xsl:value-of select="$month"/>
<xsl:value-of select="'.'"/> <!--18.03.-->
<xsl:value-of select="$year"/>
<xsl:value-of select="' '"/> <!--18.03.1976 -->
<xsl:value-of select="$hh"/>
<xsl:value-of select="':'"/> <!--18.03.1976 13: -->
<xsl:value-of select="$mm"/>
<xsl:value-of select="':'"/> <!--18.03.1976 13:24 -->
<xsl:value-of select="$ss"/> <!--18.03.1976 13:24:55 -->
<!-- END: EUROPEAN FORMAT -->

</xsl:template>

別の形式（EUROPEAN FORMATセクションを置き換えます）：

<!-- Long DATE FORMAT -->
<xsl:choose>
<xsl:when test="$month = '1' or $month= '01'">January</xsl:when>
<xsl:when test="$month = '2' or $month= '02'">February</xsl:when>
<xsl:when test="$month= '3' or $month= '03'">March</xsl:when>
<xsl:when test="$month= '4' or $month= '04'">April</xsl:when>
<xsl:when test="$month= '5' or $month= '05'">May</xsl:when>
<xsl:when test="$month= '6' or $month= '06'">June</xsl:when>
<xsl:when test="$month= '7' or $month= '07'">July</xsl:when>
<xsl:when test="$month= '8' or $month= '08'">August</xsl:when>
<xsl:when test="$month= '9' or $month= '09'">September</xsl:when>
<xsl:when test="$month= '10'">October</xsl:when>
<xsl:when test="$month= '11'">November</xsl:when>
<xsl:when test="$month= '12'">December</xsl:when>
</xsl:choose> 
<xsl:value-of select="' '"/> <!--January -->
<xsl:value-of select="$day"/> <!--January 12 -->
<xsl:value-of select="','"/> <!--January 12,-->
<xsl:value-of select="' '"/> <!--January 12, -->
<xsl:value-of select="$year"/> <!--January 12, 2001-->
<!-- END: Long DATE FORMAT -->

任意の方法で要素を再結合できます。

[1] http://geekswithblogs.net/workdog/archive/2007/02/08/105858.aspx @@ http://archive.is/4Hjep

9
rivy

この古いスレッドについてコメントすることをおologiesび申し上げますが、MSトランスフォーマーを使用している場合はJavaScriptを使用することもできます。

「msxsl」名前空間を宣言します。

xmlns:msxsl="urn:schemas-Microsoft-com:xslt"

スクリプトの名前空間を宣言します。

xmlns:js="urn:custom-javascript"

（オプション）出力からプレフィックスを省略します。

exclude-result-prefixes="msxsl js"

したがって、次のようなxsl宣言になります。

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
  xmlns:msxsl="urn:schemas-Microsoft-com:xslt"
  xmlns:js="urn:custom-javascript"
  exclude-result-prefixes="msxsl js">

Msxsl：script要素にJavaScriptを記述します。

<msxsl:script language="JavaScript" implements-prefix="js"> 
<![CDATA[ 
function javascriptFunction(dateValue){
  var date = new Date(dateValue);
  if(!isNaN(date)) return date.toLocaleString();
  return dateValue;
}
]]>
</msxsl:script>

JavaScript関数を呼び出します（「このノード」を表すXPath構文「。」を使用）：

<xsl:value-of select="js:javascriptFunction(string(.))"/>

注意：執筆時点では、外部jsファイル（jqueryライブラリなど）を含める（xsl）方法はないようです。これは、変換の前にxslファイルサーバー側を解析し、jsファイルの内容を文字列としてCDATAセクションに追加することで実行できます。私は自分でこのルートをたどり始めましたが、このレベルの機能が必要な場合は、パイプラインの別の部分に配置した方が良いと結論付けました。

ソース： http://dev.ektron.com/kb_article.aspx?id=482
ref： http://www.ibm.com/developerworks/xml/library/x-tipxsltjs/index.html

5
Phileas Fogg

おかげで、この投稿は大いに役立ちました。

次の日付形式を使用するRSSフィードを変換していました：Mon、04 Apr 2011 23:18:00 -07。これが、解析に使用した名前付きテンプレートです。

<!--Parse date format: Mon, 04 Apr 2011 23:18:00 -0700-->
<xsl:template name="formatDate">

    <xsl:param name="dateIn" />

    <xsl:variable name="day" select="substring($dateIn, 0, 3)" />
    <xsl:variable name="date" select="substring($dateIn, 6, 2)" />
    <xsl:variable name="month" select="substring($dateIn, 9, 3)" />
    <xsl:variable name="year" select="substring($dateIn, 13, 4)" />

    <xsl:variable name="hour" select="substring($dateIn, 18, 2)" />
    <xsl:variable name="min" select="substring($dateIn, 21, 2)" />
    <xsl:variable name="sec" select="substring($dateIn, 24, 2)" />

    <xsl:value-of select="concat($date, ' ', $month, ' ', $year, ' ', $hour, ':', $min, ':', $sec)" />

</xsl:template>
3
Jibran

royの投稿に対する修正：関数からの日は常に月の値を取得します。以下を使用してください。

<xsl:variable name="year" select="substring($dateTime,1,4)" />
<xsl:variable name="month-temp" select="substring-after($dateTime,'-')" />
<xsl:variable name="month" select="substring-before($month-temp,'-')" />
<xsl:variable name="day-temp" select="substring-after($month-temp,'-')" />
<xsl:variable name="day" select="substring($day-temp,1,2)" />
<xsl:variable name="time" select="substring-after($dateTime,'T')" />
<xsl:variable name="hh" select="substring($time,1,2)" />
<xsl:variable name="mm" select="substring($time,4,2)" />
<xsl:variable name="ss" select="substring($time,7,2)" />

<xsl:value-of select="concat($month,'/',$day,'/',$year,' ',$hh,':',$mm,':',$ss)" />
3
Andy