web-dev-qa-db-ja.com

0から始まるExcelオブジェクトと1から始まるExcelオブジェクトはどれですか？

VBAを使用してワークシートの最初のシートにアクセスするのがWorksheets（1）です。 ListBoxの最初の項目はmyListBox.List（0）です。コレクションは1ベースであると聞きましたが、それらが何であるかわかりません。 VBA配列は0ベースです。 MIDのようなExcel文字列関数は1ベースです。 0または1に基づくものに関する一般原則はありますか、またはそれぞれのリストを提供できますか？

microsoft-excel-2007vba
20
Noumenon

VBAで使用できるグループ化構成には主に3つのタイプがあり、インデックス間の違いがあります。

  • コレクション-1ベースのインデックス

    • 0ベースの例外：タブ、ページ、コントロール（ListBox、TextBox）などのユーザーフォームコレクション
    • コレクションは、論理的に関連するオブジェクトのグループ（またはリスト）を含むネイティブExcelオブジェクトです
    • 通常、複雑なオブジェクトを保持するために使用されますが、基本的なタイプも保持できます

    • Excelコレクション：

      • ワークブック、シート、範囲、形状
      • Sheets（1）はファイルの最初、Cells（1、1）は最初の行と最初の列のセルです

    • コレクションの主な利点は、名前で要素にアクセスできることです。

      • For-Eachループは非常に効率的です（配列のFor-Each処理と比較して）
      • ただし、インデックスで個々のアイテムにアクセスする方が、名前でアクセスするよりも高速です。

  • 配列-デフォルトでは0ベースですが、最初のインデックスは任意の数に変更できます（下図を参照）

    • 配列は、関連する変数のセットを含む変数です
    • 通常、Boolean、Integer、Long、String、Doubleなどのプリミティブデータ型に使用されます。

    • いったん定義されると、1種類のアイテムのみを保持します：Dim x() As Long

      • より複雑なオブジェクトを保持するには、配列をDim x() As Variantとして定義できます

      • バリアントは、ワークブック、シート、範囲、配列など、任意のタイプのオブジェクトにすることができます

        • Dim x As Variant: x = Array(1) '1 Variant variable containing 1 array
        • Dim y(2) As Variant '1 Variant array containing 3 arrays
        • y(0) = Array(1): y(1) = Array(2): y(2) = Array(3)

    • 配列の主な利点は、インデックスでアイテムにアクセスするときのパフォーマンスです

      • For index=0 To 10ループはFor-Eachループより高速です

  • 辞書-インデックスは作成されませんが、インデックスはキーでシミュレートできます

    • VBスクリプトにネイティブ、VBAではない（外部ライブラリを使用する必要がある））
    • 配列、コレクション、その他の辞書を含む、あらゆるタイプのオブジェクトを保持できます

ListBoxは複雑なオブジェクトであり、コントロールの0ベースのコレクションを介してアクセスできます

ListBoxの.List（）プロパティは0ベースの配列です

その他の注意事項

  • 0ベースのインデックスは他の言語の標準です

  • VBAは、新しいユーザーがより直感的に使用できるように、1ベースのコンセプトを導入しました。

    • Sheet1からSheet3まで。コレクション数は3より使いやすい
    • Sheet0からSheet2、コレクションカウント3

それらのインデックス間の違いのいくつかの実用的な例：

Public Sub vbaCollections()
    Dim c As New Collection     '1-based index

    c.Add Item:="a", Key:="1"   'index 1; Key must a String
    c.Add Item:="b", Key:="2"   'index 2
    c.Add Item:="c", Key:="3"   'index 3

    Debug.Print c.Count         '3;   Items in index sequence: a,b,c, Keys: "1","2","3"
    Debug.Print c.Item(1)       'a;   not available for Dictionaries
    'Debug.Print c.Key("1")     'invalid, so is: c.Key(1)

    c.Remove Index:=2
    Debug.Print c.Count         '2;   items in index sequence: a,c, Keys: "1","3"
    'c.Remove Item:="c"         'invalid, so is: c.Remove Key:="3"

    'c.Add Item:="c", Key:="3", Before:=1   'Key must be unique - Error
    c.Add Item:="c", Key:="5", Before:=1    'allows duplicate Item
    Debug.Print c.Count         '3;   items in index sequence: c,a,c, Keys: "5","1","3"
End Sub

