web-dev-qa-db-ja.com

Excelで最も近い15分の間隔に時間を丸める

特定のイベントの日付と時刻を含む列を含むExcelスプレッドシートがあります。この期間のイベントの総数をカウントできるように、これを最も近い15分の間隔に丸めたいと思います。丸めを行う最善の方法は何ですか？

exceldatetimerounding
17
macleojw

あなたは日付も欲しいと言ったので、これはどうですか？

= (ROUND((A1 * 1440) / 15, 0) * 15) / 1440

A1に必要な日付/時刻値があると仮定します。これは、Excelの日付/時刻の列が単なる数値であるという事実を利用しています（整数部分は日付、小数部分は時間です）

22
David

ニアレスト15に丸めたい場合：

あなたの時間がセルA2にあると仮定します

新しい時間をB2に入れます。

B2 =TIME(HOUR(A2), ROUND((MINUTE(A2)/60)*4, 0) * 15, 0)

常に切り上げまたは切り捨てが必要な場合は、ROUNDをROUNDUPまたはROUNDDOWNに置き換えます

7
databyss

シンプル：

  • 切り上げた場合= CEILING（A1、 "00:15"）
  • 切り捨てた場合= FLOOR（A1、 "00:15"）

ここで、A1は2つの時間の差です。参照または計算にすることができます：=CEILING(C2-B2,"00:15")、ここでC2は終了時間、B2は開始時間です。

7
SoteR

mroundは時間値を文字列として受け取るので、

=mround(a1,"0:15")

私はこれが最も短くて明確な方法だと思います。

4
pooroldpedro

Excel 2007と分析アドインで利用できる便利な関数MROUNDを見つけました。

あなたの時間がB2であり、8.43のような数字が8時間25.8分を表すと仮定します。

=MROUND(MOD(B2,1)*60,15)

mOD（B2,1）は、フラクショナル0.43を抽出します。 * 60は25.8に変換されます。 MROUNDは、最も近い15の倍数、つまり30にあなたを丸めます。

3
rajah9

最も近い15分の期間に丸められた日付と時刻（INTなどを使用して、常に切り上げ/切り捨てができます）：

=DATE(YEAR(B1),MONTH(B1),DAY(B1))+TIME(HOUR(B1), ROUND(MINUTE(B1)/15,0)*15, 0)

セルB1に丸められる日付時刻が含まれていると仮定します。これは、典型的なシリアル日付形式で数値を返します（例：39846.64444 = 02/02/2009 15:28）。値を表示するには、結果セルを日付/時刻としてフォーマットする必要があります（この問題のすべてのソリューションと同様）。日付と時刻を一緒に表示することは標準の日付または時刻の形式ではありません。これを行うにはカスタム形式が必要です。

3
Joel Goodwin

2つの日時があり、合計を見つけて、最も近い15分に切り上げたいとします。

A1 = 7/10/2014 16:10    
A2 = 7/10/2014 17:49

最初に、10進数の時間で合計を取得します。

A3:   =(A2-A1)*24

次に、最も近い15分に切り上げることができます。

A4:  =Ceiling(A3, .25)

または、1つのセルですべて実行します。

A3:  =Ceiling((A2-A1)*24, .25)
2
Eric

時間がセルA1にある場合：

=ROUND(A1*(24*60/15),0)/(24*60/15)

（最も近い15分の増分に丸めます）

または

=INT(A1*(24*60/15),0)/(24*60/15)

（最後の15分の増分に切り捨て）

1
JDunkerley

よりシンプル??

= B2-MOD（B2,15/24/60）

Excelの場合、1日= 24時間= 1
15/24/60（= 0.0104166666666667）は、15分の相当する数値です。

0
Patrick Honorez

複雑にしないでおく。最も近い15分の間隔に丸めます。

= ROUND(B2 * 24 * 4, 0) / 4 / 24
0
IvanD

これは私のために働いた

=CEILING(((MOD(D16-C16;1))*24);0,25)

最初に、C16とD16の2つの異なる時間の時間差を時間単位で計算します。次に切り上げます。

0
user3481381