web-dev-qa-db-ja.com

Verilogで番号を符号拡張する方法

コンピューターアーキテクチャ用に作成しているプロセッサー用に、Verilogで単純なサインエクステンダーに取り組んでいます。

これが私がこれまでに得たものです：[編集：選択ステートメントをわずかに変更しました]

`timescale 1ns / 1ps

module SignExtender( CLK, extend, extended );
input[7:0] extend;
input CLK;
output[15:0] extended;

reg[15:0] extended;
wire[7:0] extend;

always
begin
    while (CLK == 1)
    extended[7:0] = extend[7:0];
    extended[15:8] = {8{extend[7]}};
end
endmodule

While（CLK == 1）を追加して、問題を解決できると考えました。これは無限ループだと思います。これをiSimでテストしようとすると、回路が初期化されません。

また、コピー構文を削除して、[8]-[15]に対してextended [8] = extend [7]などを実行しようとしましたが、同じ結果が発生するため、最も内側の構文が正しいと確信しています。

テストファイルは次のとおりです。

`timescale 1ns / 1ps
module SignExtender_testbench0;

    // Inputs
    reg [7:0] extend;
    reg CLK;

    // Outputs
    wire [15:0] extended;

    // Instantiate the Unit Under Test (UUT)
    SignExtender uut (
        .extend(extend), 
        .extended(extended)
    );

    initial begin
        // Initialize Inputs
        extend = 0;

        #100; // Wait 100 ns for global reset to finish

        extend = -30;
        CLK = 1;
        #10;
        CLK = 0;
        if (extended == -30)
            $display("okay 1");
        else
            $display("fail 1");

        extend = 40;
        #10;
        if (extended == 40)
            $display("okay 2");
        else
            $display("fail 2");

    end

endmodule

これを成功させる方法はありますか？

verilogvlsi
9
Alex Mullans

あなたはほとんどそれを手に入れました...

always @( posedge clk ) begin
    extended[15:0] <= { {8{extend[7]}}, extend[7:0] };
end

また、「40」テスト用のクロックエッジがありません。これを試してみて、どうやって乗るのか教えてください...

18
Marty

構文$signedを使用して符号拡張を行うことができます

module signextender(
  input [7:0] unextended,//the msb bit is the sign bit
  input clk,
  output reg [15:0] extended 
);

always@(posedge clk)
  begin 
    extended <= $signed(unextended);
  end
endmodule
12
renu

ちなみに、モジュールの割り当ては純粋な組み合わせであるため、clkを含めるべきではありません。これは、モジュールを実行する別の方法です。

module sign_ext
             (
              unextend,
              extended
             );

input  [15:0] unextend;
output [31:0] extended;

assign extended = {{16{unextend[15]}}, unextend};

endmodule

//TB

module tb_sign_ext;

reg  [15:0] unex;
wire   [31:0] ext;

sign_ext TBSIGNEXT
                  (
                   .unextend(unex),
                   .extended(ext)
                  );

initial
begin
   unex = 16'd0;
end


initial 
begin
   #10 unex = 16'b0000_0000_1111_1111;
   #20 unex = 16'b1000_0000_1111_1111;
end

endmodule

;)
3
Mario