web-dev-qa-db-ja.com

javascriptでリージョン/コード崩壊を実装する方法

Visual StudioでJavaScriptのコード崩壊の領域を実装するにはどうすればよいですか？

Javascriptに数百行ある場合は、vb/C＃のように領域でコードを折りたたむとより理解しやすくなります。

#region My Code

#endregion
javascriptvisual-studiofoldingcode-regions
125
Prasad

ここのブログエントリで説明しています およびこの MSDNの質問 。

Visual Studio 2003/2005/2008マクロを使用する必要があります。

忠実にするために、ブログエントリからコピーして貼り付けます。

  1. マクロエクスプローラーを開く
  2. 新しいマクロを作成する
  3. OutlineRegionsという名前を付けます
  4. [マクロの編集]をクリックして、次のVBコードを貼り付けます。
Option Strict Off
Option Explicit Off

Imports System
Imports EnvDTE
Imports EnvDTE80
Imports System.Diagnostics
Imports System.Collections

Public Module JsMacros

    Sub OutlineRegions()
        Dim selection As EnvDTE.TextSelection = DTE.ActiveDocument.Selection

        Const REGION_START As String = "//#region"
        Const REGION_END As String = "//#endregion"

        selection.SelectAll()
        Dim text As String = selection.Text
        selection.StartOfDocument(True)

        Dim startIndex As Integer
        Dim endIndex As Integer
        Dim lastIndex As Integer = 0
        Dim startRegions As Stack = New Stack()

        Do
            startIndex = text.IndexOf(REGION_START, lastIndex)
            endIndex = text.IndexOf(REGION_END, lastIndex)

            If startIndex = -1 AndAlso endIndex = -1 Then
                Exit Do
            End If

            If startIndex <> -1 AndAlso startIndex < endIndex Then
                startRegions.Push(startIndex)
                lastIndex = startIndex + 1
            Else
                ' Outline region ...
                selection.MoveToLineAndOffset(CalcLineNumber(text, CInt(startRegions.Pop())), 1)
                selection.MoveToLineAndOffset(CalcLineNumber(text, endIndex) + 1, 1, True)
                selection.OutlineSection()

                lastIndex = endIndex + 1
            End If
        Loop

        selection.StartOfDocument()
    End Sub

    Private Function CalcLineNumber(ByVal text As String, ByVal index As Integer)
        Dim lineNumber As Integer = 1
        Dim i As Integer = 0

        While i < index
            If text.Chars(i) = vbCr Then
                lineNumber += 1
                i += 1
            End If

            i += 1
        End While

        Return lineNumber
    End Function

End Module
  1. マクロを保存してエディターを閉じます
  2. 次に、マクロにショートカットを割り当てましょう。 [ツール]-> [オプション]-> [環境]-> [キーボード]に移動し、[表示するコマンドを含む]テキストボックスでマクロを検索します
  3. [ショートカットキーを押す]の下のテキストボックスに、目的のショートカットを入力できます。 Ctrl + M + Eを使用します。なぜかわからない-最初に入力して今すぐ使用する:)
24
user195488

Microsoftには、この機能を提供するVS 2010の拡張機能があります。

JScript Editor Extensions

52
BrianFinkel

Visual Studioの最新バージョンを使用している開発者にとって朗報

Web Essentials はこの機能に付属しています。

チェックアウト

enter image description here

注：VS 2017の場合、JavaScriptリージョン：https://marketplace.visualstudio.com/items?itemName=MadsKristensen.JavaScriptRegions =

46
Kaushik Thanki

簡単だ！

折りたたみたいセクションをマークして、

Ctrl + M + H

展開するには、左側にある「+」マークを使用します。

38
Umitk

Visual Studio 2012を使用する予定の場合、Web Essentials 2012が存在します

Visual Studio 2015を使用する予定の場合、Web Essentials 2015.が存在します

使用方法は、@ prasadの質問とまったく同じです。

32
MCSI

コードのセクションをマークし（論理ブロックに関係なく）、CTRL + M + Hを押すと、選択範囲を折りたたみおよび展開可能な領域として定義します。

25
Manish Jain

Visual Studioの JSEnhancements プラグインはこれにうまく対処します。

20
Joel Harris

A0D に感謝します。私はそれで幸運を過ごしました。 Darin Dimitrov は、JSファイルの複雑さを制限することについても良い議論をします。それでも、関数を定義に折りたたむと、ファイルの閲覧がずっと簡単になる場合があります。

一般に#regionに関しては、これは SO Question で十分にカバーされています。

より高度なコードの崩壊をサポートするために、マクロにいくつかの変更を加えました。このメソッドを使用すると、//＃regionキーワードala C＃の後に説明を追加して、次のようにコードに表示できます。

サンプルコード：

//#region InputHandler
var InputHandler = {
    inputMode: 'simple', //simple or advanced

    //#region filterKeys
    filterKeys: function(e) {
        var doSomething = true;
        if (doSomething) {
            alert('something');
        }
    },
    //#endregion filterKeys

    //#region handleInput
    handleInput: function(input, specialKeys) {
        //blah blah blah
    }
    //#endregion handleInput

};
//#endregion InputHandler

