web-dev-qa-db-ja.com

クラスモジュール（VB6）のパブリックサブのパラメーターとしてのユーザー定義型（UDT）

この問題を解決しようとしましたが、解決策が見つかりません。通常のモジュールでUDTを定義していて、それをクラスモジュールのPublic Subのパラメーターとして使用したいと思いました。次に、コンパイルエラーが発生します。

クラスモジュールのパブリックプロシージャのパラメータまたは戻り値の型として、またはパブリックユーザー定義型のフィールドとして使用できるのは、パブリックオブジェクトモジュールで定義されたパブリックユーザー定義型のみです。

次に、Privateとして宣言されたクラス内のUDTを移動しようとします。このコンパイルエラーが発生します：

プライベート列挙型とユーザー定義型は、パブリックプロシージャ、パブリックデータメンバー、またはパブリックユーザー定義型のフィールドのパラメーターまたは戻り値の型として使用できません。

最後に、クラスでPublicとして宣言しようとすると、次のコンパイルエラーが発生します。

プライベートオブジェクトモジュール内でパブリックユーザー定義タイプを定義することはできません。

では、クラスのパブリックサブのパラメーターとしてパブリックUDTを使用する方法はありますか？

vbavb6user-defined-types
16
cfischer

では、クラスのパブリックサブのパラメーターとしてパブリックUDTを使用する方法はありますか？

一言で言えば、違います。 Classic VBコードで最も近いのは、UDTを複製するクラスを作成し、代わりにそれを使用することです。そこには確かに利点がありますが、合格する必要がある場合は面倒です。それは、たとえばAPIにも当てはまります。

もう1つのオプションは、typelibでUDTを定義することです。これを行うと、パブリックメソッドのパラメーターとして使用できます。

10
Karl E. Peterson

SubをFriendスコープとして定義するだけです。これは、VB6クラスで問題なくコンパイルされます。

Private Type testtype
  x As String
End Type


Friend Sub testmethod(y As testtype)

End Sub

エラーメッセージから、クラスはプライベートであるように見えます。クラスをパブリックにしたい場合（つまり、ActiveX exeまたはDLL）を作成していて、クライアントがサブにアクセスできるようにしたい場合）は、タイプとサブの両方をパブリックにします。 。

18
MarkJ

わかりました。猫に放っておいてもらうことができれば、その方法は次のとおりです。

Form1の場合（1つのコマンドボタンがあります）：

Option Explicit
'
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByVal dst As Long, ByVal src As Long, ByVal nBytes As Long)
'

Private Sub Command1_Click()
' Okay, this is what won't work in VB6:
'     Dim MyUdt1 As MyUdtType   ' Declare a variable with a publicly defined UDT (no problem).
'     Form2.Show                ' We could have created some object with a class.  This was just easier for the demo.
'           INSIDE OF FORM2:
'               Public Sub MySub(MyUdt2 As MyUdtType)   ' It won't even let you compile this.
'                   Msgbox MyUdt2.l
'                   MyUdt2.l = 5
'               End Sub
'     Form2.MySub MyUdt1                                ' You'll never get this far.
'     Unload Form2
'     Msgbox MyUdt1.l
'
' The following is a way to get it done:
'
Dim MyUdt1 As MyUdtType         ' Declare a variable with a publicly defined UDT (no problem).
Dim ReturnUdtPtr As Long        ' Declare a variable for a return pointer.
MyUdt1.l = 3                    ' Give the variable of our UDT some value.
Form2.Show                      ' Create our other object.
'
' Now we're ready to call our procedure in the object.
' This is all we really wanted to do all along.
' Notice that the VarPtr of the UDT is passed and not the actual UDT.
' This allows us to circumvent the no passing of UDTs to objects.
ReturnUdtPtr = Form2.MyFunction(VarPtr(MyUdt1))
'
' If we don't want anything back, we could have just used a SUB procedure.
' However, I wanted to give an example of how to go both directions.
' All of this would be exactly the same even if we had started out in a module (BAS).
CopyMemory VarPtr(MyUdt1), ReturnUdtPtr, Len(MyUdt1)
'
' We can now kill our other object (Unload Form2).
' We probably shouldn't kill it until we've copied our UDT data
' because the lifetime of our UDT will be technically ended when we do.
Unload Form2                    ' Kill the other object.  We're done with it.
MsgBox MyUdt1.l                 ' Make sure we got the UDT data back.
End Sub

Form2（コントロールは不要）。 （これは、クラスで作成されたオブジェクトと同じくらい簡単である可能性があります。）：

    Option Explicit
'
Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByVal dst As Long, ByVal src As Long, ByVal nBytes As Long)
'

Public Function MyFunction(ArgUdtPtr As Long) As Long
' Ok, this is how we get it done.
' There are a couple of things to notice right off the bat.
' First, the POINTER to the UDT is passed (using VarPtr) rather than the actual UDT.
' This way, we can circumvent the restriction of UDT not passed into objects.
' Second, the following MyUdt2 is declared as STATIC.
' This second point is important because the lifetime of MyUdt2 technically ends
' when we return from this function if it is just DIMmed.
' If we want to pass changes back to our caller, we will want to have a slightly longer lifetime.
Static MyUdt2 As MyUdtType
' Ok, we're here, so now we move the argument's UDT's data into our local UDT.
CopyMemory VarPtr(MyUdt2), ArgUdtPtr, Len(MyUdt2)
' Let's see if we got it.
MsgBox MyUdt2.l
' Now we might want to change it, and then pass back our changes.
MyUdt2.l = 5
' Once again, we pass back the pointer, because we can't get the actual UDT back.
' This is where the MyUdt2 being declared as Static becomes important.
MyFunction = VarPtr(MyUdt2)
End Function

そして最後に、これはモジュール（BAS）ファイルに入ります。

    Option Explicit
'
' This is just the UDT that is used for the example.
Public Type MyUdtType
    l As Long
End Type
'
9
Elroy

UDTを参照パラメーターとして渡すだけで機能します。 :)

'method in the class

Public Sub CreateFile(ByRef udt1 As UdtTest)

End Sub
2
Nithin K V

同じエラーメッセージが表示され、アプリケーションを確認したところ、クラスのプロパティウィンドウで、参照されているオブジェクトの「インスタンス化」設定が「1-プライベート」に設定されていることがわかりました。 「5-MultiUse」に変更したところ、同じエラーメッセージが表示されました。次に、その参照オブジェクトを追加してプロジェクトに再度追加する前のバージョンのプロジェクトモジュールに戻りました。デフォルトは「1-プライベート」でした。他の作業を行う前に「5-MultiUse」に変更し、プロジェクトを閉じて、コンパイルする前に更新できるようにしました。プロジェクトを再度開き、「5-MultiUse」に設定されていることを確認してから、プロジェクトをコンパイルすると、エラーメッセージなしで正常にコンパイルされました。

エラーメッセージがプライベートオブジェクトの参照を許可しないことを示していたとき、そのオブジェクトは実際にはプライベートでした。プライベートではないと宣言し、プロジェクトモジュールがその新しい設定を受け入れると、クリーンにコンパイルされました。

1
Vic Fanberg

モジュールでUDF（パブリックタイプ）を定義します。

Public Type TPVArticulo
    Referencia As String
    Descripcion As String
    PVP As Double
    Dto As Double
End Type

クラス、モジュールofrmでFriendを使用します。

Friend Function GetArticulo() As TPVArticulo
0
user2276227