web-dev-qa-db-ja.com

Delugeとマグネットリンクを取得するにはどうすればよいですか？

彼らはそれがもう互換性がないと言いますか？情報ハッシュボタンがグレー表示されるのはなぜですか？

Deluge Web UIクライアントでマグネットリンクを取得する方法を誰かが知っていますか？

ところで、私のデリュージクライアントのバージョンは1.3.5です。

deluge
4
psyko666

AskUbunt によると、WebUIでのマグネットサポートは1.3.4で5月に追加されました。最新の状態になっていますか？

2
Kruug

マグネットリンクと[リンクのアドレスをコピー]などを右クリックして、[急流を追加]でそのリンクを大洪水にコピーします。

4
Impulss

Macの場合、GitHubユーザー Lord-Kamina がAppleScriptの回避策である Deluge-Magnet-Handler を作成しました。アプリケーションフォルダーにインストールされ、magnet:リンクに関連付けるために一度実行されると、それらのURLはその後自動的にDelugeで開くはずです。

on quit
    try
        tell application "System Events" to tell process "Deluge"
            activate
            set frontmost to true
            windows where title contains "Add Torrents"
            if result is not {} then perform action "AXRaise" of item 1 of result
        end tell
    end try
end quit

on open location this_URL
    try
        tell application "Finder" to set delugePath to POSIX path of (application file id "org.deluge" as string)
        set appExists to true
    on error
        set appExists to false
        display alert "Deluge.app must be installed in order to use this plug-in." as critical
        return
    end try
    set delugeArgument to quoted form of this_URL
    try
        tell application "Deluge" to activate
    end try
    do Shell script (quoted form of (delugePath & "/Contents/MacOS/Deluge") & " add " & delugeArgument & "; return;")
    quit
end open location
tell application "Finder" to set thisPath to (POSIX path of (application file id "org.deluge.MagnetURIHandler" as string))
log thisPath
set lsToolRead to do Shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " read url magnet")
if (lsToolRead contains "Magnet Handler.app") then
    display dialog "Magnet Handler is already the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
else
    try
        set dialogResult to display dialog "Magnet Handler has not been configured to handle magnet URIs.

Would you like to do this now?" buttons {"Yes", "No"} default button "Yes" cancel button "No" with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")
    on error number -128
    end try
    try
        if button returned of dialogResult is "Yes" then
            do Shell script (quoted form of (thisPath & "/Contents/Resources/lstool") & " write url magnet org.deluge.MagnetURIHandler")
            display dialog "Magnet Handler has now been configured as the default application to handle magnet URIs" buttons {"OK"} with title "Notification" with icon POSIX file (thisPath & "/Contents/Resources/deluge_magnet.icns")

        end if
    end try
end if
quit
2
Chris