T-SQLで日月と年から日付を作成する
2007年12月1日、1月1日などの個々の部分を含む日付をSQL Server 2005の日付時刻に変換しようとしています。次のことを試みました。
CAST(DATEPART(year, DATE)+'-'+ DATEPART(month, DATE) +'-'+ DATEPART(day, DATE) AS DATETIME)
しかし、これは間違った日付になります。 3つの日付値を適切な日時形式に変換する正しい方法は何ですか。
y, m, dがすべてintであると仮定すると、どうでしょうか。
CAST(CAST(y AS varchar) + '-' + CAST(m AS varchar) + '-' + CAST(d AS varchar) AS DATETIME)
SQL Server 2012以降については、 私の他の答え を参照してください。
これを試して：
Declare @DayOfMonth TinyInt Set @DayOfMonth = 13
Declare @Month TinyInt Set @Month = 6
Declare @Year Integer Set @Year = 2006
-- ------------------------------------
Select DateAdd(day, @DayOfMonth - 1,
DateAdd(month, @Month - 1,
DateAdd(Year, @Year-1900, 0)))
同様に動作し、文字列変換を行わないという利点が追加されたため、純粋な算術処理（非常に高速）で、日付形式には依存しません。その最初の部分が1900年1月1日以降の日数を表す整数で、2番目の部分が（その日の）1日の端数部分を表す小数であるため、整数値0（ゼロ） ）常に1900年1月1日の真夜中の朝に直接翻訳されます...
または@brinaryからの提案のおかげで、
Select DateAdd(yy, @Year-1900,
DateAdd(m, @Month - 1, @DayOfMonth - 1))
2014年10月に編集。@cade Rouxで注目されるように、SQL 2012には組み込み関数が追加されました。DATEFROMPARTS(year, month, day)
それは同じことをします。
2016年10月3日に編集、（これに気付いた@bambams、およびそれを修正してくれた@brinaryに感謝します）、@brinaryによって提案された最後の解決策。年の追加が最初に実行されない限り、うるう年には機能しないようです。
select dateadd(month, @Month - 1,
dateadd(year, @Year-1900, @DayOfMonth - 1));
SQL Server 2012には、待望の新しいDATEFROMPARTS関数（日付が無効な場合はエラーが発生します - この問題に対するDATEADDベースの解決策に対する私の主な反対意見）があります。
http://msdn.Microsoft.com/en-us/library/hh213228.aspx
DATEFROMPARTS(ycolumn, mcolumn, dcolumn)
または
DATEFROMPARTS(@y, @m, @d)
または単一のdateadd関数を使用する
DECLARE @day int, @month int, @year int
SELECT @day = 4, @month = 3, @year = 2011
SELECT dateadd(mm, (@year - 1900) * 12 + @month - 1 , @day - 1)
Sql Server 2012には、パーツに基づいて日付を作成する機能があります（ DATEFROMPARTS ）。私たちの残りのために、これは私が作成したdb関数で、パートから日付を決定します（ありがとう@Charles）...
IF EXISTS (SELECT * FROM dbo.sysobjects WHERE id = object_id(N'[dbo].[func_DateFromParts]'))
DROP FUNCTION [dbo].[func_DateFromParts]
GO
CREATE FUNCTION [dbo].[func_DateFromParts]
(
@Year INT,
@Month INT,
@DayOfMonth INT,
@Hour INT = 0, -- based on 24 hour clock (add 12 for PM :)
@Min INT = 0,
@Sec INT = 0
)
RETURNS DATETIME
AS
BEGIN
RETURN DATEADD(second, @Sec,
DATEADD(minute, @Min,
DATEADD(hour, @Hour,
DATEADD(day, @DayOfMonth - 1,
DATEADD(month, @Month - 1,
DATEADD(Year, @Year-1900, 0))))))
END
GO
このように呼ぶことができます...
SELECT dbo.func_DateFromParts(2013, 10, 4, 15, 50, DEFAULT)
を返します...
2013-10-04 15:50:00.000
CASTの代わりにCONVERTを試してください。
CONVERTでは、日付形式を示す3番目のパラメータを使用できます。
フォーマットのリストはこちらです： http://msdn.Microsoft.com/ja-jp/library/ms187928.aspx
別の回答が「正しい」回答として選択された後に更新します。
この制限を示さずに、サーバー上のNLS設定に明らかに依存する回答が選択される理由はよくわかりません。
また使用することができます
select DATEFROMPARTS(year, month, day) as ColDate, Col2, Col3
From MyTable Where DATEFROMPARTS(year, month, day) Between @DateIni and @DateEnd
2012年12月以降のSQLとAzureSQLで動作する
明示的な開始点 '19000101'を使用することがより安全でより適切です。
create function dbo.fnDateTime2FromParts(@Year int, @Month int, @Day int, @Hour int, @Minute int, @Second int, @Nanosecond int)
returns datetime2
as
begin
-- Note! SQL Server 2012 includes datetime2fromparts() function
declare @output datetime2 = '19000101'
set @output = dateadd(year , @Year - 1900 , @output)
set @output = dateadd(month , @Month - 1 , @output)
set @output = dateadd(day , @Day - 1 , @output)
set @output = dateadd(hour , @Hour , @output)
set @output = dateadd(minute , @Minute , @output)
set @output = dateadd(second , @Second , @output)
set @output = dateadd(ns , @Nanosecond , @output)
return @output
end
Datetimeが必要な場合は1行のソリューションを追加しますdateとtimeの両方の部分から：
select dateadd(month, (@Year -1900)*12 + @Month -1, @DayOfMonth -1) + dateadd(ss, @Hour*3600 + @Minute*60 + @Second, 0) + dateadd(ms, @Millisecond, 0)
あなたがそれから文字列を避けたくないなら、これは同様に働きます（それを関数に入れて）：
DECLARE @Day int, @Month int, @Year int
SELECT @Day = 1, @Month = 2, @Year = 2008
SELECT DateAdd(dd, @Day-1, DateAdd(mm, @Month -1, DateAdd(yy, @Year - 2000, '20000101')))
やってみる
CAST(STR(DATEPART(year, DATE))+'-'+ STR(DATEPART(month, DATE)) +'-'+ STR(DATEPART(day, DATE)) AS DATETIME)
SQL Serverのバージョンが12未満の場合、SET DATEFORMATと組み合わせてCASTを使用することをお勧めします。
-- 26 February 2015
SET DATEFORMAT dmy
SELECT CAST('26-2-2015' AS DATE)
SET DATEFORMAT ymd
SELECT CAST('2015-2-26' AS DATE)
どのようにそれらの文字列を作成するかはあなた次第です
このクエリを試してください。
SELECT SUBSTRING(CONVERT(VARCHAR,JOINGDATE,103),7,4)AS
YEAR,SUBSTRING(CONVERT(VARCHAR,JOINGDATE,100),1,2)AS
MONTH,SUBSTRING(CONVERT(VARCHAR,JOINGDATE,100),4,3)AS DATE FROM EMPLOYEE1
結果：
2014 Ja 1
2015 Ja 1
2014 Ja 1
2015 Ja 1
2012 Ja 1
2010 Ja 1
2015 Ja 1
OPがSQL 2005の答えを求めていることは知っていますが、質問はかなり古いので、SQL 2012以上を実行している場合は次を使用できます：
SELECT DATEADD(DAY, 1, EOMONTH(@somedate, -1))
私は個人的にSubstringを好みます。それはそれがクレンジングオプションと必要に応じて文字列を分割する能力を提供するからです。データは 'dd、mm、yyyy'の形式であると仮定しています。
--2012 and above
SELECT CONCAT (
RIGHT(REPLACE(@date, ' ', ''), 4)
,'-'
,RIGHT(CONCAT('00',SUBSTRING(REPLACE(@date, ' ', ''), CHARINDEX(',', REPLACE(@date, ' ', '')) + 1, LEN(REPLACE(@date, ' ', '')) - CHARINDEX(',', REPLACE(@date, ' ', '')) - 5)),2)
,'-'
,RIGHT(CONCAT('00',SUBSTRING(REPLACE(@date, ' ', ''), 1, CHARINDEX(',', REPLACE(@date, ' ', '')) - 1)),2)
)
--2008 and below
SELECT RIGHT(REPLACE(@date, ' ', ''), 4)
+'-'
+RIGHT('00'+SUBSTRING(REPLACE(@date, ' ', ''), CHARINDEX(',', REPLACE(@date, ' ', '')) + 1, LEN(REPLACE(@date, ' ', '')) - CHARINDEX(',', REPLACE(@date, ' ', '')) - 5),2)
+'-'
+RIGHT('00'+SUBSTRING(REPLACE(@date, ' ', ''), 1, CHARINDEX(',', REPLACE(@date, ' ', '')) - 1),2)
これは、データが列に格納されている場合にどのように使用される可能性があるかを示すデモです。言うまでもなく、列に適用する前に結果セットをチェックするのが理想的です。
DECLARE @Table TABLE (ID INT IDENTITY(1000,1), DateString VARCHAR(50), DateColumn DATE)
INSERT INTO @Table
SELECT'12, 1, 2007',NULL
UNION
SELECT'15,3, 2007',NULL
UNION
SELECT'18, 11 , 2007',NULL
UNION
SELECT'22 , 11, 2007',NULL
UNION
SELECT'30, 12, 2007 ',NULL
UPDATE @Table
SET DateColumn = CONCAT (
RIGHT(REPLACE(DateString, ' ', ''), 4)
,'-'
,RIGHT(CONCAT('00',SUBSTRING(REPLACE(DateString, ' ', ''), CHARINDEX(',', REPLACE(DateString, ' ', '')) + 1, LEN(REPLACE(DateString, ' ', '')) - CHARINDEX(',', REPLACE(DateString, ' ', '')) - 5)),2)
,'-'
,RIGHT(CONCAT('00',SUBSTRING(REPLACE(DateString, ' ', ''), 1, CHARINDEX(',', REPLACE(DateString, ' ', '')) - 1)),2)
)
SELECT ID,DateString,DateColumn
FROM @Table