web-dev-qa-db-ja.com

最もシンプルだが完全なCMakeの例

どういうわけか私はCMakeの仕組みに完全に混乱しています。 CMakeがどのように書かれるべきかを理解しようとしていると思うたびに、私が読んだ次の例でCMakeは消えます。私が知りたいのは、プロジェクトをどのように構成すればよいのかということです。そうすれば、CMakeの将来のメンテナンスが最小限に抑えられます。たとえば、srcツリーに新しいフォルダーを追加するときにCMakeList.txtを更新したくないのですが、これは他のすべてのsrcフォルダーとまったく同じように機能します。

これが私のプロジェクトの構造を想像する方法ですが、これはほんの一例です。推奨される方法が異なる場合は、教えてください、それを行う方法を教えてください。

myProject
    src/
        module1/
            module1.h
            module1.cpp
        module2/
            [...]
        main.cpp
    test/
        test1.cpp
    resources/
        file.png
    bin
        [execute cmake ..]

ところで、私のプログラムがリソースの場所を知っていることが重要です。推奨されるリソース管理方法を知りたいです。 「../resources/file.png」でリソースにアクセスしたくない

c++cmakeproject-setup
101
Arne

いくつかの調査の後、今では最も単純だが完全なcmakeの例の独自のバージョンがあります。ここにあり、リソースやパッケージングなど、ほとんどの基本をカバーしようとしています。

非標準的なことの1つは、リソース処理です。デフォルトでは、cmakeはそれらを/ usr/share /、/ usr/local/share /、およびWindows上で同等のものに配置します。どこでも解凍して実行できるシンプルなZip/tar.gzが必要でした。したがって、リソースは実行可能ファイルに対してロードされます。

cmakeコマンドを理解するための基本的な規則は、次の構文です：<function-name>(<arg1> [<arg2> ...])カンマまたは半色なし。各引数は文字列です。 foobar(3.0)とfoobar("3.0")は同じです。 set(args arg1 arg2)を使用してリスト/変数を設定できます。この変数を設定すると、foobar(${args})とfoobar(arg1 arg2)は事実上同じになります。存在しない変数は、空のリストと同等です。リストは、内部的に要素を区切るセミコロンを含む単なる文字列です。したがって、要素が1つだけのリストは、定義によりその要素のみであり、ボクシングは行われません。変数はグローバルです。組み込み関数は、引数リストにPUBLICやDESTINATIONなどのIDが必要なため、引数をグループ化するために、名前付き引数の形式を提供します。しかし、これは言語機能ではありません。これらのidも単なる文字列であり、関数の実装によって解析されます。

github からすべてをクローンできます

cmake_minimum_required(VERSION 3.0)
project(example_project)

###############################################################################
## file globbing ##############################################################
###############################################################################

# these instructions search the directory tree when cmake is
# invoked and put all files that match the pattern in the variables 
# `sources` and `data`
file(GLOB_RECURSE sources      src/main/*.cpp src/main/*.h)
file(GLOB_RECURSE sources_test src/test/*.cpp)
file(GLOB_RECURSE data resources/*)
# you can use set(sources src/main.cpp) etc if you don't want to
# use globing to find files automatically

###############################################################################
## target definitions #########################################################
###############################################################################

# add the data to the target, so it becomes visible in some IDE
add_executable(example ${sources} ${data})

# just for example add some compiler flags
target_compile_options(example PUBLIC -std=c++1y -Wall -Wfloat-conversion)

# this lets me include files relative to the root src dir with a <> pair
target_include_directories(example PUBLIC src/main)

# this copies all resource files in the build directory
# we need this, because we want to work with paths relative to the executable
file(COPY ${data} DESTINATION resources)

###############################################################################
## dependencies ###############################################################
###############################################################################

# this defines the variables Boost_LIBRARIES that contain all library names
# that we need to link to
find_package(Boost 1.36.0 COMPONENTS filesystem system REQUIRED)

target_link_libraries(example PUBLIC
  ${Boost_LIBRARIES}
  # here you can add any library dependencies
)

###############################################################################
## testing ####################################################################
###############################################################################

# this is for our testing framework
# we don't add REQUIRED because it's just for testing
find_package(GTest)

if(GTEST_FOUND)
  add_executable(unit_tests ${sources_test} ${sources})

  # we add this define to prevent collision with the main
  # this might be better solved by not adding the source with the main to the
  # testing target
  target_compile_definitions(unit_tests PUBLIC UNIT_TESTS)

  # this allows us to use our executable as a link library
  # therefore we can inherit all compiler options and library dependencies
  set_target_properties(example PROPERTIES ENABLE_EXPORTS on)

  target_link_libraries(unit_tests PUBLIC
    ${GTEST_BOTH_LIBRARIES}
    example
  )

  target_include_directories(unit_tests PUBLIC
    ${GTEST_INCLUDE_DIRS} # doesn't do anything on Linux
  )
endif()

###############################################################################
## packaging ##################################################################
###############################################################################

# all install commands get the same destination. this allows us to use paths
# relative to the executable.
install(TARGETS example DESTINATION example_destination)
# this is basically a repeat of the file copy instruction that copies the
# resources in the build directory, but here we tell cmake that we want it
# in the package
install(DIRECTORY resources DESTINATION example_destination)

# now comes everything we need, to create a package
# there are a lot more variables you can set, and some
# you need to set for some package types, but we want to
# be minimal here
set(CPACK_PACKAGE_NAME "MyExample")
set(CPACK_PACKAGE_VERSION "1.0.0")

# we don't want to split our program up into several things
set(CPACK_MONOLITHIC_INSTALL 1)

# This must be last
include(CPack)
80
Arne

最も基本的で完全な例は cmake tutorial で見つけることができます：

cmake_minimum_required (VERSION 2.6)
project (Tutorial)
add_executable(Tutorial tutorial.cxx)

プロジェクトの例では、次のものがあります。

cmake_minimum_required (VERSION 2.6)
project (MyProject)
add_executable(myexec src/module1/module1.cpp src/module2/module2.cpp src/main.cpp)
add_executable(mytest test1.cpp)

追加の質問については、チュートリアルの1つの方法として、コードに含める構成可能なヘッダーファイルを作成します。このために、次の内容のファイルconfiguration.h.inを作成します。

#define RESOURCES_PATH "@RESOURCES_PATH@"

次に、CMakeLists.txtに以下を追加します。

set(RESOURCES_PATH "${PROJECT_SOURCE_DIR}/resources/"
# configure a header file to pass some of the CMake settings
# to the source code
configure_file (
  "${PROJECT_SOURCE_DIR}/configuration.h.in"
  "${PROJECT_BINARY_DIR}/configuration.h"
)

# add the binary tree to the search path for include files
# so that we will find TutorialConfig.h
include_directories("${PROJECT_BINARY_DIR}")

最後に、コード内のパスが必要な場所で、次のことができます。

#include "configuration.h"

...

string resourcePath = string(RESOURCE_PATH) + "file.png";
36
sgvd