web-dev-qa-db-ja.com

CWDがリモートファイルシステム上にある場合、zshのバージョン管理統合を選択的に無効にするにはどうすればよいですか？

OSXでzshを実行していますが、マウントされたsshfsボリュームで作業する必要がある場合があります。ただし、gitはsshfsマウントよりも非常に低速です。私のプロンプトは、zshが組み込みで提供するvcモードのものを利用しますが、この場合、その部分をスキップしたいと思います。

CWDがマウントされたファイルシステム上にあるときはいつでも、vc統合を選択的に無効にしたいのですが。どうやってやるの？

私は現在、私の.zshrcのこのスニペットを（大まかに）使用してプロンプトでgit情報を有効にしています（まあ、.oh-my-zsh/themesですが、あなたは考えを理解します）：

zstyle ':vcs_info:*' enable hg git bzr svn p4

zstyle ':vcs_info:(hg*|git*):*' get-revision true
zstyle ':vcs_info:(hg*|git*):*' check-for-changes true

# rev+changes branch misc
zstyle ':vcs_info:hg*' formats "[%i%u %b%m]"
zstyle ':vcs_info:hg*' actionformats "(%{$fg_bold[red]%}%a%{$reset_color%})[%i%u %b%m]"

# hash changes branch misc
zstyle ':vcs_info:git*' formats "[%{$fg[yellow]%}%12.12i%{$reset_color%} %u %{$fg[Magenta]%}%b%{$reset_color%}%m]"
zstyle ':vcs_info:git*' actionformats "(%a)[%{$fg[yellow]%}%12.12i%{$reset_color%} %u %{$fg[Magenta]%}%b%{$reset_color%}%m]"

zstyle ':vcs_info:git*+set-message:*' hooks git-st git-stash

zstyle ':vcs_info:hg*:netbeans' use-simple true

zstyle ':vcs_info:hg*:*' get-bookmarks true

zstyle ':vcs_info:hg*:*' get-mq true
zstyle ':vcs_info:hg*:*' get-unapplied true
zstyle ':vcs_info:hg*:*' patch-format " mq(%g):%{$fg[green]%}%n%{$reset_color%}/%{$fg_bold[blue]%}%c%{$reset_color%} %{$fg[green]%}%p%{$reset_color%}"
zstyle ':vcs_info:hg*:*' nopatch-format ""

zstyle ':vcs_info:hg*:*' unstagedstr " ?"
zstyle ':vcs_info:hg*:*' hgrevformat "%{$fg[yellow]%}%r%{$reset_color%}" # only show local rev.
zstyle ':vcs_info:hg*:*' branchformat "%{$fg[Magenta]%}%b%{$reset_color%}" # only show branch

# Show remote ref name and number of commits ahead-of or behind
function +vi-git-st() {
    local ahead behind remote
    local -a gitstatus

    # Are we on a remote-tracking branch?
    remote=${$(git rev-parse --verify ${hook_com[branch]}@{upstream} \
        --symbolic-full-name 2>/dev/null)/refs\/remotes\/}

    if [[ -n ${remote} ]] ; then
        # for git prior to 1.7
        # ahead=$(git rev-list Origin/${hook_com[branch]}..HEAD | wc -l)
        ahead=$(git rev-list ${hook_com[branch]}@{upstream}..HEAD 2>/dev/null | wc -l | tr -s ' ')
        (( $ahead )) && gitstatus+=( " ${c3}+${ahead}${c2}" )

        # for git prior to 1.7
        # behind=$(git rev-list HEAD..Origin/${hook_com[branch]} | wc -l)
        behind=$(git rev-list HEAD..${hook_com[branch]}@{upstream} 2>/dev/null | wc -l | tr -s ' ')
        (( $behind )) && gitstatus+=( " ${c4}-${behind}${c2}" )

        hook_com[branch]="${hook_com[branch]} [${remote}${(j:/:)gitstatus}]"
    fi
}

# Show count of stashed changes
function +vi-git-stash() {
    local -a stashes

    if [[ -s ${hook_com[base]}/.git/refs/stash ]] ; then
        stashes=$(git stash list 2>/dev/null | wc -l)
        hook_com[misc]+=" (${stashes} stashed)"
    fi
}

precmd () { vcs_info }
Prompt='
%{$(get_Prompt_user_color)%}%n%{$reset_color%} at %{$(get_Prompt_Host_color)%}%m%{$reset_color%} in %{$fg_bold[green]%}%~%{$reset_color%} ${vcs_info_msg_0_}
$(virtualenv_info)$(Prompt_char) '
gitversion-controlzshoh-my-zsh
16
Chris R

Version-Control-Information をご覧ください

'disable-patterns'のセクションを検索します（ページの約20％下）。
リモートマウントが固定されているか、比較的固定されている、つまり/mnt/remote/*であるか、すべてをリストできると仮定すると、それらの正規表現を思い付くことができるはずです。

リンクの例は、次の方法でvcs_infoの下の~/.zsh/を無効にすることです。

zstyle ':vcs_info:*' disable-patterns "$HOME/.zsh(|/*)"

Zshrcまたは同等の（申し訳ありませんが-bashユーザー）が起動時に（または定期的に、または...）リモートであるかを把握し、それに応じてzstyleを更新できると思います。

9
Brett Procter