更新されたマクロ：

Option Explicit On
Option Strict On

Imports System
Imports EnvDTE
Imports EnvDTE80
Imports EnvDTE90
Imports System.Diagnostics
Imports System.Collections.Generic

Public Module JsMacros


    Sub OutlineRegions()
        Dim selection As EnvDTE.TextSelection = CType(DTE.ActiveDocument.Selection, EnvDTE.TextSelection)

        Const REGION_START As String = "//#region"
        Const REGION_END As String = "//#endregion"

        selection.SelectAll()
        Dim text As String = selection.Text
        selection.StartOfDocument(True)

        Dim startIndex As Integer
        Dim endIndex As Integer
        Dim lastIndex As Integer = 0
        Dim startRegions As New Stack(Of Integer)

        Do
            startIndex = text.IndexOf(REGION_START, lastIndex)
            endIndex = text.IndexOf(REGION_END, lastIndex)

            If startIndex = -1 AndAlso endIndex = -1 Then
                Exit Do
            End If

            If startIndex <> -1 AndAlso startIndex < endIndex Then
                startRegions.Push(startIndex)
                lastIndex = startIndex + 1
            Else
                ' Outline region ...
                Dim tempStartIndex As Integer = CInt(startRegions.Pop())
                selection.MoveToLineAndOffset(CalcLineNumber(text, tempStartIndex), CalcLineOffset(text, tempStartIndex))
                selection.MoveToLineAndOffset(CalcLineNumber(text, endIndex) + 1, 1, True)
                selection.OutlineSection()

                lastIndex = endIndex + 1
            End If
        Loop

        selection.StartOfDocument()
    End Sub

    Private Function CalcLineNumber(ByVal text As String, ByVal index As Integer) As Integer
        Dim lineNumber As Integer = 1
        Dim i As Integer = 0

        While i < index
            If text.Chars(i) = vbLf Then
                lineNumber += 1
                i += 1
            End If

            If text.Chars(i) = vbCr Then
                lineNumber += 1
                i += 1
                If text.Chars(i) = vbLf Then
                    i += 1 'Swallow the next vbLf
                End If
            End If

            i += 1
        End While

        Return lineNumber
    End Function

    Private Function CalcLineOffset(ByVal text As String, ByVal index As Integer) As Integer
        Dim offset As Integer = 1
        Dim i As Integer = index - 1

        'Count backwards from //#region to the previous line counting the white spaces
        Dim whiteSpaces = 1
        While i >= 0
            Dim chr As Char = text.Chars(i)
            If chr = vbCr Or chr = vbLf Then
                whiteSpaces = offset
                Exit While
            End If
            i -= 1
            offset += 1
        End While

        'Count forwards from //#region to the end of the region line
        i = index
        offset = 0
        Do
            Dim chr As Char = text.Chars(i)
            If chr = vbCr Or chr = vbLf Then
                Return whiteSpaces + offset
            End If
            offset += 1
            i += 1
        Loop

        Return whiteSpaces
    End Function

End Module
9
Michael La Voie

これは現在VS2017にネイティブにあります：

//#region fold this up

//#endregion

//と＃の間の空白は関係ありません。

これがどのバージョンに追加されたかは、変更ログで言及されていないためわかりません。 v15.7.3で使用できます。

2
friggle

VS 2012およびVS 2015にWebEssentialsプラグインをインストールすると、インストールできます。

http://vswebessentials.com/features/javascript

1
asteriskdothmg

Resharper を使用している場合

この写真の手順を休ませる

enter image description here 次にテンプレートエディターでこれを書いてください

  //#region $name$
$END$$SELECTION$
  //#endregion $name$

この写真のように#regionと名前を付けます enter image description here

これがお役に立てば幸いです

0
Basheer AL-MOMANI

Visual Studio 2017の場合。

    //#region Get Deactivation JS
    .
    .
    //#endregion Get Deactivation JS

これは以前は機能していなかったので、拡張機能を here からダウンロードしました

0
Charlie

地域は設定を変更せずに動作するはずです

//#region Optional Naming
    var x = 5 -0; // Code runs inside #REGION
    /* Unnecessary code must be commented out */
//#endregion

コメント領域の折りたたみを有効にするには/ ** /

/* Collapse this

*/

設定->「折りたたみ」を検索->エディター：折りたたみ戦略->「自動」から「インデント」へ。

TAGS：Node.js Nodejs Node js Javascript ES5 ECMAScriptコメント折りたたみ非表示領域Visual Studioコードvscode 2018バージョン1.2+ https://code.visualstudio.com/updates/v1_17#_folding-regions

0
4baad4

Visual Studio 2017では、これらの答えはどれもうまくいきませんでした。

VS 2017に最適なプラグイン： JavaScript Regions

例1：

enter image description here

例2：

enter image description here

テスト済みおよび承認済み：

enter image description here

0
Matheus Miranda