web-dev-qa-db-ja.com

アセンブリコードのデコードと理解

だから少し背景。私はcとアセンブリコードの初心者です。特定のパスワードを必要とするメソッドを呼び出す「爆弾」割り当て（cで記述）がありますが、コードが表示されないため、アセンブリコードを見て正しいパスワードを決定する必要があります。 。

このコードは、このメソッドのパスワードが6つの数字であることを示しています。これは、メソッドフェーズ2に「入力」として渡されます（トリガーを回避しようとしています）。

私が混乱しているのは、+ 64から+42にジャンプすることです。ループのようですが、パスごとにスタックがどのように影響を受けるかはわかりません。最後の2つの数値が同じ場合、ループが終了するように見えます。これは4の加算と減算に関係していますが、アドレスがどのようにトラバースされるかはわかりません。誰かが何が起こっているのかを正確に翻訳できる場合、または特定のレジスタ/場所を調べる必要がある場合は、非常に役立ちます。さらに4つのフェーズがあり、それぞれがより複雑になるはずなので、これらを読む方法をよく理解したいと思います。

また、アセンブリコードキーワードを備えた優れたリソース（印刷可能なテーブルなど）があれば、32ビットレジスタと64ビットレジスタの間に違いがある場合は、レジスタ名以外のことを心配する必要があります。 。

    82          phase_2(input);
(gdb) disas phase_2
Dump of assembler code for function phase_2:
0x000000000040106b <phase_2+0>: Push   %rbp
0x000000000040106c <phase_2+1>: Push   %rbx
0x000000000040106d <phase_2+2>: sub    $0x28,%rsp
0x0000000000401071 <phase_2+6>: mov    %rsp,%rsi
0x0000000000401074 <phase_2+9>: callq  0x401457 <read_six_numbers>
0x0000000000401079 <phase_2+14>:        cmpl   $0x0,(%rsp)
0x000000000040107d <phase_2+18>:        jne    0x401086     <phase_2+27>
0x000000000040107f <phase_2+20>:        cmpl   $0x1,0x4(%rsp)
0x0000000000401084 <phase_2+25>:        je     0x40108b <phase_2+32>
0x0000000000401086 <phase_2+27>:        callq  0x401421 <explode_bomb>
0x000000000040108b <phase_2+32>:        lea    0x8(%rsp),%rbx
0x0000000000401090 <phase_2+37>:        lea    0x18(%rsp),%rbp
0x0000000000401095 <phase_2+42>:        mov    -0x8(%rbx),%eax
0x0000000000401098 <phase_2+45>:        add    -0x4(%rbx),%eax
0x000000000040109b <phase_2+48>:        cmp    %eax,(%rbx)
0x000000000040109d <phase_2+50>:        je     0x4010a4 <phase_2+57>
0x000000000040109f <phase_2+52>:        callq  0x401421 <explode_bomb>
0x00000000004010a4 <phase_2+57>:        add    $0x4,%rbx
0x00000000004010a8 <phase_2+61>:        cmp    %rbp,%rbx
0x00000000004010ab <phase_2+64>:        jne    0x401095 <phase_2+42>
0x00000000004010ad <phase_2+66>:        add    $0x28,%rsp
0x00000000004010b1 <phase_2+70>:        pop    %rbx
0x00000000004010b2 <phase_2+71>:        pop    %rbp
0x00000000004010b3 <phase_2+72>:        retq
cgdbassemblies
20
Gadesxion

これは、フェーズ2に相当するCです。

int t[6];
read_six_numbers (t);
if ((t[0] != 0) || (t[1] != 1)) {
    explode_bomb();
}

for (int i = 2; i < 6; i++) {
        if (t[i] != t[i - 2] + t[i - 1]) {
            explode_bomb();
    }
}

したがって、パスワードは0、1、1、2、3、5です。

どうやってこれをしましたか？アセンブリを徐々にCに置き換える。

スタックポインタ（rsp）は決して変更されないことに注意してください。スタックは、32ビット数の配列tとして見ることができます。つまり、4バイト移動するたびに、次の要素に移動します。つまり、0（％rsp）、4（％rsp）、...はt [0]、t [1]、..と同等です。

私はあなたが問題を抱えているビットの可能な段階的な変換をあなたに示します：

                lea    0x8(%rsp),%rbx
                lea    0x18(%rsp),%rbp
<phase_2+42>:   mov    -0x8(%rbx),%eax
                add    -0x4(%rbx),%eax
                cmp    %eax,(%rbx)
                je     <phase_2+57>
                callq  explode_bomb
<phase_2+57>:   add    $0x4,%rbx
                cmp    %rbp,%rbx
                jne    phase_2+42
------------------------------------------------------
                    rbx = rsp + 8;
                    rbp = rsp + 24;
<phase_2+42>:       eax = [rbx - 8];
                    eax += [rbx - 4];
                    if (eax == [rbx]) goto <phase_2+57>;
                    explode_bomb();
<phase_2+57>:       rbx += 4;
                    if (rbx != rbp) goto phase_2+42;
------------------------------------------------------
rbx = rsp + 8;
rbp = rsp + 24;
do {
    eax = [rbx - 8] + [rbx - 4];
        if (eax != [rbx]) {
        explode_bomb();
    }
        rbx += 4;
} while (rbx != rbp);
------------------------------------------------------
rbx = 8;
do {
    eax = [rsp + rbx - 8] + [rsp + rbx - 4];
        if (eax != [rsp + rbx]) {
        explode_bomb();
    }
        rbx += 4;
} while (rbx < 24);
------------------------------------------------------
i = 2;
do {
    eax = t[i - 2] + t[i - 1];
        if (eax != t[i]) {
        explode_bomb();
    }
        i += 1;
} while (i < 6);
------------------------------------------------------
for (int i = 2; i < 6; i++) {
    if (t[i] != t[i - 2] + t[i - 1]) {
            explode_bomb();
        }
}

これらの変換を理解するために時間をかけると、アセンブリの任意の部分を変換して理解できるようになります。

48
Antoine Mathys