web-dev-qa-db-ja.com

Outlookで特定のExcel範囲を貼り付ける

自動化するExcelレポートに取り組んでいますが、セルの範囲がOutlookに貼り付けられていません。

ここに私のコードがあります：

Sub Mail_Selection_Range_Outlook_Body()

Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object

Set rng = Nothing
On Error Resume Next
' Only send the visible cells in the selection.
Set rng = Selection.SpecialCells(xlCellTypeVisible)
Set rng = Sheets("Sheet1").RangeToHtml("D4:D12").SpecialCells(xlCellTypeVisible, xlTextValues)
On Error GoTo 0

If rng Is Nothing Then
    MsgBox "The selection is not a range or the sheet is protected. " & _
           vbNewLine & "Please correct and try again.", vbOKOnly
    Exit Sub
End If

With Application
    .EnableEvents = False
    .ScreenUpdating = False
End With

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)

On Error Resume Next
With OutMail
    .To = ThisWorkbook.Sheets("Sheet2").Range("C1").Value
    .CC = ""
    .BCC = ""
    .Subject = "This is the Subject line"
    .HTMLBody = RangeToHtml.rng
    ' In place of the following statement, you can use ".Display" to
    ' display the e-mail message.
    .Display
End With
On Error GoTo 0

With Application
    .EnableEvents = True
    .ScreenUpdating = True
End With

Set OutMail = Nothing
Set OutApp = Nothing
End Sub

エラーは発生していません。Outlookに範囲を貼り付けていないだけです。ありがとうございました。

excelvbaexcel-vbaoutlook
6
Gilbert Jacob

まず、RangeToHTML。スクリプトはmethodのように呼び出しますが、そうではありません。 MVP Ron de Bruin による人気の関数です。偶然にも、それらのリンクは、それらの数行が変更される前に、投稿したスクリプトの正確なソースを指します。

Range.SpecialCells でオン。このメソッドは範囲で動作し、指定された基準に一致するセルのみを返します。あなたの場合、あなたは目に見えるテキストセルにのみ興味があるようです。重要なのは、HTMLテキストではなく、Rangeで動作することです。

完全を期すために、以下のスクリプトの作業バージョンを投稿します。私は確かにそれを無視して、Ron the Bruinによる素晴らしいオリジナルを再訪することを勧めます。

Sub Mail_Selection_Range_Outlook_Body()

Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object

Set rng = Nothing
' Only send the visible cells in the selection.

Set rng = Sheets("Sheet1").Range("D4:D12").SpecialCells(xlCellTypeVisible)

If rng Is Nothing Then
    MsgBox "The selection is not a range or the sheet is protected. " & _
           vbNewLine & "Please correct and try again.", vbOKOnly
    Exit Sub
End If

With Application
    .EnableEvents = False
    .ScreenUpdating = False
End With

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)


With OutMail
    .To = ThisWorkbook.Sheets("Sheet2").Range("C1").Value
    .CC = ""
    .BCC = ""
    .Subject = "This is the Subject line"
    .HTMLBody = RangetoHTML(rng)
    ' In place of the following statement, you can use ".Display" to
    ' display the e-mail message.
    .Display
End With
On Error GoTo 0

With Application
    .EnableEvents = True
    .ScreenUpdating = True
End With

Set OutMail = Nothing
Set OutApp = Nothing
End Sub


Function RangetoHTML(rng As Range)
' By Ron de Bruin.
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close savechanges:=False

    'Delete the htm file we used in this function
    Kill TempFile

    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function
17
Paul-Jan

多くの場合、この質問はRon de BruinのRangeToHTML関数のコンテキストで尋ねられます。この関数はExcel.RangeからHTML PublishObjectを作成し、FSOを介してそれを抽出し、結果のストリームHTMLをメールのHTMLBodyに。その際、デフォルトの署名が削除されます（RangeToHTML関数には、デフォルトの署名を挿入しようとするヘルパー関数GetBoilerがあります）。

残念ながら、文書化が不十分なApplication.CommandBarsメソッドはOutlook経由では利用できません。

wdDoc.Application.CommandBars.ExecuteMso "PasteExcelTableSourceFormatting"

ランタイム6158が発生します。

enter image description here

ただし、Word.Documentメソッドを介してアクセスできるMailItem.GetInspectorを引き続き利用できます。このようなことを行うと、デフォルトの署名を保持しながら、ExcelからOutlookメール本文に選択範囲をコピーアンドペーストできます（ 1であります）。

Dim rng as Range
Set rng = Range("A1:F10") 'Modify as needed

With OutMail
    .To = "[email protected]"
    .BCC = ""
    .Subject = "Subject"
    .Display
    Dim wdDoc As Object     '## Word.Document
    Dim wdRange As Object   '## Word.Range
    Set wdDoc = OutMail.GetInspector.WordEditor
    Set wdRange = wdDoc.Range(0, 0)
    wdRange.InsertAfter vbCrLf & vbCrLf
    'Copy the range in-place
    rng.Copy
    wdRange.Paste
End With

場合によっては列の幅や行の高さを完全に保持できない場合があり、Excel範囲内の図形やその他のオブジェクトもコピーしますが、これによりファンキーな配置の問題が発生する場合がありますが、単純なテーブルとExcelの範囲、それは非常に良いです：

enter image description here

2
David Zemens