web-dev-qa-db-ja.com

Elixirマクロを使用して動的関数名を作成する方法は？

関数名を動的に作成したい。私はこのマクロを書いた

defmacro generate_dynamic(name) do
  quote do 
    def add_(unquote(name)) do
    end
  end
end

そして、私はそれを次のように使用しました：

defmodule AnotherModule do
  generate_dynamic :animal
end

現在、AnotherModule.add_関数のみが定義されているのに対して、AnotherModule.add_animal関数が必要です。

elixir
34
shankardevy

これを達成するには、:add_を名前にbefore引用符を外します。また、この場合のメソッド名の後の括弧は、あいまいさを防ぐために必要です。これでうまくいくはずです：

defmacro generate_dynamic(name) do
  quote do 
    def unquote(:"add_#{name}")() do
      # ...
    end
  end
end
44
Patrick Oscity

便利なショートカットとして、引用符のないフラグメントを使用してマクロを記述することなく、同じ結果をインラインで実現できる場合があります。

defmodule Hello do
  [:alice, :bob] |> Enum.each fn name ->
    def unquote(:"hello_#{name}")() do
      IO.inspect("Hello #{unquote(name)}")
    end
  end
end

Hello.hello_bob    # => "Hello bob"
Hello.hello_alice  # => "Hello alice"
21
Paweł Obrok

Rubyのattr_accessorを模倣するために、Gistで同じ種類のことを行いました。

defmodule MacroExp do
  defmacro attr_accessor(atom) do
    getter = String.to_atom("get_#{atom}")
    setter = String.to_atom("set_#{atom}")
    quote do
      def unquote(getter)(data) do
        data |> Map.from_struct |> Map.get(unquote(atom))
      end
      def unquote(setter)(data, value) do
        data |> Map.put(unquote(atom), value)
      end
    end
  end

  defmacro attr_reader(atom) do
    getter = String.to_atom("get_#{atom}")
    quote do
      def unquote(getter)(data) do
        data |> Map.from_struct |> Map.get(unquote(atom))
      end
    end
  end
end


defmodule Calculation do
  import MacroExp
  defstruct first: nil, second: nil, operator: :plus

  attr_accessor :first   # defines set_first/2 and get_first/1
  attr_accessor :second  # defines set_second/2 and get_second/1
  attr_reader :operator  # defines set_operator/2 and get_operator/1

  def result(%Calculation{first: first, second: second, operator: :plus}) do
    first + second
  end
end

https://Gist.github.com/rcdilorenzo/77d7a29737de39f0cd84

6
Christian Di Lorenzo