パッケージ名のリストを指定してEmacsパッケージを自動的にインストールする方法は？
私はpackageを使用してEmacs拡張機能を管理しています。異なるコンピューターでEmacs設定を同期するには、.emacsファイルでパッケージ名のリストを指定し、packageがパッケージを自動的に検索してインストールできるようにしたいので、 M-x package-list-packagesを呼び出して手動でインストールする必要はありません。どうやってするか？
Profpatschのコメントと以下の回答に基づきます。
(defun ensure-package-installed (&rest packages)
"Assure every package is installed, ask for installation if it’s not.
Return a list of installed packages or nil for every skipped package."
(mapcar
(lambda (package)
;; (package-installed-p 'evil)
(if (package-installed-p package)
nil
(if (y-or-n-p (format "Package %s is missing. Install it? " package))
(package-install package)
package)))
packages))
;; make sure to have downloaded archive description.
;; Or use package-archive-contents as suggested by Nicolas Dudebout
(or (file-exists-p package-user-dir)
(package-refresh-contents))
(ensure-package-installed 'iedit 'magit) ; --> (nil nil) if iedit and magit are already installed
;; activate installed packages
(package-initialize)
; list the packages you want
(setq package-list '(package1 package2))
; list the repositories containing them
(setq package-archives '(("elpa" . "http://tromey.com/elpa/")
("gnu" . "http://elpa.gnu.org/packages/")
("marmalade" . "http://marmalade-repo.org/packages/")))
; activate all the packages (in particular autoloads)
(package-initialize)
; fetch the list of packages available
(unless package-archive-contents
(package-refresh-contents))
; install the missing packages
(dolist (package package-list)
(unless (package-installed-p package)
(package-install package)))
Emacs 25.1+は、カスタマイズ可能なpackage-selected-packages変数にユーザーがインストールしたパッケージを自動的に追跡します。 package-installはカスタマイズ変数を更新し、package-install-selected-packages関数を使用して選択したすべてのパッケージをインストールできます。
このアプローチのもう1つの便利な利点は、package-autoremoveを使用して、package-selected-packagesに含まれていないパッケージを自動的に削除できることです（ただし、依存関係は保持されます）。
(package-initialize)
(unless package-archive-contents
(package-refresh-contents))
(package-install-selected-packages)
ソース： http://endlessparentheses.com/new-in-package-el-in-emacs-25-1-user-selected-packages.html
Emacs Prelude に使用するコードは次のとおりです。
(require 'package)
(require 'melpa)
(add-to-list 'package-archives
'("melpa" . "http://melpa.milkbox.net/packages/") t)
(package-initialize)
(setq url-http-attempt-keepalives nil)
(defvar prelude-packages
'(ack-and-a-half auctex clojure-mode coffee-mode deft expand-region
Gist haml-mode haskell-mode helm helm-projectile inf-Ruby
magit magithub markdown-mode paredit projectile
python sass-mode Rainbow-mode scss-mode solarized-theme
volatile-highlights yaml-mode yari yasnippet zenburn-theme)
"A list of packages to ensure are installed at launch.")
(defun prelude-packages-installed-p ()
(loop for p in prelude-packages
when (not (package-installed-p p)) do (return nil)
finally (return t)))
(unless (prelude-packages-installed-p)
;; check for new packages (package versions)
(message "%s" "Emacs Prelude is now refreshing its package database...")
(package-refresh-contents)
(message "%s" " done.")
;; install the missing packages
(dolist (p prelude-packages)
(when (not (package-installed-p p))
(package-install p))))
(provide 'prelude-packages)
MELPAを使用していない場合は、MELPAを必要とする必要はありません（およびmelpa.elはあなたのload-path（またはMELPA経由でインストール）。パッケージdbは毎回更新されません（これにより起動が著しく遅くなるため）-アンインストールされたパッケージが存在する場合のみ。
Cask についてはまだ誰も言及していませんが、このタスクには非常に適しています。
基本的に、インストールするパッケージをリストする~/.emacs.d/Caskを作成します。例えば：
(source melpa)
(depends-on "expand-region")
(depends-on "goto-last-change")
; ... etc
コマンドラインからcaskを実行すると、これらのパッケージと、必要な依存関係がインストールされます。
また、cask updateを使用してインストール済みパッケージを自動的に更新できます。
(require 'cl)
(require 'package)
(setq cfg-var:packages '(
emmet-mode
ergoemacs-mode
flycheck
flycheck-pyflakes
monokai-theme
py-autopep8
py-isort
Rainbow-mode
yafolding
yasnippet))
(defun cfg:install-packages ()
(let ((pkgs (remove-if #'package-installed-p cfg-var:packages)))
(when pkgs
(message "%s" "Emacs refresh packages database...")
(package-refresh-contents)
(message "%s" " done.")
(dolist (p cfg-var:packages)
(package-install p)))))
(add-to-list 'package-archives '("gnu" . "http://elpa.gnu.org/packages/") t)
(add-to-list 'package-archives '("melpa" . "http://melpa.org/packages/") t)
(add-to-list 'package-archives '("melpa-stable" . "http://stable.melpa.org/packages/") t)
(add-to-list 'package-archives '("org" . "http://orgmode.org/elpa/") t)
(package-initialize)
(cfg:install-packages)
パッケージ名をシンボルとしてpackage-installを呼び出します。パッケージのパッケージ名を見つけるには、package-installをインタラクティブに呼び出して名前を補完します。関数package-installed-pは、既にインストールされているかどうかを知らせます。
例えば：
(mapc
(lambda (package)
(or (package-installed-p package)
(package-install package)))
'(package1 package2 package3))
this answer で行われたように、ユーザーが最初にパッケージをインストールするかどうかを確認するのが好きです。また、何かをインストールする前にパッケージの内容を1回更新しています。これが最善の方法であるかどうかはわかりませんが、一番の答えは私のためにそれをやっていたとは思いません。
(setq required-pkgs '(jedi flycheck cider clojure-mode paredit markdown-mode jsx-mode company))
(require 'cl)
(setq pkgs-to-install
(let ((uninstalled-pkgs (remove-if 'package-installed-p required-pkgs)))
(remove-if-not '(lambda (pkg) (y-or-n-p (format "Package %s is missing. Install it? " pkg))) uninstalled-pkgs)))
(when (> (length pkgs-to-install) 0)
(package-refresh-contents)
(dolist (pkg pkgs-to-install)
(package-install pkg)))
(package-install 'org)に.emacsを追加しても何も起こらないという問題に遭遇しました。 org-modeの最新バージョンをインストールしたかったのですが、組み込みのorg-modeはかなり古いです。
Emacs 25.3.1からpackage-installのソースコードを掘り出しました。関数selfは、パッケージがインストールされているかどうかをすでに確認しており、パッケージが既にインストールされている場合はインストールを拒否します。したがって、答え 10093312 からの(unless (package-installed-p package) ...)のチェックは実際には呼び出されません。
(defun package-install (pkg &optional dont-select)
"Install the package PKG.
PKG can be a package-desc or a symbol naming one of the available packages
in an archive in `package-archives'. Interactively, Prompt for its name.
If called interactively or if DONT-SELECT nil, add PKG to
`package-selected-packages'.
If PKG is a package-desc and it is already installed, don't try
to install it but still mark it as selected."
(interactive
(progn
;; Initialize the package system to get the list of package
;; symbols for completion.
(unless package--initialized
(package-initialize t))
(unless package-archive-contents
(package-refresh-contents))
(list (intern (completing-read
"Install package: "
(delq nil
(mapcar (lambda (elt)
(unless (package-installed-p (car elt))
(symbol-name (car elt))))
package-archive-contents))
nil t))
nil)))
(add-hook 'post-command-hook #'package-menu--post-refresh)
(let ((name (if (package-desc-p pkg)
(package-desc-name pkg)
pkg)))
(unless (or dont-select (package--user-selected-p name))
(package--save-selected-packages
(cons name package-selected-packages)))
(if-let ((transaction
(if (package-desc-p pkg)
(unless (package-installed-p pkg)
(package-compute-transaction (list pkg)
(package-desc-reqs pkg)))
(package-compute-transaction () (list (list pkg))))))
(package-download-transaction transaction)
(message "`%s' is already installed" name))))
組み込みのorg-modeもインストール済みとしてカウントされ、package-installはELPAからの新しいバージョンのインストールを拒否します。 package.elを読んでしばらくしてから、次の解決策を思いつきました。
(dolist (package (package-compute-transaction
() (list (list 'python '(0 25 1))
(list 'org '(20171211)))))
;; package-download-transaction may be more suitable here and
;; I don't have time to check it
(package-install package))
動作する理由は、package-*ファミリー関数が、それがシンボルであるかpackage-descオブジェクトであるかによって引数を異なる方法で処理するためです。 package-installオブジェクトを介してのみpackage-descのバージョン情報を指定できます。
これは私のものです、もっと短いです:)
(mapc
(lambda (package)
(unless (package-installed-p package)
(progn (message "installing %s" package)
(package-refresh-contents)
(package-install package))))
'(browse-kill-ring flycheck less-css-mode tabbar org auto-complete undo-tree clojure-mode markdown-mode yasnippet paredit paredit-menu php-mode haml-mode Rainbow-mode fontawesome))