web-dev-qa-db-ja.com

VBScript日付をフォーマットするにはどうすればよいですか？

日付をMM/DD/YYYYではなくMM-DD-YYYYのように見せたい。

datevbscript
20
Cocoa Dev
0 = vbGeneralDate - Default. Returns date: mm/dd/yy and time if specified: hh:mm:ss PM/AM.
1 = vbLongDate - Returns date: weekday, monthname, year
2 = vbShortDate - Returns date: mm/dd/yy
3 = vbLongTime - Returns time: hh:mm:ss PM/AM
4 = vbShortTime - Return time: hh:mm


d=CDate("2010-02-16 13:45")
document.write(FormatDateTime(d) & "<br />")
document.write(FormatDateTime(d,1) & "<br />")
document.write(FormatDateTime(d,2) & "<br />")
document.write(FormatDateTime(d,3) & "<br />")
document.write(FormatDateTime(d,4) & "<br />")

別の形式を使用する場合は、独自の関数を作成し、月、年、日などを解析して、好みの形式にまとめる必要があります。

Function myDateFormat(myDate)
    d = WhatEver(Day(myDate))
    m = WhatEver(Month(myDate))    
    y = Year(myDate)
    myDateFormat= m & "-" & d & "-" & y
End Function

Function WhatEver(num)
    If(Len(num)=1) Then
        WhatEver="0"&num
    Else
        WhatEver=num
    End If
End Function

編集：値が0nより小さい場合、10として日と月をフォーマットする関数を追加しました。

37
stian.net

関数の実行中に変化する分または日を防ぐために、関数で「Now」を1回だけ呼び出すことをお勧めします。

したがって：

Function timeStamp()
    Dim t 
    t = Now
    timeStamp = Year(t) & "-" & _
    Right("0" & Month(t),2)  & "-" & _
    Right("0" & Day(t),2)  & "_" & _  
    Right("0" & Hour(t),2) & _
    Right("0" & Minute(t),2) '    '& _    Right("0" & Second(t),2) 
End Function
17
Sam

FormatDateTimeの出力は、コントロールパネルの[地域の設定]の構成によって異なります。そのため、他の国では、FormatDateTime（d、2）は、たとえばyyyy-MM-ddを返す場合があります。

出力を「カルチャーインバリアント」にしたい場合は、stian.netのソリューションを使用してください。日付のスラッシュが嫌いで、他の国の日付形式を気にしない場合は、

Replace(FormatDateTime(d,2),"/","-")
9
MBu

'私が使用する一意のファイル名

Dim ts, logfile, thisScript

thisScript = LEFT(Wscript.ScriptName,LEN(Wscript.ScriptName)-4) ' assuming .vbs extension

ts = timeStamp
logfile = thisScript & "_" & ts

' ======
Function timeStamp() 
    timeStamp = Year(Now) & "-" & _
    Right("0" & Month(Now),2)  & "-" & _
    Right("0" & Day(Now),2)  & "_" & _  
    Right("0" & Hour(Now),2) & _
    Right("0" & Minute(Now),2) '    '& _    Right("0" & Second(Now),2) 
End Function
' ======
4
qaweb

答えは提供されていますが、私はより簡単な解決策を見つけました：

日付：

01/20/2017

交換することにより

CurrentDate = replace(date, "/", "-")

出力されます：

01-20-2017
1
vpetkovic

このスニペットは datePart関数 でこの問題も解決します。また、right()トリックを使用してrpad(x,2,"0")を実行しました。

option explicit

Wscript.Echo "Today is " & myDate(now)

' date formatted as your request
Function myDate(dt)
    dim d,m,y, sep
    sep = "-"
    ' right(..) here works as rpad(x,2,"0")
    d = right("0" & datePart("d",dt),2)
    m = right("0" & datePart("m",dt),2)
    y = datePart("yyyy",dt)
    myDate= m & sep & d & sep & y
End Function
0
gwarah