web-dev-qa-db-ja.com

シェルコマンドを実行するGroovy

GroovyはexecuteメソッドをStringに追加して、シェルの実行をかなり簡単にします。

println "ls".execute().text

しかし、エラーが発生した場合、結果の出力はありません。 標準エラーと標準出力の両方を取得する簡単な方法はありますか？（大量のコードを作成する以外に、2つのスレッドを作成して両方の入力ストリームを読み取り、親ストリームを使用してそれらを待機します）完了したら、文字列をテキストに変換しますか？）

次のようなものがあるといいでしょう。

 def x = shellDo("ls /tmp/NoFile")
 println "out: ${x.out} err:${x.err}"
groovy
147
Bob Herrmann

OK、自分で解決しました。

def sout = new StringBuilder(), serr = new StringBuilder()
def proc = 'ls /badDir'.execute()
proc.consumeProcessOutput(sout, serr)
proc.waitForOrKill(1000)
println "out> $sout err> $serr"

ディスプレイ：

out> err> ls: cannot access /badDir: No such file or directory

163
Bob Herrmann

"ls".execute()はProcessオブジェクトを返すため、"ls".execute().textが機能します。エラーストリームを読み取るだけで、エラーが発生したかどうかを判断できるはずです。

Processには、StringBufferを渡してテキストを取得するための追加メソッドconsumeProcessErrorStream(StringBuffer error)があります。

例：

def proc = "ls".execute()
def b = new StringBuffer()
proc.consumeProcessErrorStream(b)

println proc.text
println b.toString()
39
Joshua
// a wrapper closure around executing a string                                  
// can take either a string or a list of strings (for arguments with spaces)    
// prints all output, complains and halts on error                              
def runCommand = { strList ->
  assert ( strList instanceof String ||
           ( strList instanceof List && strList.each{ it instanceof String } ) \
)
  def proc = strList.execute()
  proc.in.eachLine { line -> println line }
  proc.out.close()
  proc.waitFor()

  print "[INFO] ( "
  if(strList instanceof List) {
    strList.each { print "${it} " }
  } else {
    print strList
  }
  println " )"

  if (proc.exitValue()) {
    println "gave the following error: "
    println "[ERROR] ${proc.getErrorStream()}"
  }
  assert !proc.exitValue()
}
27
mholm815

上記の回答にもう1つの重要な情報を追加するには-

プロセス用

def proc = command.execute();

常に使用してみてください

def outputStream = new StringBuffer();
proc.waitForProcessOutput(outputStream, System.err)
//proc.waitForProcessOutput(System.out, System.err)

のではなく

def output = proc.in.text;

後者はブロッキング呼び出しであるため、groovyでコマンドを実行した後に出力をキャプチャします（ SOの質問 ）。

19
Aniket Thakur

私はこれをより慣用的に見つけます：

def proc = "ls foo.txt doesnotexist.txt".execute()
assert proc.in.text == "foo.txt\n"
assert proc.err.text == "ls: doesnotexist.txt: No such file or directory\n"

別の投稿が言及しているように、これらはブロッキング呼び出しです。しかし、出力を処理したいので、これが必要になるかもしれません。

15
solstice333
def exec = { encoding, execPath, execStr, execCommands ->

def outputCatcher = new ByteArrayOutputStream()
def errorCatcher = new ByteArrayOutputStream()

def proc = execStr.execute(null, new File(execPath))
def inputCatcher = proc.outputStream

execCommands.each { cm ->
    inputCatcher.write(cm.getBytes(encoding))
    inputCatcher.flush()
}

proc.consumeProcessOutput(outputCatcher, errorCatcher)
proc.waitFor()

return [new String(outputCatcher.toByteArray(), encoding), new String(errorCatcher.toByteArray(), encoding)]

}

def out = exec("cp866", "C:\\Test", "cmd", ["cd..\n", "dir\n", "exit\n"])

println "OUT:\n" + out[0]
println "ERR:\n" + out[1]
5
emles-kz
command = "ls *"

def execute_state=sh(returnStdout: true, script: command)

しかし、コマンドが失敗した場合、プロセスは終了します

0
舒何伟