web-dev-qa-db-ja.com

主キーを非クラスター化からクラスター化に変更する

2つのインデックスを持つSQL Server 2005テーブルTableXがあるとします。

PK_TableX = FieldAにプライマリキーが含まれていません
IX_TableX_FieldB = FieldBでクラスター化

PKをCLUSTEREDに切り替え、他のインデックスをNONCLUSTEREDに切り替えたい。

インデックスラウンドを変更しようとする時点でデータベースが使用中であると想定する必要があります。つまり、プロセスのある時点でテーブルにPK制約が存在しないことを回避したいという私の主な懸念があります。重複したキーが挿入されるリスクから保護したい。

つまり、主キーを削除して再作成することはできません。

このプロセスは、SSMSではなくSQLスクリプトを介して実行する必要があります。

私はうまくいくと思うアプローチがあります（私はそれを潜在的な回答として投稿します）が、何かが足りない場合、または別の/より良い方法がある場合に備えて開きたいです。さらに、将来的には他の人にも役立つかもしれません

sqlsql-serversql-server-2005indexing
30
AdaTheDev

1）最初に既存のクラスター化インデックスを削除します（IX_TableX_FieldB）：

   DROP INDEX TableX.IX_TableX_FieldB

2）主キーで参照される一意のフィールドに（一時的な）UNIQUE制約を作成する

    ALTER TABLE TableX
    ADD CONSTRAINT UQ_TableX UNIQUE(FieldA)

3）PRIMARY KEYをドロップします

    ALTER TABLE TableX
    DROP CONSTRAINT PK_TableX

4）主キーをクラスターとして再作成します

   ALTER TABLE TableX
   ADD CONSTRAINT PK_TableX PRIMARY KEY CLUSTERED(FieldA)

5）一時的なUNIQUE制約を削除します

   ALTER TABLE TableX
   DROP CONSTRAINT UQ_TableX

6）IX_TableX_FieldBをNONCLUSTEREDとして再度追加します。

   CREATE NONCLUSTERED INDEX IX_TableX_FieldB ON TableX(FieldB)
43
AdaTheDev

私はこれが古いことを知っていますが、これはすべてのFKドロップ、pkドロップ、pk再作成、FK再作成をスクリプト化します。 MYTABLEをテーブル名に置き換えます。

   IF  EXISTS (SELECT * FROM sys.tables WHERE object_id = OBJECT_ID(N'[dbo].[FKAgainstTableList]'))
BEGIN 
    DROP TABLE FKAgainstTableList
END
--CREATE TABLE FKAgainstTableList (ForeignKey VARCHAR(30),[Table] VARCHAR(30))
DECLARE @PKTableName VARCHAR(100), 
        @PKName varchar(100),
        @FKName varchar(100),
        @sql varchar(max),
        @PKcolumnName varchar(30),
        @table VARCHAR(100),
        @FKColumnName VARCHAR(100), 
        @parentColumnNumber int
SET @PKTableName = 'MYTABLE'
set @PKName = (SELECT name FROM sys.indexes WHERE OBJECT_NAME(object_id) = @PKTableName AND is_primary_key = 1)
set @PKcolumnName = (SELECT name FROM sys.columns WHERE OBJECT_NAME(object_id) = @PKTableName AND is_identity =1)
PRINT @PKcolumnName

 SELECT  OBJECT_NAME(sys.foreign_key_columns.parent_object_id) [Table],sys.columns.name [FKColumnName],sys.foreign_keys.name [FKName] 
    INTO FKAgainstTableList
    FROM sys.foreign_keys INNER JOIN sys.foreign_key_columns 
    ON sys.foreign_keys.object_id = sys.foreign_key_columns.constraint_object_id
    INNER JOIN sys.columns ON sys.columns.object_id = sys.foreign_keys.parent_object_id AND sys.columns.column_id = sys.foreign_key_columns.parent_column_id
    WHERE OBJECT_NAME(sys.foreign_keys.referenced_object_id) = @PKTableName


DECLARE table_cur1 CURSOR  FOR
    SELECT  * FROM FKAgainstTableList

    PRINT @sql

-------------------------------Disable constraint on FK Tables
OPEN table_cur1
FETCH NEXT FROM table_cur1 INTO @table,@FKColumnName,@FKName
WHILE   @@FETCH_STATUS = 0
    BEGIN
        SET @sql ='ALTER TABLE '+@table+' DROP CONSTRAINT '+ @FKName
        PRINT @sql
        FETCH NEXT FROM table_cur1 INTO @table,@FKColumnName,@FKName
    END
CLOSE table_cur1
DEALLOCATE table_cur1
--------------------------------DROP AND recreate CLUSTERED pk
IF  EXISTS (SELECT 1 FROM sys.indexes WHERE object_id = OBJECT_ID(@PKTableName) AND name = @PKName)
BEGIN
    SET @sql = 'ALTER TABLE '+@PKTableName+' DROP CONSTRAINT '+ @PKName
    PRINT @sql

END
SET @sql = 'ALTER TABLE '+@PKTableName +' ADD  CONSTRAINT '+@PKName+' PRIMARY KEY CLUSTERED ('+@PKcolumnName+' ASC)
WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, SORT_IN_TEMPDB = OFF, IGNORE_DUP_KEY = OFF, ONLINE = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON, FILLFACTOR = 80) ON [PRIMARY]'
PRINT(@sql)

--------------------------------Enable FK constraints on FK tables.
DECLARE table_cur2 CURSOR  FOR
    SELECT  * FROM FKAgainstTableList
OPEN table_cur2
FETCH NEXT FROM table_cur2 INTO @table,@FKColumnName,@FKName
WHILE   @@FETCH_STATUS = 0
    BEGIN
        SET @sql = 'ALTER TABLE '+@table+' WITH NOCHECK ADD  CONSTRAINT  '+ @FKName+' FOREIGN KEY(['+@FKColumnName+'])
        REFERENCES ['+@PKTableName+'] (['+@PKcolumnName+'])'
        PRINT(@sql)
        SET @sql = 'ALTER TABLE '+@table+' CHECK CONSTRAINT  '+@FKName
        PRINT(@sql)

        FETCH NEXT FROM table_cur2 INTO @table,@FKColumnName,@FKName

         END
CLOSE table_cur2
DEALLOCATE table_cur2
DROP TABLE FKAgainstTableList
11
Jerloldrartolf