web-dev-qa-db-ja.com

Word 2007のすべての相互参照に特定のスタイルを割り当てることはできますか？

追加するものは何もありません。すべてのスタイルを変更したいと思いますcross-references Word 2007文書に一度にあります。しかし、私はそれを行う方法がわかりません。これはどのように行うことができますか？

microsoft-wordmicrosoft-officemicrosoft-word-2007
35
Drake

一部の相互参照タイプは自動的に「強参照」スタイルでフォーマットされますが、ほとんどは「通常」のテキストとしてフォーマットされます。

相互参照のテキストに「強参照」スタイルを適用するには：

  • テキストを選択
  • リボンの[ホーム]タブを選択します
  • リボンの[スタイル]グループのアップダウンボタンまたはドロップダウンボタンのいずれかを使用して、[詳細な参照]スタイル（または必要に応じて別のスタイル）を選択します

特定のスタイルのすべてのテキストの外観を変更するには：

  • リボンの[ホーム]タブを選択します
  • リボンの[スタイル]グループのドロップダウンボタンを使用して、[スタイルを適用...]を選択します
  • [スタイル名]の[スタイルの適用]ダイアログボックスで、変更するスタイルの名前を選択します（例：「参照の集中」）
  • 「変更...」ボタンをクリックします
  • あなたに合うようにフォーマットを変更し、「OK」をクリックしてください

すべての相互参照にスタイルを一度に適用するには：

  • 押す Alt+F9 フィールドコードを表示するには
  • リボンの[ホーム]タブを選択します
  • 「編集」グループの「置換」をクリックします
  • [検索する文字列]フィールドに^19 REF と入力します
    • （それはキャレット-ワン-ナイン-スペース-R-E-F）
  • 「置換」フィールドをクリックしますが、何も入力しないでください
  • [もっと見る]ボタンをクリックします
  • ダイアログの下部セクションは「置換」というタイトルが付いているはずです（その後に横罫線が付きます）。
  • 「フォーマット」ボタンをクリックし、「スタイル...」を選択します
  • スタイル（「強烈な参照」など）を選択して[OK]をクリックします
  • 「置換」フィールドで選択したスタイルが表示されます。
  • 勇気がある場合は[すべて置換]をクリックするか、[次を検索]と[置換]を使用して、各参照フィールドコードのスタイルを個別にステップ実行して置換またはスキップします。
  • 押す Alt+F9 フィールドコードを非表示にする

検索と置換の特殊コードの詳細については このページ を参照してください。

以下は、各フィールドにスイッチ\* mergeformatを追加するマクロです。このスイッチは、フィールドを更新した場合にフォーマットが失われないようにするために必要です。マクロをキーストロークに割り当てることができ、キーストロークを押すたびに一度に1つずつフィールドをステップ実行します。マクロを編集してドキュメント全体をループし、プロセスを自動化することもできます。

Sub mf()
'
' mf Macro
' Find cross references and add \* mergeformat
'
    Selection.Find.ClearFormatting
    With Selection.Find
        .Text = "^19 REF"
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute
    Selection.MoveRight Unit:=wdCharacter, Count:=1
    Selection.MoveLeft Unit:=wdCharacter, Count:=1
    Selection.TypeText Text:="\* mergeformat "
    Selection.Find.Execute
End Sub
41
Paused until further notice.
  • 押す Alt+F9 フィールドコードを表示するには

  • 次のマクロを使用して、CHARFORMATをすべての相互参照に追加します。このマクロは、まだ存在しない場合にのみ、フィールドに文字列を追加します。

    Sub SetCHARFORMAT()
'
' Set CHARFORMAT switch to all {REF} fields. Replace MERGEFORMAT.
'
'
    Dim oField As Field
    Dim oRng As Range
    For Each oField In ActiveDocument.Fields
    'For Each oField In Selection.Fields
        If InStr(1, oField.Code, "REF ") = 2 Then
            If InStr(1, oField.Code, "MERGEFORMAT") <> 0 Then
                oField.Code.Text = Replace(oField.Code.Text, "MERGEFORMAT", "CHARFORMAT")
            End If
            If InStr(1, oField.Code, "CHARFORMAT") = 0 Then
                oField.Code.Text = oField.Code.Text + "\* CHARFORMAT "
            End If
        End If
    Next oField


