web-dev-qa-db-ja.com

Clonezillaバックアップ前のWindows7クリーンアップ

Win7ボックスをSP1で更新し、ブラウザーをIE11にアップグレードしました。 Clonezillaで不必要にアーカイブされないように、操作（インストールファイルなど）に不要なファイルを削除したいと思います。この目的をサポートする優れたスクリプト、リスト、または手順はありますか？ありがとうございました

clonezilla
5
gatorback

Windows7のクリーンアップスクリプトとプロセス

以下は、イメージングの前にマシンをクリーンアップするために過去に使用したバッチスクリプトですWindows 7およびWindows Vistaなので、必要に応じて試してみてください。

sysprep を参照し、それも使用して実行することを検討してください。マシンの電源が切れたら、CloneZillaを使用してイメージを取得し、起動する前にWindows。

バッチスクリプト

スクリプトを確認し、プロセスに含めたくないものはすべてコメントアウトして、事前にテストマシンでテストしてください。また、安全のために、必要に応じて必要なものをクリーンアップまたは削除する必要はありません。

これはバッチスクリプトなので、これを.cmdまたは.batファイル拡張子の付いたテキストドキュメントに保存し、右クリックして管理者として昇格して実行してください。

これらのプロセスの一部も冗長であることは知っていますが、これらの重複するプロセスをクリーンアップする機会がないだけですが、同じフォルダーなどで削除またはクリーンアッププロセスを2回実行しても問題はありません。

@ECHO on

TASKKILL /F /IM Explorer.exe

ECHO *****""Stopping Windows Services""****
NET STOP /Y "Themes"
NET STOP /Y "Windows Update"
NET STOP /Y "Fax"
NET STOP /Y "Print Spooler"
NET STOP /Y "Remote Registry"
NET STOP /Y "Background Intelligent Transfer Service"
NET STOP /Y "Office Source Engine"
NET STOP /Y "Offline Files"
NET STOP /Y "Secondary Logon"
NET STOP /Y "Java Quick Starter"
NET STOP /Y "IIS Admin"
NET STOP /Y "smart card"
NET STOP /Y "Tablet PC Input Service"
NET STOP /Y "Telephony"
NET STOP /Y "Windows Media Player Network Sharing Service"
NET STOP /Y "Windows Mobile 2003-based device connectivity"
NET STOP /Y "Windows Mobile-based device connectivity"
NET STOP /Y "Cisco Systems, Inc. VPN Service"
NET STOP /Y "Adobe LM Service"
NET STOP /Y "Adobe Flash Player Update Service"
NET STOP /Y "Bluetooth Support Service"

SC CONFIG "Adobe Flash Player Update Service" START= manual
SC CONFIG "Adobe LM Service" START= manual
SC CONFIG "Fax" START= manual
SC CONFIG "Offline Files" START= manual
SC CONFIG "Java Quick Starter" START= manual
SC CONFIG "Tablet PC Input Service" START= manual
SC CONFIG "Windows Media Player Network Sharing Service" START= manual
SC CONFIG "Windows Mobile 2003-based device connectivity" START= manual
SC CONFIG "Windows Mobile-based device connectivity"" START= manual

::Setting Source Directories as Variables
SET SRC1=C:\Users
SET SRC2=AppData\Local\Temp
SET SRC3=AppData\Local\Microsoft\Windows\Temporary Internet Files
SET SRC4=AppData\Local\Microsoft\Windows\History
SET SRC5=AppData\Microsoft\Windows\Cookies
SET SRC6=AppData\Local\Microsoft\Windows\WER
SET SRC7=AppData\Local\Microsoft\Windows\Explorer
SET SRC8=AppData\Local

