web-dev-qa-db-ja.com

OracleのPL / SQL - 単純な配列変数を作成する方法？

PL/SQLコードで使用できるメモリー内配列変数を作成したいです。純粋なメモリーを使用するコレクションをOracle PL/SQLに見つけることはできません。それらはすべてテーブルに関連付けられているようです。私はPL/SQL（C＃構文）でこのようなことをすることを考えています。

string[] arrayvalues = new string[3] {"Matt", "Joanne", "Robert"};

編集：オラクル：9i

oracleplsqloracle9i
114
contactmatt

固定サイズの配列にVARRAYを使用できます。

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t('Matt', 'Joanne', 'Robert');
begin
   for i in 1..array.count loop
       dbms_output.put_line(array(i));
   end loop;
end;

無制限配列の場合はTABLE

...
   type array_t is table of varchar2(10);
...

ここでの「テーブル」という単語は、データベーステーブルとは無関係です。どちらの方法でもメモリ内配列が作成されます。

これらのどちらでも、要素を追加する前にコレクションを初期化して拡張する必要があります。

declare
   type array_t is varray(3) of varchar2(10);
   array array_t := array_t(); -- Initialise it
begin
   for i in 1..3 loop
      array.extend(); -- Extend it
      array(i) := 'x';
   end loop;
end;

最初のインデックスは0ではなく1です。

221
Tony Andrews

DBMS_SQL.VARCHAR2_TABLEを宣言して、BINARY_INTEGERで索引付けされたメモリー内の可変長配列を保持できます。

DECLARE
   name_array dbms_sql.varchar2_table;
BEGIN
   name_array(1) := 'Tim';
   name_array(2) := 'Daisy';
   name_array(3) := 'Mike';
   name_array(4) := 'Marsha';
   --
   FOR i IN name_array.FIRST .. name_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

連想配列（以前はPL/SQL表と呼ばれていました）をメモリー内の配列として使用できます。

DECLARE
   TYPE employee_arraytype IS TABLE OF employee%ROWTYPE
        INDEX BY PLS_INTEGER;
   employee_array employee_arraytype;
BEGIN
   SELECT *
     BULK COLLECT INTO employee_array
     FROM employee
    WHERE department = 10;
   --
   FOR i IN employee_array.FIRST .. employee_array.LAST
   LOOP
      -- Do something
   END LOOP;
END;

連想配列は、レコードタイプを構成することができます。

Ollieさん、お役に立てば幸いです。

58
Ollie

別の解決策は、Oracle Collectionをハッシュマップとして使用することです。

declare 
-- create a type for your "Array" - it can be of any kind, record might be useful
  type hash_map is table of varchar2(1000) index by varchar2(30);
  my_hmap hash_map ;
-- i will be your iterator: it must be of the index's type
  i varchar2(30);
begin
  my_hmap('a') := 'Apple';
  my_hmap('b') := 'box';
  my_hmap('c') := 'crow';
-- then how you use it:

  dbms_output.put_line (my_hmap('c')) ;

-- or to loop on every element - it's a "collection"
  i := my_hmap.FIRST;

  while (i is not null)  loop     
    dbms_output.put_line(my_hmap(i));      
    i := my_hmap.NEXT(i);
  end loop;

end;
11
J. Chomel

Oracle defined collectionを使用することもできます。

DECLARE 
  arrayvalues sys.odcivarchar2list;
BEGIN
  arrayvalues := sys.odcivarchar2list('Matt','Joanne','Robert');
  FOR x IN ( SELECT m.column_value m_value
               FROM table(arrayvalues) m )
  LOOP
    dbms_output.put_line (x.m_value||' is a good pal');
  END LOOP;
END;

私はインメモリアレイを使うでしょう。しかし、uziberiaによって提案された.COUNTの改善により、

DECLARE
  TYPE t_people IS TABLE OF varchar2(10) INDEX BY PLS_INTEGER;
  arrayvalues t_people;
BEGIN
  SELECT *
   BULK COLLECT INTO arrayvalues
   FROM (select 'Matt' m_value from dual union all
         select 'Joanne'       from dual union all
         select 'Robert'       from dual
    )
  ;
  --
  FOR i IN 1 .. arrayvalues.COUNT
  LOOP
    dbms_output.put_line(arrayvalues(i)||' is my friend');
  END LOOP;
END;

別の解決策は、@ Jchomelが行ったようなハッシュマップを使用することです ここ 。

注意：

Oracle 12cでは、 今すぐ配列に直接問い合わせることも可能です ！

10
Jika