Public Sub vbaArrays()
    Dim a() As Long, b(3) As Long   'Arrays default to "Option Base {0 | 1}"
    Dim c(0 To 0)                   'if "Option Base" not defined, it defaults to 0
    Dim ar(1) As Worksheet: Set ar(0) = Worksheets(1)   'array with 1 Worksheets object

    ReDim a(3)          'creates an array of 4 elements; indexes 0,1,2,3
        Debug.Print "LB: " & LBound(a) & ", UB: " & UBound(a)   'LB: 0, UB: 3
        Debug.Print UBound(a) - LBound(a)                       '3, array b() is the same

    'even whith "Option Base 1", the following still default to 0
    Dim v As Variant:  v = Split("A B")         'array with 2 items: v(0) = "A", v(1) = "B"
    'UserForm1.ListBox1.List = Array("Test")    'array with 1 item: .List(0,0) = "Test"

    ReDim a(0 To 3)     'creates an array of 4 elements; indexes 0,1,2,3
    a(0) = 1:   a(1) = 2:   a(2) = 3    'a(3) defaults to 0

        Debug.Print "LB: " & LBound(a) & ", UB: " & UBound(a)   'LB: 0, UB: 3
        Debug.Print UBound(a) - LBound(a)                       '3; offset index by -1

    ReDim a(1 To 3)     'creates an array of 3 elements; indexes 1,2,3
    a(1) = 1:   a(2) = 2:   a(3) = 3

        Debug.Print "LB: " & LBound(a) & ", UB: " & UBound(a)   'LB: 1, UB: 3
        Debug.Print UBound(a) - LBound(a)                       '2; offset count by +1

    ReDim a(5 To 7)     'creates an array of 3 elements; indexes 5,6,7
    a(5) = 1:   a(6) = 2:   a(7) = 3

        Debug.Print "LB: " & LBound(a) & ", UB: " & UBound(a)   'LB: 5, UB: 7
        Debug.Print UBound(a) - LBound(a)                       '2; offset count by +1

    ReDim a(-3 To -1)   'creates an array of 3 elements; indexes -3,-2,-1
    a(-3) = 1:  a(-2) = 2:  a(-1) = 3

        Debug.Print "LB: " & LBound(a) & ", UB: " & UBound(a)   'LB: -3, UB: -1
        Debug.Print UBound(a) - LBound(a)                       '2; offset count by +1
End Sub

Public Sub vbsDictionaries()
    Dim d As Object         'not indexed (similar to linked lists)
    Set d = CreateObject("Scripting.Dictionary")    'native to VB Script, not VBA

    d.Add Key:="a", Item:=1 'index is based on Key (a, b, c)
    d.Add Key:="b", Item:=2
    d.Add Key:="c", Item:=3
    Debug.Print d.Count     '3; Keys: a,b,c, Items: 1,2,3

    Debug.Print d(1)        'output is empty ("") - adds new element: Key:="1", Item:=""
    Debug.Print d.Count     '4; Keys: a,b,c,1, Items: 1,2,3,Empty
    Debug.Print d("a")      '1
    Debug.Print d(1)        'output is Empty ("") from element with Key:="1"

    'd.Add Key:="b", Item:=2        'attempt to add existing element: Key:="b" - Error

    'd.Keys  - 0-based array (not available for Collections)
    'd.Items - 0-based array (not available for Collections)

    d.Remove d.Keys()(1)            'remove element Item:=2 (Key:="b")
        Debug.Print d.Count         '3; Keys: a,c,1, Items: 1,3,""
    d.Remove d.Items()(0)           'remove Items element 0 (Key:="1", Item:="")
        Debug.Print d.Count         '2; Keys: a,c, Items: 1,3
    d.Remove "c"                    'remove element Key:="c" (Item:=3)
        Debug.Print d.Count         '1; Keys: a, Items: 1

    d.Add Key:="c", Item:=3
        Debug.Print d.Count         '2; Keys: a,c, Items: 1,3

    'd.Remove d.Items()(0)          'invalid
    Debug.Print d.Items()(d.Count - 1)  '3
    d.Remove d.Keys()(d.Count - 1)  'remove last element; access last Key by Key
        Debug.Print d.Count         '1; Keys: a, Items: 1

    Debug.Print d.Exists("a")       'True (not available for Collections)
    Debug.Print d.Exists(2)         'False
End Sub

参考文献：

24
paul bica