ECHO ****Deleting User\AppData\Local\Temp Sub-Directories****
FOR /D %%X IN ("%SRC1%\*") DO FOR /D %%Y IN ("%%X\%SRC2%\*.*") DO DEL /F /S /Q "%%Y"
FOR /D %%X IN ("%SRC1%\*") DO FOR /D %%Y IN ("%%X\%SRC2%\") DO RMDIR /S /Q "%%Y"

ECHO ***Deleting User\AppData\Local\MS\Windows\Temporary Internet Files***
FOR /D %%X IN ("%SRC1%\*") DO FOR /D %%Y IN ("%%X\%SRC3%\*.*") DO DEL /F /S /Q "%%Y"

ECHO ***Deleting User\AppDate\Local\MS\Windiws\History Sub-Directories***
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC4%\*.*") DO DEL /F /S /Q "%%Y"
FOR /D %%X IN ("%SRC1%\*") DO FOR /D %%Y IN ("%%X\%SRC4%\") DO RMDIR /S /Q "%%Y"
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC3%\*.*") DO DEL /F /S /Q "%%Y"

ECHO **Deleting User\AppData\Local\Microsoft\Windows\Cookies Sub-Directories**
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC5%\*.*") DO DEL /F /S /Q "%%Y"

ECHO **Deleting User\AppData\Local\Microsoft\Windows\WER\ReportArchive & Report Queue**
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC6%\*.*") DO DEL /F /S /Q "%%Y"

ECHO **Deleting User\AppData\Local\Microsoft\Windows\Explorer**
FOR /D %%X IN ("%SRC1%\*") DO FOR %%Y IN ("%%X\%SRC7%\*.*") DO DEL /F /S /Q "%%Y"


ECHO ****""Deleting Non-User Temp files and directories""****
RMDIR /S /Q C:\WINDOWS\SoftwareDistribution
DEL /F /S /Q %TEMP%\*.*
DEL /F /S /Q %systemroot%\temp\*.*
DEL /F /S /Q C:\ProgramData\TEMP\*.*
DEL /F /S /Q C:\Windows\Temp\*.*
DEL /F /S /Q %windir%\Temp\*.*
FOR /D %%X IN ("%windir%\temp\*") DO RMDIR /S /Q "%%X"

ECHO **Recreate all %userprofile%\Appdata\Local\Temp\Low directory**
FOR /D %%X IN (%SRC1%\*) DO FOR /D %%Y IN (%%X\%SRC8%) DO MD %%Y\Temp\Low

ECHO **Set security level back up on all %userprofile%\Appdata\Local\Temp\Low directory**          
FOR /D %%X IN (%SRC1%\*) DO FOR /D %%Y IN (%%X\%SRC8%) DO ICACLS %%Y\Temp\Low /setintegritylevel (OI)(CI)low

ECHO ** Remove all print jobs that are pendning**
DEL /Q /F "%systemroot%\system32\spool\printers\*.shd"
DEL /Q /F "%systemroot%\system32\spool\printers\*.spl"

::Empty all recycle bins
RD /S /Q C:\recycler
RD /S /Q C:\$RECYCLE.BIN

ECHO *** Turn off Windows hibernation power save setting ***
POWERCFG HIBERNATE OFF

ECHO *** Resize VSS (shadow storage) ***
VSSADMIN RESIZE SHADOWSTORAGE /FOR=C: /ON=C: /MAXSIZE=1GB

ECHO *** Set disk cleanup parameters to clean and then clean after being set ***
CLEANMGR /D c: /SAGESET:100
PAUSE
CLEANMGR /SAGERUN:100

ECHO *** Flush DNS ***
IPCONFIG /FLUSHDNS

ECHO *** Reset TCP/IP ***
NETSH INT IP RESET

ECHO *** Reset Winsock ***
NETSH WINSOCK RESET CATALOG

Explorer.exe

GOTO EOF

Dismコマンド

注：エラー1260が発生した場合は、グループポリシーなどでシステムの復元が無効になっている可能性があります。したがって、システムの復元を有効にしてから、管理者の昇格したコマンドプロンプトからこれらのコマンドを再実行します。さらに、以下の各コマンドを実行する前に、CD /D "C:\Windows\System32"を実行する必要がある場合があります。

次のコマンドは、スケジュールされたタスクの30日間の猶予期間なしで、以前のバージョンのコンポーネントをすべてアンインストールします。

DISM.exe /online /Cleanup-Image /StartComponentCleanup

次のコマンドは、サービスパックのアンインストールに必要なファイルを削除します。次のコマンドを実行した後は、現在インストールされているサービスパックをアンインストールできなくなります。

DISM.exe /online /Cleanup-Image /SPSuperseded

次のコマンドは、すべてのコンポーネントの古いバージョンをすべて削除します。これが完了すると、現在インストールされているサービスパックまたはアップデートをアンインストールできなくなります。

DISM.exe /online /Cleanup-Image /StartComponentCleanup /ResetBase\

ソース

その他のリソース

7
Pimp Juice IT