web-dev-qa-db-ja.com

sp_executesqlの結果を変数に取得する方法は？

実行する必要がある動的SQLがあり、結果を変数に格納する必要があります。

sp_executesqlを使用できることは知っていますが、これを行う方法について明確な例を見つけることができません。

tsqldynamic-sql
160
JohnIdol

OUTPUTパラメーターがある場合は、次のことができます

DECLARE @retval int   
DECLARE @sSQL nvarchar(500);
DECLARE @ParmDefinition nvarchar(500);

DECLARE @tablename nvarchar(50)  
SELECT @tablename = N'products'  

SELECT @sSQL = N'SELECT @retvalOUT = MAX(ID) FROM ' + @tablename;  
SET @ParmDefinition = N'@retvalOUT int OUTPUT';

EXEC sp_executesql @sSQL, @ParmDefinition, @retvalOUT=@retval OUTPUT;

SELECT @retval;

ただし、SPを変更せず、変更できない場合：

-- Assuming that your SP return 1 value
create table #temptable (ID int null)
insert into #temptable exec mysp 'Value1', 'Value2'
select * from #temptable

きれいではありませんが、動作します。

230
Eduardo Molteni
DECLARE @tab AS TABLE (col VARCHAR(10), colu2 varchar(10)) 
  INSERT into @tab EXECUTE  sp_executesql N'SELECT 1 as col1, 2 as col2 union all SELECT 1 as col1, 2 as col2 union all SELECT 1 as col1, 2 as col2'

  SELECT * FROM @tab
42
Nishanth
DECLARE @vi INT
DECLARE @vQuery NVARCHAR(1000)

SET @vQuery = N'SELECT @vi= COUNT(*) FROM <TableName>'

EXEC SP_EXECUTESQL 
        @Query  = @vQuery
      , @Params = N'@vi INT OUTPUT'
      , @vi = @vi OUTPUT

SELECT @vi
37
Buchaiah

@variable intを宣言します

Exec @variable = proc_name

3
Mark Hedley

複数の値を返したい場合は、これを使用します：

DECLARE @sqlstatement2      NVARCHAR(MAX);
DECLARE @retText            NVARCHAR(MAX);  
DECLARE @ParmDefinition     NVARCHAR(MAX);
DECLARE @retIndex           INT = 0;

SELECT @sqlstatement = 'SELECT @retIndexOUT=column1 @retTextOUT=column2 FROM XXX WHERE bla bla';

SET @ParmDefinition = N'@retIndexOUT INT OUTPUT, @retTextOUT NVARCHAR(MAX) OUTPUT';

exec sp_executesql @sqlstatement, @ParmDefinition, @retIndexOUT=@retIndex OUTPUT, @retTextOUT=@retText OUTPUT;

返される値は@retIndexおよび@retTextにあります

2
cihata87

DECLARE @ValueTable TABLE（Value VARCHAR（100））

                    SELECT @sql = N'SELECT SRS_SizeSetDetails.'+@COLUMN_NAME+' FROM SRS_SizeSetDetails WHERE FSizeID = '''+@FSizeID+''' AND SRS_SizeSetID = '''+@SRS_SizeSetID+'''';

                    INSERT INTO @ValueTable
                    EXEC sp_executesql @sql;

                    SET @Value='';

                    SET @Value = (SELECT TOP 1  Value FROM @ValueTable)

                    DELETE FROM @ValueTable
2
Abhishek Dheeman

戻り値は通常、結果を「返す」ためではなく、成功（0）またはエラー番号（1〜65K）を返すために使用されます。上記はすべて、sp_executesqlが値を返さないことを示しているようですが、これは正しくありません。 sp_executesqlは、成功の場合は0を、失敗の場合はその他の数値を返します。

以下では、@ iは2727を返します

DECLARE @s NVARCHAR(500)
DECLARE @i INT;
SET @s = 'USE [Blah]; UPDATE STATISTICS [dbo].[TableName] [NonExistantStatisticsName];';
EXEC @i = sys.sp_executesql @s
SELECT @i AS 'Blah'

SSMSは、このメッセージ2727、レベル11、状態1、行1を表示します。インデックス 'NonExistantStaticsName'が見つかりません。

2
PseudoToad

これはかなり前のことなので、これがまだ必要かどうかはわかりませんが、@@ ROWCOUNT変数を使用して、前のsqlステートメントの影響を受けた行数を確認できます。

これは、たとえば動的なUpdateステートメントを作成し、execで実行する場合に役立ちます。 @@ ROWCOUNTは、更新された行数を示します。

ここに定義があります

0
bazsano1

これは私のために働いた：

DECLARE @SQL NVARCHAR(4000)

DECLARE @tbl Table (
    Id int,
    Account varchar(50),
    Amount int
) 

-- Lots of code to Create my dynamic sql statement

insert into @tbl EXEC sp_executesql @SQL

select * from @tbl
0
Dylan Hayes