web-dev-qa-db-ja.com

マクロを使用してOfficeExcelテーブルをcsvにエクスポートします

Excel2010でExcelテーブルを使用しています。これらのテーブルの内容を* .csvにすばやくエクスポートしたいと思います。

現在のワークフロー：1.テーブルを手動で選択2.内容を新しいワークブックにコピー3.ワークブックを* .csvファイルとして保存

必要なワークフロー：1。テーブルを手動で選択します2.事前定義されたファイル名に書き込むマクロを実行します

テーブルには一意の名前（CurrentDataTableなど）があるため、テーブル名、ターゲットファイル、および目的の出力形式を取得して出力ファイルを書き込む関数はありますか？

microsoft-excel-2010csv
7
vg425

組み込みのExcelコマンドや関数はありませんが、VBAを使用してプログラムできます。

次のコードは、探しているものに近い可能性があります。

Sub ExportTable()

    Dim wb As Workbook, wbNew As Workbook
    Dim ws As Worksheet, wsNew As Worksheet
    Dim wbNewName As String


   Set wb = ThisWorkbook
   Set ws = ActiveSheet

   Set wbNew = Workbooks.Add

   With wbNew
       Set wsNew = wbNew.Sheets("Sheet1")
       wbNewName = ws.ListObjects(1).Name
       ws.ListObjects(1).Range.Copy
       wsNew.Range("A1").PasteSpecial Paste:=xlPasteAll
       .SaveAs Filename:=wb.Path & "\" & wbNewName & ".csv", _
             FileFormat:=xlCSVMSDOS, CreateBackup:=False
   End With

End Sub

コードは、各ワークシートに1つのテーブルがあることを前提としています。新しいワークブックを作成し、テーブルをそのワークブックのシート1にコピーして、ワークブックをテーブルと同じ名前のCSVファイルとして保存します。

5
chuff

これがExcel2013に対するchuffの回答の私のバージョンです。モーダルダイアログも無効になります。

Sub ExportCSV()

   Dim wb As Workbook, wbNew As Workbook
   Dim ws As Worksheet, wsNew As Worksheet

   Set wb = ThisWorkbook
   Set ws = ActiveSheet

   Set wbNew = Workbooks.Add
   Application.DisplayAlerts = False
   With wbNew
       Set wsNew = wbNew.Sheets("Sheet1")
       ws.Rows.Copy
       wsNew.Paste
       .SaveAs Filename:=ws.name & ".csv", FileFormat:=xlCSV, CreateBackup:=True
       wsNew.Delete
   End With
   Windows(ws.name & ".csv").Activate
   ActiveWindow.Close
   Application.DisplayAlerts = True

End Sub
3
Thorsten

同じことをする必要がありましたが、CSVファイルとしてエクスポートする必要があるテーブルを指定する必要がありました。次のようにVBAを使用して、「ExportTables」という名前の範囲を作成しました。

Public Sub Export()
    Dim i       As Integer
    Dim iMax    As Integer
    Dim sTable  As String

    iMax = Range("ExportTables").Rows.Count

    For i = 1 To iMax
        sTable = Range("ExportTables").Cells(i, 1).Value
        Call ExportTable(sTable)
    Next i
End Sub

Public Sub ExportTable(tableName As String)
    Dim wkb         As Workbook
    Dim wkbNew      As Workbook
    Dim wks         As Worksheet
    Dim wksNew      As Worksheet

    Set wkb = ThisWorkbook

    Application.Goto Reference:=tableName
    Set wks = ActiveSheet

    Set wkbNew = Workbooks.Add
    Set wksNew = wkbNew.Sheets(1)

    wks.ListObjects(tableName).Range.Copy
    wksNew.Range("A1").PasteSpecial Paste:=xlPasteValues

    Application.DisplayAlerts = False

    wkbNew.SaveAs Filename:=wkb.Path & "\" & tableName & ".csv", _
        FileFormat:=xlCSV, CreateBackup:=False
    wkbNew.Close SaveChanges:=False

    Application.DisplayAlerts = True

    ' Release object variables.
    Set wkb = Nothing
    Set wkbNew = Nothing
    Set wks = Nothing
    Set wksNew = Nothing
End Sub
1
ColinB

上記のコードから1004エラーが発生していました。Thorstenのコードで削除してください。私はそれを この例 とマージし、これを取得しました。これは私にとってはうまくいきます：

Sub ExportCSV2()

   Dim wb As Workbook, wbNew As Workbook
   Dim ws As Worksheet, wsNew As Worksheet

   Set wb = ThisWorkbook
   Set ws = ActiveSheet

   Application.DisplayAlerts = False

   ws.Copy
   ActiveWorkbook.SaveAs Filename:=ws.Name & ".csv", FileFormat:=xlCSV, CreateBackup:=True
   Windows(ws.Name & ".csv").Activate
   ActiveWorkbook.Close False
   Application.DisplayAlerts = True

End Sub

この（Thorstenの）アプローチでは、テーブルだけでなくシート全体がエクスポートされるため、多くの空の行が取得されることに注意してください。

0
Martin Morrey