web-dev-qa-db-ja.com

t-sqlコマンドで大文字の最初の文字としてデータを更新する方法は？

データベースにテーブルがあります。私のテーブルの名前は「会社」です。データ「company_name」を大文字の最初の文字として変更したい。例えば;

「ABCカンパニー」

「DEF可塑性」

なので

「Abc Company」

「Def Plasticity」

「UPDATE」コマンドを使用する必要があることを知っています。しかし、どうやって？ご協力いただきありがとうございます！

（CONCATは機能しません）

sql-servertsqlsql-updateuppercase
18
cethint

SQL Server OracleのようなInitcap関数はありません。

Initcap用のUDFを作成できます。

CREATE FUNCTION [dbo].[InitCap] ( @InputString varchar(4000) ) 
RETURNS VARCHAR(4000)
AS
BEGIN

DECLARE @Index          INT
DECLARE @Char           CHAR(1)
DECLARE @PrevChar       CHAR(1)
DECLARE @OutputString   VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 1

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char     = SUBSTRING(@InputString, @Index, 1)
    SET @PrevChar = CASE WHEN @Index = 1 THEN ' '
                         ELSE SUBSTRING(@InputString, @Index - 1, 1)
                    END

    IF @PrevChar IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(')
    BEGIN
        IF @PrevChar != '''' OR UPPER(@Char) != 'S'
            SET @OutputString = STUFF(@OutputString, @Index, 1, UPPER(@Char))
    END

    SET @Index = @Index + 1
END

RETURN @OutputString

END
GO

UDFの動作確認

select [dbo].[InitCap] ('stackoverflow com');

Stackoverflow Com

このようにテーブルを更新できます

update table
set column=[dbo].[InitCap](column);
26
mr_eclair
update  YourTable
set     company_name = upper(substring(company_name,1,1)) + 
            lower(substring(company_name, 2, len(company_name)-1))
where   len(company_name) > 0

SQL Fiddleでの実例

9
Andomar

this one のような分割関数の助けを借りて。

これを試して、YourTableをテーブル名に置き換えてください：

update T
set Name = P.Name
from YourTable as T
  cross apply (select (select upper(left(X.s, 1))+lower(stuff(X.s, 1, 1, ''))+' '
                       from dbo.split(' ', Name) as X
                       for xml path(''), type).value('.', 'varchar(50)')
              ) as P(Name)
1
Mikael Eriksson

さらに修正すると、Mcで始まる所有格（ 's）と単語が処理されます。

if ' ' + @OutputString like '% Mc%'
set @OutputString = ' ' + @OutputString
set @index = CHARINDEX ( ' Mc', @OutputString)
while @Index > 0
begin
    set @OutputString = SUBSTRING(@outputString, 1, @index + 2) + UPPER(SUBSTRING(@outputString, @index + 3, 1)) + SUBSTRING(@outputString, @index + 4, len(@outputString))
    set @index = CHARINDEX ( ' Mc', @OutputString, @Index + 4)
end
set @outputstring = ltrim(rtrim(@outputstring))

if @OutputString + ' ' like '%''S %' 
set @OutputString = ltrim(rtrim(REPLACE(@outputstring + ' ', '''S ', '''s ')))

returnの直前

0
Bruce Sheffer

上記の投稿のおかげで、この関数は、頭字語であると想定される特定の文字長より短いものを除き、すべてのWordの最初の文字を大文字にします。問題ない場合は、2番目の引数を0に設定します。

_CREATE function [dbo].[f_camel_exc_short_words] (@InputString varchar(4000),@AcronymMaxLen INT )
RETURNS VARCHAR(4000)
AS
BEGIN

DECLARE @Index          INT
DECLARE @Char           CHAR(1)
DECLARE @PrevChar       CHAR(1)
DECLARE @Word           VARCHAR(255)
DECLARE @WordChar       CHAR(1)
DECLARE @OutputString   VARCHAR(255)
DECLARE @WordIndex      INT

SET @Word = ''
SET @OutputString = '' 
SET @Index = 1

WHILE @Index <= LEN(@InputString)+1
BEGIN
    SET @Char     = SUBSTRING(@InputString, @Index, 1)
    SET @PrevChar = CASE WHEN @Index = 1 THEN   ' '   ELSE   SUBSTRING(@InputString, @Index - 1, 1)  END

    --IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(')
    --    SET @OutputString = @OutputString + @Char

    IF @PrevChar IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&', '''', '(','0','1','2','3','4','5','6','7','8','9') or @Index = LEN(@InputString)+1
    BEGIN
         SET @WordIndex = 1
        IF LEN(@Word) > @AcronymMaxLen 
        BEGIN
            WHILE @WordIndex <= LEN(@Word)
            BEGIN
                SET @WordChar = SUBSTRING(@Word,@WordIndex,1)
                if @WordIndex = 1  begin
                    SET @Word = STUFF(@Word,@WordIndex,1,UPPER(@WordChar))    end
                else    begin
                    SET @Word = STUFF(@Word,@WordIndex,1,LOWER(@WordChar))    end
                SET @WordIndex = @WordIndex + 1
            END
        END
        ELSE BEGIN
            SET @Word = UPPER(@Word)
        END
        set @OutputString = @OutputString + @Word
        SET @Word = ''
    END
    SET @Word = @Word + @Char
    SET @Index = @Index + 1
END  

return @OutputString

end
GO
_ </ code>

したがって、PRINT dbo.f_camel_exc_short_words ('Pioneer EURO BOND FUND CLASS C (NON-DIST) (EUR) (OFFSHORE) ISIN LU0119429891',4)はPioneer EURO BOND FUND Class C（Non-Dist）（EUR）（Offshore）ISIN LU0119429891を返します

それが役に立てば幸い。

0
BrownsFan

これを試して：

declare @Word as nvarchar (50)
set @Word = 'ABC COMPANY'
select upper(left(@Word, 1)) + lower(SUBSTRING(@Word,2,charindex(' ', @Word)-2)) + ' ' + 
upper(left(substring(@Word,charindex(' ', @Word)+1,len(@Word)-1),1)) 
+ lower(SUBSTRING(@Word,charindex(' ', @Word)+2, len(@Word)))
0
Myk Syk