web-dev-qa-db-ja.com

QtQMLでボタンのフォントサイズを変更する

ButtonコントロールのテキストのフォントサイズをQMLでどのように設定できますか？デザイナにはオプションがなく、「font」はButtonの有効なプロパティではありません。

Button {
    id: cmdQuit
    text: qsTr("Quit")
    width: 64
    height: 32
}
qtqmlqt-quick
11
user1054922

ボタンの style プロパティを設定します。

import QtQuick 2.2
import QtQuick.Controls 1.2
import QtQuick.Controls.Styles 1.2

Rectangle {
  id: container
  width: 800
  height: 800

  Button {
    id: cmdQuit
    text: qsTr("Quit")
    width: 64
    height: 32
    style: ButtonStyle {
      label: Text {
        renderType: Text.NativeRendering
        verticalAlignment: Text.AlignVCenter
        horizontalAlignment: Text.AlignHCenter
        font.family: "Helvetica"
        font.pointSize: 20
        color: "blue"
        text: control.text
      }
    }
  }
}
26
fxam

QtQuick 2の場合、次に示すようにcontentItemプロパティを使用する必要があります： https://doc.qt.io/qt-5/qtquickcontrols2-customize.html#customizing-button

import QtQuick 2.12
import QtQuick.Controls 2.12

Button {
    id: control
    text: qsTr("Button")

    contentItem: Text {
        text: control.text
        font: control.font
        font.pointSize: 20
        opacity: enabled ? 1.0 : 0.3
        color: control.down ? "#17a81a" : "#21be2b"
        horizontalAlignment: Text.AlignHCenter
        verticalAlignment: Text.AlignVCenter
        elide: Text.ElideRight
    }
}
2
Chris