web-dev-qa-db-ja.com

Inno Setup：以前にインストールしたバージョンを自動的にアンインストールする方法は？

Inno Setupを使用してインストーラーを作成しています。

インストーラーに、上書きするのではなく、以前にインストールしたバージョンを自動的にアンインストールしてほしい。どうやってやるの？

installerinno-setup
81
Vimvq1987

AppId（つまり、[Setup]-セクションのAppIDに使用した値）を指定すると、レジストリからアンインストール文字列を読み取ることができるはずです。 Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\（HKLMまたはHKCUのいずれかであるため、両方を確認することをお勧めします）で、{AppId}を実際の値に置き換える必要があります。 UninstallStringまたはQuietUninstallString値を探し、Exec関数を使用してInitializeSetup()イベント関数から実行します。

更新：[Run]- sectionエントリと{uninstallexe}を使用して動作しない代替ソリューションを削除-これを指摘したすべてのコメント者に感謝します！

25
Oliver Giesen

以下を使用しました。それが最も簡単な方法だとは思いませんが、うまくいきます。

これは、Inno Setup Preprocessorに依存する{#emit SetupSetting("AppId")}を使用します。それを使用しない場合は、アプリIDを直接カットアンドペーストしてください。

[Code]

/////////////////////////////////////////////////////////////////////
function GetUninstallString(): String;
var
  sUnInstPath: String;
  sUnInstallString: String;
begin
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;


/////////////////////////////////////////////////////////////////////
function IsUpgrade(): Boolean;
begin
  Result := (GetUninstallString() <> '');
end;


/////////////////////////////////////////////////////////////////////
function UnInstallOldVersion(): Integer;
var
  sUnInstallString: String;
  iResultCode: Integer;
begin
// Return Values:
// 1 - uninstall string is empty
// 2 - error executing the UnInstallString
// 3 - successfully executed the UnInstallString

  // default return value
  Result := 0;

  // get the uninstall string of the old app
  sUnInstallString := GetUninstallString();
  if sUnInstallString <> '' then begin
    sUnInstallString := RemoveQuotes(sUnInstallString);
    if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
      Result := 3
    else
      Result := 2;
  end else
    Result := 1;
end;

/////////////////////////////////////////////////////////////////////
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if (CurStep=ssInstall) then
  begin
    if (IsUpgrade()) then
    begin
      UnInstallOldVersion();
    end;
  end;
end;

代替案

このブログ投稿「バージョン比較用のInnoセットアップスクリプトのサンプル」 を参照してください。 。

103
Craig McQueen

Inno Setupを使用する場合、以前のバージョンが別のインストーラープログラムによってインストールされない限り、以前のバージョンをアンインストールする理由はありません。それ以外の場合、アップグレードは自動的に処理されます。

7
mlaan

「古いアイコンを削除したいだけ」（変更/更新されているため）の場合、これを使用できます。

; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;

これは「インストールの開始時に」実行されるため、基本的に古いアイコンが削除され、完全に完了した後も新しいアイコンがそこにインストールされます。

「何か変更があった場合」アイコンごとにインストールするたびにこれを行います（とにかくすべてが再インストールされます）。

6
rogerdpack

クレイグマックイーンが提供する答えは完全に実行可能です。ただし、これらのコメントを追加します。

  • {#emit SetupSetting("AppId")}コードは機能しないため、アプリIDを追加するだけです。
  • アンインストーラーによって削除されるAppData /フォルダーにINI configファイルが保存されており、消去されたくないため、アンインストールプログラムを実行したくありませんでした。そのため、Craig McQueenが提供するコードを少し変更して、プログラムのパスを取得した後、プログラムがインストールされているディレクトリを削除しました。

したがって、Craig McQueenのコードに関して、変更点は次のとおりです。

  • InstallLocationキーの代わりにUninstallStringキーを取得します。
  • Exec(sUnInstallString, ...)の代わりにDelTree関数を使用します
2
user650022

上記のGetUninstallString()を使用してCurStepChanged()内のアンインストールを強制し、ディスクキャッシュの問題がある場合は、アンインストーラーexeのインストール後、しばらく待ってから実際に待機する関連ソリューションを参照してください。削除されます！

inno-setupでのディスクキャッシュの問題？

1
fubar

[code]セクションでアンインストーラーを実行できます。既存のアンインストーラーへのパスを取得する方法を理解する必要があります。アプリをインストールするときに簡単にするために、アンインストーラーを含むフォルダーを指すレジストリ文字列値を追加し、InitializeWizardコールバックでアンインストーラーを実行します。

Innoセットアップアンインストーラーの名前はすべてuninsnnn.exeの形式であることに注意してください。コード内でそれを考慮する必要があります。

0
Jim In Texas

私は@Crain Mc-Queenコードを編集しましたが、別のプロジェクトで変更する必要がないため、このコードの方が良いと思います：

[Code]
function GetNumber(var temp: String): Integer;
var
  part: String;
  pos1: Integer;
begin
  if Length(temp) = 0 then
  begin
    Result := -1;
    Exit;
  end;
    pos1 := Pos('.', temp);
    if (pos1 = 0) then
    begin
      Result := StrToInt(temp);
    temp := '';
    end
    else
    begin
    part := Copy(temp, 1, pos1 - 1);
      temp := Copy(temp, pos1 + 1, Length(temp));
      Result := StrToInt(part);
    end;
end;

function CompareInner(var temp1, temp2: String): Integer;
var
  num1, num2: Integer;
begin
    num1 := GetNumber(temp1);
  num2 := GetNumber(temp2);
  if (num1 = -1) or (num2 = -1) then
  begin
    Result := 0;
    Exit;
  end;
      if (num1 > num2) then
      begin
        Result := 1;
      end
      else if (num1 < num2) then
      begin
        Result := -1;
      end
      else
      begin
        Result := CompareInner(temp1, temp2);
      end;
end;

function CompareVersion(str1, str2: String): Integer;
var
  temp1, temp2: String;
begin
    temp1 := str1;
    temp2 := str2;
    Result := CompareInner(temp1, temp2);
end;

function InitializeSetup(): Boolean;
var
  oldVersion: String;
  uninstaller: String;
  ErrorCode: Integer;
  vCurID      :String;
  vCurAppName :String;
begin
  vCurID:= '{#SetupSetting("AppId")}';
  vCurAppName:= '{#SetupSetting("AppName")}';
  //remove first "{" of ID
  vCurID:= Copy(vCurID, 2, Length(vCurID) - 1);
  //
  if RegKeyExists(HKEY_LOCAL_MACHINE,
    'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1') then
  begin
    RegQueryStringValue(HKEY_LOCAL_MACHINE,
      'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
      'DisplayVersion', oldVersion);
    if (CompareVersion(oldVersion, '{#SetupSetting("AppVersion")}') < 0) then      
    begin
      if MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. Continue to use this old version?',
        mbConfirmation, MB_YESNO) = IDYES then
      begin
        Result := False;
      end
      else
      begin
          RegQueryStringValue(HKEY_LOCAL_MACHINE,
            'SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\' + vCurID + '_is1',
            'UninstallString', uninstaller);
          ShellExec('runas', uninstaller, '/SILENT', '', SW_HIDE, ewWaitUntilTerminated, ErrorCode);
          Result := True;
      end;
    end
    else
    begin
      MsgBox('Version ' + oldVersion + ' of ' + vCurAppName + ' is already installed. This installer will exit.',
        mbInformation, MB_OK);
      Result := False;
    end;
  end
  else
  begin
    Result := True;
  end;
end;
0
MohsenB