web-dev-qa-db-ja.com

法線行列の計算方法は？

通常のマトリックスに問題があります。

vs.glsl

#version 440

in vec3 vPosition;
in vec3 vNormal;

out vec4 eyeCordFs;
out vec4 eyeNormalFs;

uniform mat4 model;
uniform mat4 view;
uniform mat4 proj;

void main()
{   
    mat4 modelView = view * model;
    mat4 normalMatrix = view * transpose(inverse(model));
    vec4 eyeNorm = normalize(normalMatrix * vec4(vNormal, 0.0));
    vec4 eyeCord= modelView * vec4(vPosition, 1.0);

    eyeCordFs = eyeCord;
    eyeNormalFs = eyeNorm;

    gl_Position = proj * modelView * vec4( vPosition,1.0);
}

fs.glsl

#version 440

in vec4 eyeCordFs;
in vec4 eyeNormalFs;

out vec3 outputColor;

uniform vec4 lightPos;

void main()
{
    vec4 s = normalize(lightPos - eyeCordFs) ;
    vec4 r = reflect(-s,eyeNormalFs);
    vec4 v = normalize(-eyeCordFs);
    float spec = max( dot(v,r),0.0 );
    float diff = max(dot(eyeNormalFs,s),0.0);

    vec3 diffColor = diff * vec3(1,0,0);
    vec3 specColor = pow(spec,3) * vec3(1,1,1);
    vec3 ambientColor = vec3(0.1,0.1,0.1);

    outputColor =  diffColor + 0.5 * specColor + ambientColor; 
}

この出力は次のようになります enter image description here

私には少し奇妙に思えた。しかし、私は何もスケーリングしていないことを知っていたので、modelViewマトリックスを使用して法線を変換できると考えました。

だから私は行を変更しました

vec4 eyeNorm = normalize(normalMatrix * vec4(vNormal, 0.0));

に

vec4 eyeNorm = normalize(modelView * vec4(vNormal, 0.0));

出力は次のようになります

enter image description here

正しいように見えます。 normalMatrixを間違った方法で計算していますか？

openglgraphics3dglsl
17
Maik Klein

通常の行列は、modelview行列の転置逆行列です。 GLSLでは、

mat4 normalMatrix = transpose(inverse(modelView));

ただし、[〜＃〜] not [〜＃〜]シェーダーで通常のマトリックスを計算する必要があります。シェーダーでこれを行うと、貴重なGPUサイクルの多くが無駄になります。マトリックスの反転は、最初は安価な操作ではなく、シェーダーで実行すると、GPUが各頂点の計算を何度も繰り返し実行するように強制されます。 CPUで事前計算し、ユニフォームとして渡します。

46
datenwolf