ODBC SQL Serverの接続ロックテーブル

Question

ERPシステムは最新のものより少し低く、バックエンドは現在SQL Server 2008 R2のインストールに置かれています。管理の義務があります（常にそうとは限りません）。多くのユーザーがデータを自分の好みのレポート（BI、Powerquery、Access、Excelなど）に操作する目的で、このシステムから自由にデータを抽出できるようにする完全に非実用的な方法

これらすべてのレポート生成ユーザーには選択権しかありませんが、EDI、自動化されたデータ入力などの目的で実際にデータを操作する機能を持つ他のいくつかのアプリケーションがあります。

論理的には、これによりテーブルにいくつかの競合状態が生じます。先着順、またはさらに悪いことに、まだ配信中、お待ちください、または単にNO ...これは、ベンダーの支援による修正を必要とする、長年の原因不明のデータ破損をさらに引き起こしていると思います。なぜなら、他の何かがそれ自身の私的な意図を妨害した可能性を予測するために、すべてのアプリケーションが適切にコーディングされているわけではないからです。

したがって、タスクは、私が最近継承したシステムで可能な場合にそれを証明/修正/緩和することです。

私の最初の本能は、異なるベンダーの製品間の何らかのIPC /エラー/トランザクション制御とそれを修正する意志、ソースコードの制御、またはそれを制限する能力なしでは、これをDBAから修正できないことは不可能であることを教えてくれます見方をすれば、それは単に潜在的に望ましくない副作用として予期されるものにつながる悪い習慣です。

したがって、この時点で私ができることはそれを証明することだけです。証明があれば、経営者の心にある種の行動の変化を求め、それがこのようでなければならないと主張することができます。

最初のステップは、リソースを集中的に使用しているにもかかわらず、継続的なプロファイラー出力をディスクに実行していることです。戻って、送信された内容、送信者、送信者の影響を確認できる必要があります。また、perfmonロギングとPALを使用して、サーバーで相互参照の多い動作を試行し、相互参照しています"プロセッサとメモリがペグされている場合、SQLサーバーはそのインスタンスで何を行っていたか（おそらくGUIの1つにサービスを提供しています） 、パフォーマンスが低い、10テーブル結合、インデックス付けされていないクエリ、一部のレポートライター/ツールが一緒に投げられた "

これらの状況の1つが発生したばかりで、ERPシステムに機能を実行できないユーザーがいます。ERPソフトウェア（ODBC、選択のみのアクセス権を持つSQLユーザー、およびMS Accessを使用していた）を切断し、機能を通過させた。管理者は、「異なるテーブルを処理する必要があり、ユーザーには選択アクセスしかありませんでした」と私はそれが起こる直前の瞬間のプロファイル履歴を持っていません。

[〜＃〜] proving [〜＃〜]タスクAがアプリケーションBによって悪影響を受けていることを考えると、そのすべてがDBAフェローへの質問に要約されます。あなたが提供しなければならない提案はありますか？

Answer 1

残念ながら、私が扱っているこの問題についても対処している可能性があります。これが問題である場合、データベースを知らない人は、MS Accessで文字通り「ライブ」のSQLテーブルを開きます。最初は、Accessをすばやく開いたり閉じたりするため、一時的なように見えることがあります。しかし、昼食のために、またはおそらく長い週末の間、MS AccessをライブSQLテーブル上で開いたままにする瞬間があります。データベースを使用しようとするアプリケーションをブロックします。明確に述べると、ブロッキングは、ブロックされたSQL行、テーブル、またはデータベースを使用しようとするアプリケーションに悪影響を与える可能性があります。

何かを証明するために本当にしなければならなかったのは、sp_who2ブロッキングチェーンを検索します。

そうは言っても、コンソールから離れているときも、10年以上前に書いた次のコードを使用して（つまり、DBCC InputBufferをまだ使用しています）、これらの厄介な問題を見つけています-必要に応じて（それがあなたのニーズを満たしているかどうかを確認するためのテスト/開発環境）。確かにルーチンのロールスロイスではありませんが、それでも私にはうまくいきます。

このコードは基本的に、新しいデータベースDBADMINにBlockingProcessesというテーブルを作成して、ブロッキング情報を格納します。 2つのストアドプロシージャsp__Maint_BlockWatchおよびsp__Maint_Blockingprocesses協力してブロッカーを見つけます。また、SQLジョブは1分間に1回実行され、ブロックをチェックします。以下のコードで、ジョブを実行する必要のあるユーザー、可能なスケジューリングなどのマイナーな変更が必要になる場合があります。

CREATE DATABASE DBADMIN
GO

USE [dbadmin]
GO

SET ANSI_NULLS ON
GO   
SET QUOTED_IDENTIFIER ON
GO    
SET ANSI_PADDING ON
GO

CREATE TABLE [dbo].[BlockingProcesses]
(
    [PK] [int] IDENTITY(1,1) NOT NULL,
    [last_batch] [datetime] NULL,
    [spid] [int] NULL,
    [BlockedTotal] [int] NULL,
    [LoginName] [varchar](128) NULL,
    [DBName] [varchar](128) NULL,
    [HostName] [varchar](128) NULL,
    [Program_Name] [varchar](255) NULL,
    [CPU] [bigint] NULL,
    [Physical_IO] [bigint] NULL,
    [Memusage] [bigint] NULL,
    [Open_tran] [int] NULL,
    [EventInfo] [varchar](max) NULL,
    [InsertTime] [smalldatetime] NULL,
    [Params] [varchar](500) NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]    
