web-dev-qa-db-ja.com

VBエラー "オブジェクトが必要です"

次のスクリプトを実行すると、最後の行である54行目に「オブジェクトが必要です」というエラーが表示されます。なにが問題ですか？

 Option Explicit
Dim cmdString, g_strHostFile, filepath, flexnetpath, importcmd, dtmToday, dtmYesterday, dtmFileDate, param1, param2, param3, i4path, objFSO, objTextStream, g_strComputer, WshShell
'Initialize global constants and variables.
Const FOR_READING = 1
g_strHostFile = "D:\dataimports\LUM_servers.txt"
i4path = "C:\IFOR\WIN\BIN\i4blt.exe"
filepath = "D:\DataImports\"
flexnetpath = "C:\Program Files (x86)\Flexnet\Manager\Admin"
importcmd = flexnetpath & "flexnet bulkimport -uadmin -padmin -f" & filepath
dtmToday = Date()
dtmYesterday = Date() - 1
dtmFileDate = Year(Date) & padDate(Month(Date)) & padDate(Day(Date))
param1 = "-r1 -e2,4 -n "
param2 = " -v 'Dassault Systemes' -b "
param3 = " -g "
WScript.Echo "i4Path: " & i4path
WScript.Echo "FilePath: " & filepath
WScript.Echo "flexnetpath: " & flexnetpath
WScript.Echo "importcmd: " & importcmd
WScript.Echo "dtmToday: " & dtmToday
WScript.Echo "dtmYesterday: " & dtmYesterday
WScript.Echo "dtmFileDate: " & dtmFileDate

'Read LUM Server Names from text file.
Set objFSO = CreateObject("Scripting.FileSystemObject")
If objFSO.FileExists(g_strHostFile) Then
  Set objTextStream = objFSO.OpenTextFile(g_strHostFile, FOR_READING)
Else
  WScript.Echo "Input file " & g_strHostFile & " not found."
  WScript.Quit
End If
'Loop through list of computers and perform tasks on each.
Do Until objTextStream.AtEndOfStream
  g_strComputer = objTextStream.ReadLine
WScript.Echo "Processing Server: " & g_strComputer
Set cmdString = i4path & param1 & g_strComputer & param2 & dtmYesterday & param3 & dtmToday & filepath & g_strComputer & "_" & dtmFileDate & "_lum.lrl"
WScript.Echo "Processing Command: " & cmdString
Set WshShell = WScript.CreateObject("WScript.Shell")
WshShell.Run "cmdString"
Loop
objTextStream.Close
Set WshShell = WScript.CreateObject("WScript.Shell")
WScript.Echo "Processing Bulk Import: " & importcmd
WshShell.Run "importcmd"

Function padDate(intNumber)
 if intNumber <= 9 Then
  padDate = "0" & CStr(intNumber)
 Else
  padDate = CStr(intNumber)
 End If
End Function
vbscript
10
ChuckO

いくつか問題があると思います。

 importcmd = flexnetpath & "flexnet bulkimport -uadmin -padmin -f" & filepath

おそらくいくつかのスペースが必要です：

 importcmd = flexnetpath & " flexnet bulkimport -uadmin -padmin -f " & filepath

Setはオブジェクトでのみ使用され、文字列では使用されないため、次の行から削除する必要があります。

 Set cmdString = i4path & param1 & g_strComputer & param2 & dtmYesterday & param3 & dtmToday & filepath & g_strComputer & "_" & dtmFileDate & "_lum.lrl"

私はあなたがどちらかを意味するとかなり確信しています

 WshShell.Run importcmd

または

 WshShell.Run """" & importcmd & """"
6
Fionnuala

Set x = yのようなステートメントがある場合、必要なオブジェクトが発生します。ここで、xはオブジェクト型ではなく、単純な型です（Integer、Double、Date 、など）。私はラインだと思います

Set cmdString = i4path & param1 & g_strComputer & param2 & ...

がエラーの原因であり、あなたがしなければならないのはSetステートメントを削除することだけだと思います。文字列はObjectから派生していないため、Setステートメントは必要ないと思います。

7
ja72