web-dev-qa-db-ja.com

WinInetAPIを使用してDelphiでHTTP POST Requestを送信する方法

WinInet関数を使用してDelphiからHTTPリクエストを作成しようとしています。

これまでのところ：

function request:string;
var
  hNet,hURL,hRequest: HINTERNET;
begin
  hNet := InternetOpen(PChar('User Agent'),INTERNET_OPEN_TYPE_PRECONFIG or INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if Assigned(hNet) then 
  begin
  try
    hURL := InternetConnect(hNet,PChar('http://example.com'),INTERNET_DEFAULT_HTTP_PORT,nil,nil,INTERNET_SERVICE_HTTP,0,DWORD(0));
    if(hURL<>nil) then
      hRequest := HttpOpenRequest(hURL, 'POST', PChar('param=value'),'HTTP/1.0',PChar(''), nil, INTERNET_FLAG_RELOAD or INTERNET_FLAG_PRAGMA_NOCACHE,0);
    if(hRequest<>nil) then
      HttpSendRequest(hRequest, nil, 0, nil, 0);
    InternetCloseHandle(hNet);
  except
    on E : Exception do
      ShowMessage(E.ClassName+' error raised, with message : '+E.Message);
  end;
  end
end;

しかし、これは何もしません（私はネットワークhttpトラフィックをスニッフィングしてそれが機能するかどうかを確認しています）。 InternetOpenURLを正常に使用しましたが、POSTリクエストを送信する必要があり、その関数はそれを行いません。

誰かが私に簡単な例を見せてもらえますか？私が望む結果は、文字列としてvarのhttp応答ページを取得することです。

delphihttppostrequestwininet
15
Sebastian

すべてのURL /ファイル名の部分が前のコードで台無しになりました。私はこれを使用しています Jeff DeVoreから 現在、正常に動作しています：

function request(const AUrl, AData: AnsiString; blnSSL: Boolean = True): AnsiString;
var
  aBuffer     : Array[0..4096] of Char;
  Header      : TStringStream;
  BufStream   : TMemoryStream;
  sMethod     : AnsiString;
  BytesRead   : Cardinal;
  pSession    : HINTERNET;
  pConnection : HINTERNET;
  pRequest    : HINTERNET;
  parsedURL   : TStringArray;
  port        : Integer;
  flags       : DWord;
begin
  ParsedUrl := ParseUrl(AUrl);

  Result := '';

  pSession := InternetOpen(nil, INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);

  if Assigned(pSession) then
  try
    if blnSSL then
      Port := INTERNET_DEFAULT_HTTPS_PORT
    else
      Port := INTERNET_DEFAULT_HTTP_PORT;
    pConnection := InternetConnect(pSession, PChar(ParsedUrl[0]), port, nil, nil, INTERNET_SERVICE_HTTP, 0, 0);

    if Assigned(pConnection) then
    try
      if (AData = '') then
        sMethod := 'GET'
      else
        sMethod := 'POST';

      if blnSSL then
        flags := INTERNET_FLAG_SECURE or INTERNET_FLAG_KEEP_CONNECTION
      else
        flags := INTERNET_SERVICE_HTTP;

      pRequest := HTTPOpenRequest(pConnection, PChar(sMethod), PChar(ParsedUrl[1]), nil, nil, nil, flags, 0);

      if Assigned(pRequest) then
      try
        Header := TStringStream.Create('');
        try
          with Header do
          begin
            WriteString('Host: ' + ParsedUrl[0] + sLineBreak);
            WriteString('User-Agent: Custom program 1.0'+SLineBreak);
            WriteString('Accept: text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8'+SLineBreak);
            WriteString('Accept-Language: en-us,en;q=0.5' + SLineBreak);
            WriteString('Accept-Charset: ISO-8859-1,utf-8;q=0.7,*;q=0.7'+SLineBreak);
            WriteString('Keep-Alive: 300'+ SLineBreak);
            WriteString('Connection: keep-alive'+ SlineBreak+SLineBreak);
          end;

          HttpAddRequestHeaders(pRequest, PChar(Header.DataString), Length(Header.DataString), HTTP_ADDREQ_FLAG_ADD);

          if HTTPSendRequest(pRequest, nil, 0, Pointer(AData), Length(AData)) then
          begin
            BufStream := TMemoryStream.Create;
            try
              while InternetReadFile(pRequest, @aBuffer, SizeOf(aBuffer), BytesRead) do
              begin
                if (BytesRead = 0) then Break;
                BufStream.Write(aBuffer, BytesRead);
              end;

              aBuffer[0] := #0;
              BufStream.Write(aBuffer, 1);
              Result := PChar(BufStream.Memory);
            finally
              BufStream.Free;
            end;
          end;
        finally
          Header.Free;
        end;
      finally
        InternetCloseHandle(pRequest);
      end;
    finally
      InternetCloseHandle(pConnection);
    end;
  finally
    InternetCloseHandle(pSession);
  end;
end;

ParseUrlは、URLを「ホスト名/ファイル名」に分割する関数であり、TStringArrayは文字列の配列です。明日もコードを確認する必要がありますが、問題はないようで、スニファで投稿データとヘッダーが送信されているのがわかりました。

9
Sebastian

個人的には、すべてのTCP/IP作業に synapse ライブラリを使用することを好みます。たとえば、単純なHTTPPOSTは次のようにコーディングできます。

uses
  httpsend;

function testpost;
begin
  stm := tStringstream.create('param=value');
  try
    HttpPostBinary('http://example.com',Stm);
  finally
    stm.free;
  end;
end;

ライブラリはよく書かれており、特定の要件に合わせて非常に簡単に変更できます。最新のSubversionリリースは、Delphi2009とDelphi2010の両方で問題なく動作します。このフレームワークはコンポーネントベースではなく、マルチスレッド環境に適した一連のクラスとプロシージャです。

2
skamradt

HttpOpenRequest への3番目のパラメーター（lpszObjectName）は、[〜＃〜] url [〜＃〜]リクエストしたい。そのため、ドキュメントでは5番目のパラメーター（lpszReferer）を「要求内のURL（lpszObjectName）の取得元のドキュメントのURLを指定するnullで終了する文字列へのポインター」と説明しています。

投稿されたデータは HttpSendRequest ;で送信されます。 lpOptionalパラメーターは次のように記述されます。

リクエストヘッダーの直後に送信されるオプションのデータを含むバッファーへのポインター。このパラメーターは通常、POSTおよびPUT操作に使用されます。オプションのデータは、サーバーに送信されるリソースまたは情報にすることができます。送信するオプションのデータがない場合、このパラメーターはNULLにすることができます。

InternetOpen の2番目のパラメーターはサーバー名だけ;プロトコルを含めるべきではありません。 6番目のパラメーターで指定するプロトコル。

リクエストを送信した後、 InternetReadFile および InternetQueryDataAvailable でレスポンスを読み取ることができます。

API関数がゼロを返すかどうかを確認してから、次の行に進むだけではいけません。失敗した場合は、GetLastErrorに電話して理由を確認してください。投稿したコードは例外を発生させないので、例外をキャッチするのは無駄です。 （そして、とにかくそうしているようにそれらを「処理」するのは愚かです。修正方法がまだわからないという例外をキャッチしないでください。他のすべてを発信者または発信者の発信者などに任せてください。 。）

1
Rob Kennedy