web-dev-qa-db-ja.com

PL / SQLでのレコード表の使用

PL/SQLパッケージで次のタイプを宣言しました。

TYPE t_simple_object IS RECORD (
   wert   NUMBER,
   gs     NUMBER,
   vl     NUMBER);

TYPE t_obj_table IS TABLE OF t_simple_object
  INDEX BY BINARY_INTEGER;

次に、変数を宣言します。

obj t_obj_table;

ただし、変数を使用する場合、初期化または拡張できません。

obj := t_obj_table ();

次のエラーが発生します。

PLS-00222: no function with name 'T_OBJ_TABLE' exists in this scope

初期化しないと、日付を追加するように拡張できません。

obj.EXTEND();

別のエラーが発生します：

PLS-00306: wrong number or types of arguments in call to 'EXTEND'

どうすればこれを機能させることができますか？

oracleplsql
12
Thorsten

「何か」でインデックス付けされたテーブルを拡張するのではなく、それを使用するだけです...

DECLARE
   TYPE t_simple_object IS RECORD 
      ( wert   NUMBER
      , gs     NUMBER
      , vl     NUMBER
      ); 

   TYPE t_obj_table IS TABLE OF t_simple_object
   INDEX BY BINARY_INTEGER; 

   my_rec t_simple_object;
   obj t_obj_table; 
BEGIN
   my_rec.wert := 1;
   my_rec.gs := 1;
   my_rec.vl := 1;
   obj(1) := my_rec;
END;
/

EXTEND構文を使用するには、この例でそれを行う必要があります...

DECLARE
   TYPE t_simple_object IS RECORD 
      ( wert   NUMBER
      , gs     NUMBER
      , vl     NUMBER
      ); 

   TYPE t_obj_table IS TABLE OF t_simple_object; 

   my_rec t_simple_object;
   obj t_obj_table := t_obj_table(); 
BEGIN
   obj.EXTEND;
   my_rec.wert := 1;
   my_rec.gs := 1;
   my_rec.vl := 1;
   obj(1) := my_rec;
END;
/

このリンク（トムに尋ねる） も参照してください

22
PaulJ

連想配列を拡張することはできません。それに値を割り当てるだけです

declare
  TYPE t_simple_object IS RECORD (
    wert   NUMBER,
    gs     NUMBER,
    vl     NUMBER);

  TYPE t_obj_table IS TABLE OF t_simple_object INDEX BY BINARY_INTEGER;

  simple_object t_simple_object;
begin
  simple_object.wert := 1;
  simple_object.gs := 2;
  simple_object.vl := 3;
  obj(1) := simple_object;
end;
/
8
Robert Merkwürdigeliebe

連想配列（別名index-by table）を使用したくない場合は、「INDEXBYBINARY_INTEGER」句を省略してください。その後、コードは正常に機能します。

declare 
    TYPE t_simple_object IS RECORD (
       wert   NUMBER,
       gs     NUMBER,
       vl     NUMBER);
    TYPE t_obj_table IS TABLE OF t_simple_object;
    obj t_obj_table;
begin  
    obj := t_obj_table ();
    obj.EXTEND();
end;
8
Tony Andrews

または、レコードを使用する（またはレコードの連想配列）

create or replace package p_test is

  type t_rec is record (
    empname varchar2(50),
    empaddr varchar2(50));

  function p_test_ret_record return t_rec;

end p_test;


create or replace package body p_test is

  function p_test_ret_record return t_rec is
     l_rec t_rec;
  begin
     l_rec.empname := 'P1';
     l_rec.empaddr := 'P2';     
     return l_rec;
  end;

end p_test;

declare
  -- Non-scalar parameters require additional processing 
  result p_test.t_rec;
begin
  -- Call the function
  result := p_test.p_test_ret_record;
  dbms_output.put_line('Name: ' || result.empname || ' Addr: ' || result.empaddr);
end;
0
kayakpim