web-dev-qa-db-ja.com

特定の文字列をクリップボードにコピーするExcel VBAコード

クリックするとスプレッドシートに特定のURLをクリップボードにコピーするボタンをスプレッドシートに追加しようとしています。

Excel VBAの知識は少しありましたが、しばらく経ち、苦労しています。

excel-vbaclipboardvbaexcel
42
user1958738

このマクロは、遅延バインディングを使用して、参照を設定することなくテキストをクリップボードにコピーします。あなたはただ貼り付けて行くことができるはずです：

Sub CopyText(Text As String)
    'VBA Macro using late binding to copy text to clipboard.
    'By Justin Kay, 8/15/2014
    Dim MSForms_DataObject As Object
    Set MSForms_DataObject = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}")
    MSForms_DataObject.SetText Text
    MSForms_DataObject.PutInClipboard
    Set MSForms_DataObject = Nothing
End Sub

使用法：

Sub CopySelection()
    CopyText Selection.Text
End Sub
89
Jroonk

最も簡単な（Win32以外の）方法は、VBAプロジェクトにUserFormを追加する（まだ持っていない場合）か、またはMicrosoft Forms 2 Object Libraryへの参照を追加してから、シート/簡単にできるモジュール：

With New MSForms.DataObject
    .SetText "http://zombo.com"
    .PutInClipboard
End With
20
Alex K.

URLがワークブックのセルにある場合、そのセルから値を単純にコピーできます。

Private Sub CommandButton1_Click()
    Sheets("Sheet1").Range("A1").Copy
End Sub

（開発者タブを使用してボタンを追加します。表示されない場合は、リボンをカスタマイズします。）

URLがブックにない場合は、Windows APIを使用できます。次のコードはここにあります： http://support.Microsoft.com/kb/210216

以下のAPI呼び出しを追加したら、ボタンの背後にあるコードを変更してクリップボードにコピーします。

Private Sub CommandButton1_Click()
    ClipBoard_SetData ("http:\\stackoverflow.com")
End Sub

ワークブックに新しいモジュールを追加し、次のコードを貼り付けます。

Option Explicit

Declare Function GlobalUnlock Lib "kernel32" (ByVal hMem As Long) _
   As Long
Declare Function GlobalLock Lib "kernel32" (ByVal hMem As Long) _
   As Long
Declare Function GlobalAlloc Lib "kernel32" (ByVal wFlags As Long, _
   ByVal dwBytes As Long) As Long
Declare Function CloseClipboard Lib "User32" () As Long
Declare Function OpenClipboard Lib "User32" (ByVal hwnd As Long) _
   As Long
Declare Function EmptyClipboard Lib "User32" () As Long
Declare Function lstrcpy Lib "kernel32" (ByVal lpString1 As Any, _
   ByVal lpString2 As Any) As Long
Declare Function SetClipboardData Lib "User32" (ByVal wFormat _
   As Long, ByVal hMem As Long) As Long

Public Const GHND = &H42
Public Const CF_TEXT = 1
Public Const MAXSIZE = 4096

Function ClipBoard_SetData(MyString As String)
   Dim hGlobalMemory As Long, lpGlobalMemory As Long
   Dim hClipMemory As Long, X As Long

   ' Allocate moveable global memory.
   '-------------------------------------------
   hGlobalMemory = GlobalAlloc(GHND, Len(MyString) + 1)

   ' Lock the block to get a far pointer
   ' to this memory.
   lpGlobalMemory = GlobalLock(hGlobalMemory)

   ' Copy the string to this global memory.
   lpGlobalMemory = lstrcpy(lpGlobalMemory, MyString)

   ' Unlock the memory.
   If GlobalUnlock(hGlobalMemory) <> 0 Then
      MsgBox "Could not unlock memory location. Copy aborted."
      GoTo OutOfHere2
   End If

   ' Open the Clipboard to copy data to.
   If OpenClipboard(0&) = 0 Then
      MsgBox "Could not open the Clipboard. Copy aborted."
      Exit Function
   End If

   ' Clear the Clipboard.
   X = EmptyClipboard()

   ' Copy the data to the Clipboard.
   hClipMemory = SetClipboardData(CF_TEXT, hGlobalMemory)

OutOfHere2:

   If CloseClipboard() = 0 Then
      MsgBox "Could not close Clipboard."
   End If

End Function
8
Jon Crowell

Microsoft Forms 2.0 Object Libraryへの参照を追加して、このコードを試してください。テキストでのみ機能し、他のデータ型では機能しません。

Dim DataObj As New MSForms.DataObject

'Put a string in the clipboard
DataObj.SetText "Hello!"
DataObj.PutInClipboard

'Get a string from the clipboard
DataObj.GetFromClipboard
Debug.Print DataObj.GetText

こちら VBAでクリップボードを使用する方法の詳細を確認できます。

7
stenci

イミディエイトウィンドウを使用してクリップボードに変数の値を配置する場合、次の1行を使用してコードにブレークポイントを簡単に配置できます。

Set MSForms_DataObject = CreateObject("new:{1C3B4210-F441-11CE-B9EA-00AA006B1A69}"): MSForms_DataObject.SetText VARIABLENAME: MSForms_DataObject.PutInClipboard: Set MSForms_DataObject = Nothing
4
F_Face

貼り付ける場所にテーブルの書式設定（ブラウザのURLバーなど）の貼り付けに問題がない場合、最も簡単な方法は次のとおりです。

Sheets(1).Range("A1000").Value = string
Sheets(1).Range("A1000").Copy
MsgBox "Paste before closing this dialog."
Sheets(1).Range("A1000").Value = ""
0
Maycow Moura