web-dev-qa-db-ja.com

Excel VBA：散布図をオブジェクトとしてワークシートに追加します

ボタンを押すと、Sheet 1に散布図を作成し、A2:A11をx値として使用し、B2:B11をy値として使用する散布図を作成しようとしています。

下部のコードを使用すると、A1:B3の値に基づいて散布図を作成できます（これは ここ から取得しました）。その近くですが、私が探しているものとは異なります。ニーズに合わせてこれを調整するにはどうすればよいですか？

必要な値に基づいてグラフが作成されるように設定しましたが、Sheet 1でオブジェクトとして表示することができません。どうすればよいですか？ .Location xlLocationAsObjectが機能していないようです。

Private Sub chartButton_Click()
    ActiveWorkbook.Charts.Add
    With ActiveWorkbook.ActiveChart
        'Data?
        .ChartType = xlXYScatter
        .SeriesCollection.NewSeries
        .SeriesCollection(1).Name = "=""Scatter Chart"""
        .SeriesCollection(1).XValues = "=Sheet1!$A$2:$A$11"
        .SeriesCollection(1).Values = "=Sheet1!$B$2:$B$11"

        'Location
        'DON'T KNOW WHAT TO PUT HERE
        '.location xlLocationAsObject doesn't work!

        'Titles
        .HasTitle = True
        .ChartTitle.Characters.Text = "Scatter Chart"
        .Axes(xlCategory, xlPrimary).HasTitle = True
        .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "X values"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Y values"
        .Axes(xlCategory).HasMajorGridlines = True

        'Formatting
        .Axes(xlCategory).HasMinorGridlines = False
        .Axes(xlValue).HasMajorGridlines = True
        .Axes(xlValue).HasMinorGridlines = False
        .HasLegend = False

    End With
End Sub
vbaexcel-vbachartsexcel
6
Josh I

記述されたコードは、チャートをWorksheetのチャートとしてではなく、Chart Sheetとして追加します。

これを試して：

交換

ActiveWorkbook.Charts.Add
With ActiveWorkbook.ActiveChart

と

Dim sh As Worksheet
Dim chrt As Chart

Set sh = ActiveWorkbook.Worksheets("Sheet1")
Set chrt = sh.Shapes.AddChart.Chart
With chrt

次に、その位置とサイズを制御できます

    .ChartArea.Left
    .ChartArea.Top 
    .ChartArea.Height
    .ChartArea.Width
8
chris neilsen

Chart.Locationを使用する場合は、場所を指定する必要があります。

.Location Where:=xlLocationAsObject, Name:="Sheet1"
0
Jon Peltier