web-dev-qa-db-ja.com

evil-mode '>' evil-shift-leftは選択を失います

Evil-mode evil-shift-leftが選択を失う理由はありますか？

つまり、選択範囲で「>」と「<」を複数回押して、テキストを左右にシフトできるようにしたいのです。

以下に実装を示します。とにかく、この動作を変更するためのアドバイスを追加しますか？

evil-commands.el

(evil-define-operator evil-shift-right (beg end &optional count)
  "Shift text from BEG to END to the right.
The text is shifted to the nearest multiple of `evil-shift-width'
\(the rounding can be disabled by setting `evil-shift-round').
See also `evil-shift-left'."
  :type line
  (interactive "<r><vc>")
  (let ((beg (set-marker (make-marker) beg))
        (end (set-marker (make-marker) end)))
    (dotimes (i (or count 1))
      (if (not evil-shift-round)
          (indent-rigidly beg end evil-shift-width)
        (let* ((indent
                (save-excursion
                  (goto-char beg)
                  (evil-move-beginning-of-line nil)
                  (while (and (< (point) end) (looking-at "[ \t]*$"))
                    (forward-line))
                  (if (> (point) end) 0
                    (current-indentation))))
               (offset (- evil-shift-width (mod indent evil-shift-width))))
          (indent-rigidly beg end offset))))
    (set-marker beg nil)
    (set-marker end nil)))
emacsevil
5
justingordon

これにより、現在の動作がオーバーロードされて再選択されます（ djoyner/dotfiles/emacs/LISP/evil-config.el＃L36-L4 にあります）。

; Overload shifts so that they don't lose the selection
(define-key evil-visual-state-map (kbd ">") 'djoyner/evil-shift-right-visual)
(define-key evil-visual-state-map (kbd "<") 'djoyner/evil-shift-left-visual)
(define-key evil-visual-state-map [tab] 'djoyner/evil-shift-right-visual)
(define-key evil-visual-state-map [S-tab] 'djoyner/evil-shift-left-visual)

(defun djoyner/evil-shift-left-visual ()
  (interactive)
  (evil-shift-left (region-beginning) (region-end))
  (evil-normal-state)
  (evil-visual-restore))

(defun djoyner/evil-shift-right-visual ()
  (interactive)
  (evil-shift-right (region-beginning) (region-end))
  (evil-normal-state)
  (evil-visual-restore))
4
avsej

@avsejによってすでに提供されている回答と非常に似ていますが、call-interactivelyを使用すると、evil-shift- {left、right}がすべての引数を受け取ります（例：COUNT）。例えば、

(defun my-visual-shift-left ()
  (interactive)
  (call-interactively 'evil-shift-left)
  (evil-normal-state)
  (evil-visual-restore))

そうすれば、一度に複数のユニットでインデントすることができます（例： 4>）。

0
ivan