web-dev-qa-db-ja.com

SDKを使用せずにNetAPPONTAP APIをクエリするにはどうすればよいですか？

公開鍵と秘密鍵のペアを使用してssh経由でアクセスしているNetAppファイラーがたくさんあります。

私がしていることを拡張したいと思います-私たちは繰り返し制限にぶつかっています。 sshはコマンドの完了に失敗し（実行前に切断）、実行中のコマンドからの出力のフォーマットは「人間が読める」ため、マシンの解析が煩わしいことを意味します。

そこで、APIにクエリを実行したいと思います。さまざまな理由から、NetApp SDKではなく、CPANの「既成の」モジュールを使用してクエリを実行したいと思います。

これは可能ですか？もしそうなら、どのように？

（私はこれがStack Overflowに適しているかどうかを考えていましたが、Perlスクリプトよりもおそらくsysadminに関連していると結論付けました）。

storagenetapp
1
Sobrique

基本は非常に単純です。コピーする必要があるものが2つあります。

  • XML
  • http（s）

CPANから、これを行うことができるさまざまなモジュールがあります。私は LWP と XML::Twig 。

  • まず、アクセスする必要のあるAPIを調べる必要があります。通常のオプションはDFMまたはfilerで、さまざまなAPIリクエストを利用できます。 （SDKのダウンロードが必要になる場合があります： http://mysupport.netapp.com/NOW/download/software/nmsdk/5.3/ ）
  • リクエストとしていくつかのXMLをアセンブルします。
  • リクエストを送信する
  • 応答をデコードします（XML）。

これは少し次のようになります。

#!/usr/local/bin/Perl

use strict;
use warnings;

use XML::Twig;
use LWP::UserAgent;

my $filer     = 'filername';
my $vfiler    = 'vfilername';
my $user      = 'api-user';
my $pass      = 'api-pass';
my $api_call  = 'volume-list-info';
my %api_param = ( volume => 'vfiler_vol0' );

my $API = '/servlets/netapp.servlets.admin.XMLrequest_filer';
my $url = "https://$filer/$API";

my $xml_request = XML::Twig->new();
$xml_request->set_root(
    XML::Twig::Elt->new(
        'netapp',
        {   version => '1.7',
            vfiler  => $vfiler,
            xmlns   => 'http://www.netapp.com/filer/admin'
        },
    )
);
my $req = $xml_request->root->insert_new_elt($api_call);

foreach my $key ( keys %api_param ) {
    $req->insert_new_elt( $key, $api_param{$key} );
}

$xml_request->set_doctype('netapp SYSTEM "file:/etc/netapp_filer.dtd"');
$xml_request->set_xml_version('1.0');
$xml_request->set_encoding('utf-8');


my $agent = LWP::UserAgent->new(
    ssl_opts => {
        verify_hostname => 0,
        SSL_version     => 'SSLv3'
    }
);

my $request = HTTP::Request->new( POST => $url );
$request->content( $xml_request->sprint );
$request->authorization_basic( $user, $pass );

my $results = $agent->request($request);
if ( $results->is_success ) {

    #do nothing yet
}
else {
    print "Request error:", $results->status_line;
    die;
}
my $results_twig = XML::Twig->new( pretty_print => 'indented' );
$results_twig->parse( $results->content );

#dump the whole thing
$results_twig->print;

print some values selectively. 
foreach my $vol ( $results_twig -> root -> children('volume-info') ) {
    print $vol -> first_child_text('name'), " "; 
    print $vol -> first_child_text('state'),"\n";
}
1
Sobrique