web-dev-qa-db-ja.com

Oracle PL / SQLのForループを使用して、カンマ区切りの文字列を反復処理します

文字列の内容を反復処理する必要があるコードを書いています。各値は,で区切られています。

例えば私はelementsを持っています

v_list_pak_like varchar2(4000) := 'PEBO,PTGC,PTTL,PTOP,PTA';

それを配列/カーソルに入れてループで繰り返すにはどうすればよいですか？

for x in (elements)
loop
   -- do my stuff
end loop;

連想配列の宣言をできるだけ避けて、非常に簡単な方法を探しています。

forループの入力として使用可能な何かを返す関数を作成することはできますか？ https://stackoverflow.com/a/19184203/6019417 ）のように使用できますか？

よろしくお願いします。

oraclefor-loopplsql
8
J. Chomel

純粋に[〜＃〜] sql [〜＃〜]で簡単に実行できます。それを行うには複数の方法があります、を参照してくださいコンマで区切られた文字列をOracleの行に分割してください

ただし、本当にPL/SQLで実行する場合は、次のように実行できます。

SQL> set serveroutput on
SQL> DECLARE
  2    str VARCHAR2(100) := 'PEBO,PTGC,PTTL,PTOP,PTA';
  3  BEGIN
  4    FOR i IN
  5    (SELECT trim(regexp_substr(str, '[^,]+', 1, LEVEL)) l
  6    FROM dual
  7      CONNECT BY LEVEL <= regexp_count(str, ',')+1
  8    )
  9    LOOP
 10      dbms_output.put_line(i.l);
 11    END LOOP;
 12  END;
 13  /
PEBO
PTGC
PTTL
PTOP
PTA

PL/SQL procedure successfully completed.

SQL>
17
Lalit Kumar B

Lalitのすばらしい指示のおかげで、forループから呼び出すことができる関数を作成できます。

タイプと関数を作成する

CREATE OR REPLACE TYPE t_my_list AS TABLE OF VARCHAR2(100);
CREATE OR REPLACE
       FUNCTION comma_to_table(p_list IN VARCHAR2)
         RETURN t_my_list
       AS
         l_string VARCHAR2(32767) := p_list || ',';
         l_comma_index PLS_INTEGER;
         l_index PLS_INTEGER := 1;
         l_tab t_my_list     := t_my_list();
       BEGIN
         LOOP
           l_comma_index := INSTR(l_string, ',', l_index);
           EXIT
         WHEN l_comma_index = 0;
           l_tab.EXTEND;
           l_tab(l_tab.COUNT) := TRIM(SUBSTR(l_string,l_index,l_comma_index - l_index));
           l_index            := l_comma_index + 1;
         END LOOP;
         RETURN l_tab;
       END comma_to_table;
/

次に、それを私のforループで呼び出す方法：

declare
  v_list_pak_like varchar2(4000) := 'PEBO,PTGC,PTTL,PTOP,PTA';
begin
    FOR x IN (select * from (table(comma_to_table(v_list_pak_like)) ) )
    loop
        dbms_output.put_line(x.COLUMN_VALUE);
    end loop;
end;
/

Oracleによって与えられたデフォルト名COLUMN_VALUEに注意してください。これは、結果を使用したい場合に必要です。

期待どおりの結果：

PEBO
PTGC
PTTL
PTOP
PTA
3
J. Chomel