web-dev-qa-db-ja.com

マルチGPUの基本的な使用法

たとえば、次のコード（ベクトルの合計）のパフォーマンスを向上させるために、2つのデバイスを使用するにはどうすればよいですか？より多くのデバイスを「同時に」使用することは可能ですか？はいの場合、さまざまなデバイスのグローバルメモリでのベクトルの割り当てをどのように管理できますか？

#include <stdio.h>
#include <stdlib.h>
#include <math.h>
#include <time.h>
#include <cuda.h>

#define NB 32
#define NT 500
#define N NB*NT

__global__ void add( double *a, double *b, double *c);

//===========================================
__global__ void add( double *a, double *b, double *c){

    int tid = threadIdx.x + blockIdx.x * blockDim.x; 

    while(tid < N){
        c[tid] = a[tid] + b[tid];
        tid += blockDim.x * gridDim.x;
    }

}

//============================================
//BEGIN
//===========================================
int main( void ) {

    double *a, *b, *c;
    double *dev_a, *dev_b, *dev_c;

    // allocate the memory on the CPU
    a=(double *)malloc(N*sizeof(double));
    b=(double *)malloc(N*sizeof(double));
    c=(double *)malloc(N*sizeof(double));

    // allocate the memory on the GPU
    cudaMalloc( (void**)&dev_a, N * sizeof(double) );
    cudaMalloc( (void**)&dev_b, N * sizeof(double) );
    cudaMalloc( (void**)&dev_c, N * sizeof(double) );

    // fill the arrays 'a' and 'b' on the CPU
    for (int i=0; i<N; i++) {
        a[i] = (double)i;
        b[i] = (double)i*2;
    }

    // copy the arrays 'a' and 'b' to the GPU
    cudaMemcpy( dev_a, a, N * sizeof(double), cudaMemcpyHostToDevice);
    cudaMemcpy( dev_b, b, N * sizeof(double), cudaMemcpyHostToDevice);

    for(int i=0;i<10000;++i)
        add<<<NB,NT>>>( dev_a, dev_b, dev_c );

    // copy the array 'c' back from the GPU to the CPU
    cudaMemcpy( c, dev_c, N * sizeof(double), cudaMemcpyDeviceToHost);

    // display the results
    // for (int i=0; i<N; i++) {
    //      printf( "%g + %g = %g\n", a[i], b[i], c[i] );
    //  }
    printf("\nGPU done\n");

    // free the memory allocated on the GPU
    cudaFree( dev_a );
    cudaFree( dev_b );
    cudaFree( dev_c );
    // free the memory allocated on the CPU
    free( a );
    free( b );
    free( c );

    return 0;
}

前もって感謝します。ミケーレ

cudagpumulti-gpu
22
micheletuttafesta

CUDA 4.0がリリースされて以来、あなたが求めているタイプのマルチGPU計算は比較的簡単です。それ以前は、同じホストアプリケーション内で複数のGPUを使用するには、GPUごとに1つのホストスレッドとある種のスレッド間通信システムを備えたマルチスレッドホストアプリケーションを使用する必要がありました。

これで、ホストコードのメモリ割り当て部分に対して次のようなことを行うことができます。

double *dev_a[2], *dev_b[2], *dev_c[2];
const int Ns[2] = {N/2, N-(N/2)};

// allocate the memory on the GPUs
for(int dev=0; dev<2; dev++) {
    cudaSetDevice(dev);
    cudaMalloc( (void**)&dev_a[dev], Ns[dev] * sizeof(double) );
    cudaMalloc( (void**)&dev_b[dev], Ns[dev] * sizeof(double) );
    cudaMalloc( (void**)&dev_c[dev], Ns[dev] * sizeof(double) );
}

（免責事項：ブラウザで記述され、コンパイルされたり、テストされたりすることはなく、自己責任で使用してください）。

ここでの基本的な考え方は、デバイスで操作を実行するときに、cudaSetDeviceを使用してデバイスを選択することです。したがって、上記のスニペットでは、2つのGPUを想定し、それぞれにメモリを割り当てています[（N/2）は最初のデバイスで2倍、N-（N/2）は2番目のデバイスで]。

ホストからデバイスへのデータの転送は、次のように簡単です。

// copy the arrays 'a' and 'b' to the GPUs
for(int dev=0,pos=0; dev<2; pos+=Ns[dev], dev++) {
    cudaSetDevice(dev);
    cudaMemcpy( dev_a[dev], a+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice);
    cudaMemcpy( dev_b[dev], b+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice);
}

（免責事項：ブラウザで記述され、コンパイルされたり、テストされたりすることはなく、自己責任で使用してください）。

コードのカーネル起動セクションは、次のようになります。

for(int i=0;i<10000;++i) {
    for(int dev=0; dev<2; dev++) {
        cudaSetDevice(dev);
        add<<<NB,NT>>>( dev_a[dev], dev_b[dev], dev_c[dev], Ns[dev] );
    }
}

（免責事項：ブラウザで記述され、コンパイルされたり、テストされたりすることはなく、自己責任で使用してください）。

カーネルの各インスタンスは、処理する配列要素の数が異なる場合があるため、カーネル呼び出しに引数を追加したことに注意してください。必要な変更を行うのはあなたにお任せします。ただし、基本的な考え方は同じです。cudaSetDeviceを使用して特定のGPUを選択し、通常の方法でカーネルを実行します。各カーネルは独自の引数を取得します。

これらのパーツを組み合わせて、単純なマルチGPUアプリケーションを作成できるはずです。最近のCUDAバージョンやハードウェアで複数のGPUアプリケーションを支援するために使用できる機能は他にもたくさんあります（統合アドレス指定、ピアツーピア機能など）が、これで十分です。 CUDA SDKには単純なmuLti-GPUアプリケーションもあり、より多くのアイデアを探すことができます。

37
talonmies