web-dev-qa-db-ja.com

PL / SQLでの2次元配列の作成またはシミュレーション

ストアドプロシージャのPL/SQLで2次元配列を作成する方法を教えてください。列は動的であるため、タイプも拡大および変更できます。どんな助けも大歓迎です。前もって感謝します！

私は次のコードを持っています：

Type CAR_TABLE_ARRAY is varray(2) of varchar2(255);
TYPE CAR_TABLE_TYPE IS TABLE OF CAR_TABLE_ARRAY;
CAR_TABLE CAR_TABLE_TYPE;

CAR_TABLE := CAR_TABLE_TYPE();
CAR_TABLE.EXTEND(10);
CAR_TABLE(1)(1) := 'DODGE';
CAR_TABLE(2)(1) := 'FORD';
CAR_TABLE(3)(1) := 'MUSTANG';
CAR_TABLE(4)(1) := 'EDSEL';
CAR_TABLE(5)(1) := 'STUDEBAKER';

DBMS_OUTPUT.put_line( '1 ' || CAR_TABLE(1)(1) );
DBMS_OUTPUT.put_line( '2 ' || CAR_TABLE(2)(1) );
DBMS_OUTPUT.put_line( '3 ' || CAR_TABLE(3)(1) );
DBMS_OUTPUT.put_line( '4 ' || CAR_TABLE(4)(1) );
DBMS_OUTPUT.put_line( '5 ' || CAR_TABLE(5)(1) );

実行すると、次のエラーが表示されます。

ORA-06531：初期化されていないコレクションへの参照

sqlarraysoracleplsql
17
Jemru

Pl/sqlで多次元配列を使用する例を次に示します。ここでは、配列を含む配列を使用します。

declare

  type t_features is table of varchar(100) index by pls_integer;
  type t_car_rec is record
  (
    make varchar2(50),
    model varchar2(50),
    features t_features
  );

  type t_car_tab is table of t_car_rec index by pls_integer;
  car_tab t_car_tab;

  procedure show_detail is
    car_idx pls_integer;
    features_idx pls_integer;
  begin
    car_idx := car_tab.first;
    loop
      exit when car_idx is null;
      dbms_output.put_line('Details for ' || car_tab(car_idx).make || ' ' || car_tab(car_idx).model);

      features_idx := car_tab(car_idx).features.first;
      loop
        exit when features_idx is null;
        dbms_output.put_line('   =>' || car_tab(car_idx).features(features_idx));

        features_idx := car_tab(car_idx).features.next(features_idx);
      end loop;

      car_idx := car_tab.next(car_idx);
    end loop;
  end;

begin

  -- using sequential index values
  car_tab(1).make := 'Ferrari';
  car_tab(1).model := 'Testarossa';
  car_tab(1).features(1) := 'Fast';
  car_tab(1).features(2) := 'Looks cool';
  car_tab(1).features(3) := 'Expensive';

  -- using random index values (sparse)
  car_tab(2).make := 'Acura';
  car_tab(2).model := 'TSX';
  car_tab(2).features(14) := 'Small';
  car_tab(2).features(200) := 'Good MPG';
  car_tab(2).features(36) := 'Inexpensive';

  show_detail;

end;

出力は次のようになります。

Details for Ferrari Testarossa
  =>Fast
  =>Looks cool
  =>Expensive 
Details for Acura TSX
  =>Small
  =>Inexpensive
  =>Good MPG

役立つことを願っています

20
tbone

VARRAYおよびネストした表のユーザー定義データ型は、常にコンストラクタを使用して初期化する必要があります。ネストした表に対しては正しく実行していますが、それに含まれるVARRAYに対しては実行していません。最も簡単な修正は、割り当て行でコンストラクターを呼び出すことです。

declare
    Type CAR_TABLE_ARRAY is varray(2) of varchar2(255);
    TYPE CAR_TABLE_TYPE IS TABLE OF CAR_TABLE_ARRAY;
    CAR_TABLE CAR_TABLE_TYPE;
begin    
    CAR_TABLE := CAR_TABLE_TYPE();
    CAR_TABLE.EXTEND(10);
    CAR_TABLE(1) := CAR_TABLE_ARRAY('DODGE',null);
    CAR_TABLE(2) := CAR_TABLE_ARRAY('FORD',null);
    CAR_TABLE(3) := CAR_TABLE_ARRAY('MUSTANG',null);
    CAR_TABLE(4) := CAR_TABLE_ARRAY('EDSEL',null);
    CAR_TABLE(5) := CAR_TABLE_ARRAY('STUDEBAKER',null);

    DBMS_OUTPUT.put_line( '1 ' || CAR_TABLE(1)(1) );
    DBMS_OUTPUT.put_line( '2 ' || CAR_TABLE(2)(1) );
    DBMS_OUTPUT.put_line( '3 ' || CAR_TABLE(3)(1) );
    DBMS_OUTPUT.put_line( '4 ' || CAR_TABLE(4)(1) );
    DBMS_OUTPUT.put_line( '5 ' || CAR_TABLE(5)(1) );
end;
8
Allan

これは、初期化されていない内部配列を参照しているためです。
いずれかのような追加：

CAR_TABLE(1) := CAR_TABLE_ARRAY();
CAR_TABLE(1).EXTEND(1);
CAR_TABLE(2) := CAR_TABLE_ARRAY();
CAR_TABLE(2).EXTEND(1);
...

または、内部配列（CAR_TABLE_ARRAY）を連想配列として作成します。

Type CAR_TABLE_ARRAY is TABLE of varchar2(255) index by binary_integer;
5
A.B.Cade