End Sub

  • このマクロを使用して、すべての相互参照を「微妙な参照」スタイルでフォーマットします（そのようなスタイルがあり、フィールドコードが表示されていることを確認してください）。

    Sub SetCrossRefStyle()
'
' Macro to set styole of all cross references to "Subtle Reference"
'
'
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    Selection.Find.Replacement.Style = ActiveDocument.Styles( _
        "Subtle Reference")
    With Selection.Find
        .Text = "^19 REF"
        .Replacement.Text = ""
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchKashida = False
        .MatchDiacritics = False
        .MatchAlefHamza = False
        .MatchControl = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
End Sub

  • 押す Alt+F9 フィールドコードを非表示にする

5
cyborg

サイボーグによってアップロードされたマクロを編集すると、フィールドコードの表示と非表示を簡単に自動化できます。更新するたびに、トグルフィールドコードを使用する必要はありません。次のコードを使用して、フィールドコードの切り替えを追加しました。

ActiveDocument.ActiveWindow.View.ShowFieldCodes = False

完全なマクロは次のとおりです。

Sub SetCrossRefStyle()
'
' Macro to set styole of all cross references to "Subtle Reference"
'
'
ActiveDocument.ActiveWindow.View.ShowFieldCodes = True
Selection.Find.ClearFormatting
Selection.Find.Replacement.ClearFormatting
Selection.Find.Replacement.Style = ActiveDocument.Styles( _
    "Subtle Reference")
With Selection.Find
    .Text = "^19 REF"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchKashida = False
    .MatchDiacritics = False
    .MatchAlefHamza = False
    .MatchControl = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
End With
Selection.Find.Execute Replace:=wdReplaceAll
ActiveDocument.ActiveWindow.View.ShowFieldCodes = False
End Sub

Wordでの作業を高速化するためにマクロを使用するのはこれが初めてです。そんな便利なマクロをありがとうcyborg。

3
Jaykrushna patel

上記の回答を別の関数と組み合わせてドキュメントの「ストーリー」をループし、ドキュメントの本文、ヘッダー、フッター、テキストに図形のスタイルを適用します。

以下のSetCrossRefStyle（）マクロを呼び出すだけで、すべての相互参照に「強参照」スタイルが適用されます。

Sub m_SetCHARFORMAT(textRanges As Collection)
' https://superuser.com/questions/13531/is-it-possible-to-assign-a-specific-style-to-all-cross-references-in-Word-2007
'
' Set CHARFORMAT switch to all {REF} fields. Replace MERGEFORMAT.
' Requires ActiveDocument.ActiveWindow.View.ShowFieldCodes = True
'
    Dim oField As Field
    Dim oRng As Range
    For Each oRng In textRanges
        For Each oField In oRng.Fields
            If InStr(1, oField.Code, "REF ") = 2 Then
                If InStr(1, oField.Code, "MERGEFORMAT") <> 0 Then
                    oField.Code.Text = Replace(oField.Code.Text, "MERGEFORMAT", "CHARFORMAT")
                End If
                If InStr(1, oField.Code, "CHARFORMAT") = 0 Then
                    oField.Code.Text = oField.Code.Text + "\* CHARFORMAT "
                End If
            End If
        Next oField
    Next oRng
End Sub


