web-dev-qa-db-ja.com

不規則な穴タイプの解決

私は最近、プルーフのパターンマッチングと組み合わせたタイプホールがHaskellでかなり素敵なAgdaのような体験を提供することを発見しました。例えば：

{-# LANGUAGE
    DataKinds, PolyKinds, TypeFamilies, 
    UndecidableInstances, GADTs, TypeOperators #-}

data (==) :: k -> k -> * where
    Refl :: x == x

sym :: a == b -> b == a
sym Refl = Refl 

data Nat = Zero | Succ Nat

data SNat :: Nat -> * where
    SZero :: SNat Zero
    SSucc :: SNat n -> SNat (Succ n)

type family a + b where
    Zero   + b = b
    Succ a + b = Succ (a + b)

addAssoc :: SNat a -> SNat b -> SNat c -> (a + (b + c)) == ((a + b) + c)
addAssoc SZero b c = Refl
addAssoc (SSucc a) b c = case addAssoc a b c of Refl -> Refl

addComm :: SNat a -> SNat b -> (a + b) == (b + a)
addComm SZero SZero = Refl
addComm (SSucc a) SZero = case addComm a SZero of Refl -> Refl
addComm SZero (SSucc b) = case addComm SZero b of Refl -> Refl
addComm sa@(SSucc a) sb@(SSucc b) =
    case addComm a sb of
        Refl -> case addComm b sa of
            Refl -> case addComm a b of
                Refl -> Refl

本当に素晴らしいのは、Refl -> exp構造の右側を型穴に置き換えることができ、穴のターゲット型がrewriteフォームとほぼ同じように証明で更新されることです。アグダで。

ただし、穴の更新に失敗する場合があります。

(+.) :: SNat a -> SNat b -> SNat (a + b)
SZero   +. b = b
SSucc a +. b = SSucc (a +. b)
infixl 5 +.

type family a * b where
    Zero   * b = Zero
    Succ a * b = b + (a * b)

(*.) :: SNat a -> SNat b -> SNat (a * b)
SZero   *. b = SZero
SSucc a *. b = b +. (a *. b)
infixl 6 *.

mulDistL :: SNat a -> SNat b -> SNat c -> (a * (b + c)) == ((a * b) + (a * c))
mulDistL SZero b c = Refl
mulDistL (SSucc a) b c = 
    case sym $ addAssoc b (a *. b) (c +. a *. c) of
        -- At this point the target type is
        -- ((b + c) + (n * (b + c))) == (b + ((n * b) + (c + (n * c))))
        -- The next step would be to update the RHS of the equivalence:
        Refl -> case addAssoc (a *. b) c (a *. c) of
            Refl -> _ -- but the type of this hole remains unchanged...

また、ターゲットタイプが必ずしもプルーフ内に並んでいるとは限りませんが、Agdaからすべてを貼り付けると、正常にチェックされます。

mulDistL' :: SNat a -> SNat b -> SNat c -> (a * (b + c)) == ((a * b) + (a * c))
mulDistL' SZero b c = Refl
mulDistL' (SSucc a) b c = case
    (sym $ addAssoc b (a *. b) (c +. a *. c),
    addAssoc (a *. b) c (a *. c),
    addComm (a *. b) c,
    sym $ addAssoc c (a *. b) (a *. c),
    addAssoc b c (a *. b +. a *. c),
    mulDistL' a b c
    ) of (Refl, Refl, Refl, Refl, Refl, Refl) -> Refl

なぜこれが起こるのか（または私が堅牢な方法で証明の書き換えを行う方法）について何か考えがありますか？

haskelldependent-type
105
András Kovács

そのような可能なすべての値を生成したい場合は、提供された境界または指定された境界のいずれかを使用して、生成する関数を作成できます。

タイプレベルのチャーチ数値などを使用してこれらの作成を強制することは非常に可能かもしれませんが、おそらくあなたが望む/必要とするものにはほとんど間違いなく多すぎる作業です。

これはあなたが望むものではないかもしれません（つまり、「z = 5 --x --yなので（x、y）だけを使用することを除いて」）が、有効を許可するために型レベルで何らかの強制的な制限を試みるよりも理にかなっています値。

1
Billykart