GO

SET ANSI_PADDING OFF
GO

ALTER TABLE [dbo].[BlockingProcesses] 
   ADD DEFAULT (getdate()) FOR [InsertTime]
GO

USE [master]
GO

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER OFF
GO

CREATE PROCEDURE [dbo].[sp__Maint_BlockWatch]
AS
    declare @blocker smallint

    DECLARE blocker_cursor CURSOR FOR 
         select distinct blocked 
         from sysprocesses 
         where blocked != 0

    OPEN blocker_cursor
    FETCH NEXT FROM blocker_cursor INTO @blocker

    WHILE (@@fetch_status <> -1)
    BEGIN
      IF (@@fetch_status = -2)
      BEGIN
  FETCH NEXT FROM blocker_cursor INTO @blocker
           CONTINUE
      END

  exec sp__Maint_Blockingprocesses @blocker

 FETCH NEXT FROM blocker_cursor INTO @blocker
    END
DEALLOCATE blocker_cursor


GO

USE [master]
GO

/****** Object:  StoredProcedure [dbo].[sp__Maint_BlockingProcesses]    Script Date: 09/20/2016 13:31:03 ******/
SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO



CREATE procedure [dbo].[sp__Maint_BlockingProcesses]
@spid smallint
as
declare
@blockedTotal int, 
@loginame varchar(128), 
@dbid int,
@hostname varchar(128),
@program_name varchar(128),
@cpu bigint,
@physical_io bigint,
@memusage bigint,
@open_tran int,
@dbname varchar(128),
@EventInfo varchar(255),
@Last_batch datetime
create table #temp
(
 EventType varchar(50),
 Parameters int,
 EventInfo varchar(255)
)

insert into #temp
exec ('dbcc inputbuffer('+@spid+')')

select @EventInfo=eventinfo from #temp
select @blockedTotal= count(*) from sysprocesses where blocked = @spid
select @loginame=loginame, @dbid=dbid, @hostname=hostname, @program_name=program_name, @cpu=cpu,
@physical_io = physical_io, @memusage=[memusage], @open_tran=open_tran, @Last_batch=last_batch
from sysprocesses where spid=@spid
select @dbname = name from sysdatabases where dbid=@dbid
insert into dbadmin..blockingprocesses(last_batch,spid, BlockedTotal, LoginName, DBName, HostName, Program_Name, CPU, Physical_IO, Memusage, Open_tran, EventInfo)
values(@last_batch, @spid, @BlockedTotal, @LogiName, @DBName, @HostName, @Program_Name, @CPU, @Physical_IO, @Memusage, @Open_tran, @EventInfo)
drop table #temp



GO



USE [msdb]
GO

/****** Object:  Job [_Monitor Blocks]    Script Date: 09/20/2016 13:29:34 ******/
BEGIN TRANSACTION

DECLARE @ReturnCode INT
SELECT @ReturnCode = 0
/****** Object:  JobCategory [[Uncategorized (Local)]]]    Script Date: 09/20/2016 13:29:34 ******/
IF NOT EXISTS (SELECT name FROM msdb.dbo.syscategories WHERE name=N'[Uncategorized (Local)]' AND category_class=1)
BEGIN
EXEC @ReturnCode = msdb.dbo.sp_add_category @class=N'JOB', @type=N'LOCAL', @name=N'[Uncategorized (Local)]'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback

END

DECLARE @jobId BINARY(16)
EXEC @ReturnCode =  msdb.dbo.sp_add_job @job_name=N'_Monitor Blocks', 
        @enabled=1, 
        @notify_level_eventlog=2, 
        @notify_level_email=0, 
        @notify_level_netsend=0, 
        @notify_level_page=0, 
        @delete_level=0, 
        @description=N'No description available.', 
        @category_name=N'[Uncategorized (Local)]', 
        @owner_login_name=N'sa', @job_id = @jobId OUTPUT
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
/****** Object:  Step [Look For Blocking]    Script Date: 09/20/2016 13:29:34 ******/
EXEC @ReturnCode = msdb.dbo.sp_add_jobstep @job_id=@jobId, @step_name=N'Look For Blocking', 
        @step_id=1, 
        @cmdexec_success_code=0, 
        @on_success_action=1, 
        @on_success_step_id=0, 
        @on_fail_action=2, 
        @on_fail_step_id=0, 
        @retry_attempts=0, 
        @retry_interval=1, 
        @os_run_priority=0, @subsystem=N'TSQL', 
        @command=N'exec sp__Maint_BlockWatch', 
        @database_name=N'master', 
        @flags=0
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_update_job @job_id = @jobId, @start_step_id = 1
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobschedule @job_id=@jobId, @name=N'Run Once a Minute', 
        @enabled=1, 
        @freq_type=4, 
        @freq_interval=1, 
        @freq_subday_type=4, 
        @freq_subday_interval=1, 
        @freq_relative_interval=0, 
        @freq_recurrence_factor=0, 
        @active_start_date=20060918, 
        @active_end_date=99991231, 
        @active_start_time=0, 
        @active_end_time=235959
        --, @schedule_uid=N'bf518f11-c5ba-438a-8afd-e4e33e8dad1e'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name = N'(local)'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
COMMIT TRANSACTION
GOTO EndSave
QuitWithRollback:
    IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION
EndSave:

GO