Sub m_AddCrossRefStyle(textRanges As Collection)
' https://superuser.com/questions/13531/is-it-possible-to-assign-a-specific-style-to-all-cross-references-in-Word-2007
'
' Macro to set style of all cross references to "Intense Reference"
' Requires ActiveDocument.ActiveWindow.View.ShowFieldCodes = True
'
    For Each oRng In textRanges
        oRng.Find.ClearFormatting
        oRng.Find.Replacement.ClearFormatting
        oRng.Find.Replacement.Style = ActiveDocument.Styles("Intense Reference")
        With oRng.Find
            .Text = "^19 REF"
            .Replacement.Text = ""
            .Forward = True
            .Wrap = wdFindContinue
            .Format = True
            .MatchCase = False
            .MatchWholeWord = False
            .MatchKashida = False
            .MatchDiacritics = False
            .MatchAlefHamza = False
            .MatchControl = False
            .MatchWildcards = False
            .MatchSoundsLike = False
            .MatchAllWordForms = False
        End With
        oRng.Find.Execute Replace:=wdReplaceAll
    Next oRng
End Sub


Function m_GetAllTextRanges() As Collection
' https://wordmvp.com/FAQs/Customization/ReplaceAnywhere.htm
' https://www.mrexcel.com/forum/Excel-questions/443052-returning-collection-function.html
'
' Get text ranges in all document parts.
'
    Set m_GetAllTextRanges = New Collection
    For Each rngStory In ActiveDocument.StoryRanges
        'Iterate through all linked stories
        Do
            m_GetAllTextRanges.Add rngStory
            On Error Resume Next
            Select Case rngStory.StoryType
                Case 6, 7, 8, 9, 10, 11
                If rngStory.ShapeRange.Count > 0 Then
                    For Each oShp In rngStory.ShapeRange
                        If oShp.TextFrame.HasText Then
                            m_GetAllTextRanges.Add oShp.TextFrame.TextRange
                        End If
                    Next
                End If
                Case Else
                    'Do Nothing
            End Select
            On Error GoTo 0
            'Get next linked story (if any)
            Set rngStory = rngStory.NextStoryRange
        Loop Until rngStory Is Nothing
    Next
End Function

Sub SetCrossRefStyle()
'
' 1. Get all text ranges since Selection.Find only works on document body, but not on headers/footers
' 2. Add CHARFORMAT to make styling persistent
' 3. Add styling to all references
'
    Dim textRanges As Collection
    Set textRanges = m_GetAllTextRanges
    ActiveDocument.ActiveWindow.View.ShowFieldCodes = True
    m_SetCHARFORMAT textRanges
    m_AddCrossRefStyle textRanges
    ActiveDocument.ActiveWindow.View.ShowFieldCodes = False
End Sub
0
eymre

高速かつ効果的な方法：

  1. 参照に使用するフォーマットのテキストを選択します。
  2. リボンのHomeタブを選択します。
  3. Normalスタイルを右クリックして、-pdate Normal to Update selectionを選択します。
  4. 参照を更新 Ctrl + A、 F9。
0
Evgeny

このマクロは、相互参照ダイアログボックスを開いて、現在のカーソル位置に相互参照を挿入します。

参照の挿入後に外部参照ダイアログボックスを閉じると、マクロが再開され、挿入された相互参照が上付き文字にフォーマットされます。

Sub XrefSuper()
'
' This opens the Cross Reference dialogue box to insert a cross reference at the current cursor position.
'   When the dialogue box is closed after inserting the reference the macro resumes to format the inserted cross reference to superscript.
'
'
Dim wc As Integer
    wc = ActiveDocument.Characters.Count

Dim dlg As Dialog
    Set dlg = Dialogs(wdDialogInsertCrossReference)
        dlg.Show 'Open dialogue and perform the insertion from the dialog box) 
                 'Macro continues after closing CrossRef dialogue box

    If wc = ActiveDocument.Characters.Count Then Exit Sub   'If we failed to insert something then exit

    Selection.MoveLeft Unit:=wdCharacter, Count:=1, Extend:=wdExtend
    Selection.Font.Superscript = wdToggle
    Selection.MoveRight Unit:=wdCharacter, Count:=1
    Selection.Font.Superscript = wdToggle
End Sub

外部参照ダイアログを開く方法について Graham Skan at ExpertsExchange に感謝します。

0
TJH