Windowsの場合：wmicを使用してファイルの最終変更日（UTC時刻）を取得する方法
最終変更日を取得するために、次のバッチを作成しました。問題は、UTC時間ではなく、クロック時間でそれを与えることです。分単位のラグがあることはわかっていますが、バッチファイルを使用して数値をシフトするのはそれほど簡単ではありません。 UTC時間を取得するためにwmicに与えるフラグはありますか？これはバッチファイルです
@echo off
setlocal enableextensions disabledelayedexpansion
set file=%1
set WORKINGdir=%~dp0
rem wmic wants double backslash
set PATHfile=%WORKINGdir%%file%
set PATHfile=%PATHfile:\=\\%
for /f %%a in (
'wmic DataFile where "Name='%PATHfile%'" get lastmodified ^| find "+" '
) do set "val=%%a"
echo %val%
rem get first 14 digits (good until year 9999)
echo %val:~0,14%
endlocal
これにより、次の出力が得られます。
20161026144823.620815+120
20161026144823
多数のファイルの場合は遅くなる可能性がありますが、純粋なバッチで可能です。バッチルーチンは、 Richie Lawrence Batch Function Library。 の関数から派生しています。
:: Demo_DateAddSecs.cmd ::::::::::::::::::::::::::::::::::::::::::::
@Echo off&cls
Call :GetISODT DateTime
Echo %DateTime% is now
Call :DateAddSecs %DateTime% 7200 NewDT
Echo %NewDT% +7200 secs
Echo y___m_d_h_n_s_
Echo 20160101013000 Subtract 2h from new year 1:30
Call :DateAddSecs 20160101013000 -7200 NewDT
Echo %NewDT% -7200 secs
Echo y___m_d_h_n_s_
Echo 20160301013000 March first -12h this is a leap year
Call :DateAddSecs 20160301013000 -43200 NewDT
Echo %NewDT% -43200 secs
Echo y___m_d_h_n_s_
Pause
Goto :Eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:GetISODT Var
SetLocal
for /f "tokens=1-3 delims=.+-" %%A in (
'wmic os get LocalDateTime^|findstr ^^[0-9]'
) do Set _IsoDT=%%A
EndLocal&Set "%1=%_IsoDT%"&Goto :Eof
:: GetISODT.cmd :::::::::::::::::::::::::::::::::::::::::::::::::::::
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:DateAddSecs %yyyymmddhhnnss% %secs2Add% DTreturnvar
:: Original functions DateToSecs and SecsToDate
:: By: Ritchie Lawrence, updated 2002-08-13. Version 1.1
:: Func: Converts DateTime to number of seconds elapsed since
:: 1st January 1970 00:00:00 adds the supplied seconds
:: and converts back to a valid Datetime
:: For a given calendar date and time of day. Tested with Win10pro.
:: Args:
:: %1 by val Datetime in the form yyyymmddhhnnss
:: %2 by val seconds integer to add/subtract 1 hour = 60*60 = 3600
:: %3 by ref the var name to receive the resulting Datetime
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
SetLocal EnableExtensions& Set DT=%1
Set yy=%DT:~0,4%&set mm=%DT:~4,2%&set dd=%DT:~6,2%
set hh=%DT:~8,2%&set nn=%DT:~10,2%&set ss=%DT:~12,2%
Set /a dd=100%dd%%%100,mm=100%mm%%%100
Set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
Set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
if 1%hh% LSS 20 set hh=0%hh%
Set /a hh=100%hh%%%100,nn=100%nn%%%100,ss=100%ss%%%100
Set /a j=j*86400+hh*3600+nn*60+ss
Endlocal&set /A secs=%j%+%2
:: SecsToDate %secs% yy mm dd hh nn ss
SetLocal EnableExtensions
Set /a i=%secs%,ss=i%%60,i/=60,nn=i%%60,i/=60,hh=i%%24,dd=i/24,i/=24
Set /a a=i+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
Set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2
Set /a dd/=5,dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
(if %hh% LSS 10 set hh=0%hh%)&(if %nn% LSS 10 set nn=0%nn%)
if %ss% LSS 10 set ss=0%ss%
Endlocal&set "%3=%yy%%mm%%dd%%hh%%nn%%ss%"&Goto :Eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
この出力を与える
> DemoDateAddSecs.cmd
20161027053749 is now
20161027073749 +7200 secs
y___m_d_h_n_s_
20160101013000 Subtract 2h from new year 1:30
20151231233000 -7200 secs
y___m_d_h_n_s_
20160301013000 March first -12h this is a leap year
20160229133000 -43200 secs
y___m_d_h_n_s_
HTH
確かに、タイムスタンプの計算は苦痛です。時間をUTCに調整すると、日付が異なる可能性があります。つまり、月の日数について心配する必要があり、うるう年について心配する必要がある場合があります。
WMICには、タイムスタンプをUTCとしてフォーマットするための組み込みプロビジョニングがありません。そして、バッチは確かに日付/時刻演算の処理を事実上サポートしていません。
私はあなたの問題を簡単に解決できる JREN.BATと呼ばれるユーティリティ を書きました。これは主に、正規表現を使用してファイル/フォルダーの名前を変更できるようにするために作成されました。ただし、この問題を解決できる追加機能があります。
JREN.BATは、XP以降-サードパーティのexeファイルは必要ありません。_jren /?_を実行すると、完全なドキュメントが利用可能になります。コマンドPrompt（またはページヘルプの場合は_jren /??_）から
以下は、タイムスタンプをUTCとして正しく表示することを除いて、スクリプトと同じ機能を提供します。
_@echo off
for /f "delims=" %%A in (
'jren "^.*" "ts({dt:'modified',tz:0})" /j /list /p "%~dp0" /fm %1'
) do set "ts=%%A"
echo %ts%
_出力は句読点のないISO8601形式になり、文字列セマンティクスを使用して時系列で適切に並べ替えられます。 _20161006T155621.746+0000_のようなもの。
Ts（）呼び出しにfmt：オプションを簡単に追加して、タイムスタンプを適切と思われる方法でフォーマットできます。 jren /?ts()を使用して、タイムスタンプの操作に使用できるすべてのオプションに関する完全なヘルプを取得します。
JRENを使用して、UTC時刻を含む完全なディレクトリリストを提供するのは非常に簡単です。
以下に、現在のディレクトリでtで始まるすべての.txtファイルの最終変更タイムスタンプ、ファイルサイズ、およびファイル名を示します。
_D:\test>jren "^.*" "ts({dt:'modified',tz:0,fmt:'{iso-dt} {iso-tm}'})+size(' ')+' '+$0" /j /list /fm t*.txt
2015-06-22 19:11:22.134 74 temp1.txt
2015-06-22 19:11:22.259 0 temp2.txt
2015-06-22 19:11:22.384 0 temp3.txt
2016-09-07 15:20:08.146 10376 tempfile.txt
2016-10-06 15:56:21.746 14 test.txt
2015-06-22 19:11:23.600 342 text2.txt
2015-06-22 19:11:23.741 288 textfile1.txt
2015-06-22 19:11:23.866 144 textfile2.txt
2015-10-19 19:12:16.441 707 TL.txt
2016-01-13 17:35:17.505 1030 tl64.txt
2016-01-13 17:36:48.501 974 tl64_2.txt
2016-01-13 17:45:16.383 943 tl64_3.txt
2016-01-13 17:37:21.308 707 tl_1.txt
2016-01-13 17:37:30.356 707 tl_2.txt
2016-01-13 17:45:50.469 707 tl_3.txt
2015-06-22 19:11:24.006 42 tmp.txt
2015-06-22 19:11:24.427 541553 toc-z.txt
2015-08-31 20:59:25.202 17442083 tree.txt
2015-06-22 19:11:24.583 304 tsc_call_layout.txt
_JRENはWMIを使用して、最後に変更されたタイムスタンプを取得しますが、これは非常に低速です。言語設定によっては、fsomodifiedの代わりにmodifiedを使用して、FileSystemObjectを使用してタイムスタンプを取得できる場合があります。これははるかに高速ですが、ミリ秒は提供されません。また、言語がJScriptの日付オブジェクトで解釈できる方法でタイムスタンプ文字列をフォーマットする場合にのみ機能します。
_D:\test>jren "^.*" "ts({dt:'fsomodified',tz:0,fmt:'{iso-dt} {hh}:{nn}:{ss}'})+size(' ')+' '+$0" /j /list /fm t*.txt
2015-06-22 19:11:22 74 temp1.txt
2015-06-22 19:11:22 0 temp2.txt
2015-06-22 19:11:22 0 temp3.txt
2016-09-07 15:20:08 10376 tempfile.txt
2016-10-06 15:56:21 14 test.txt
2015-06-22 19:11:23 342 text2.txt
2015-06-22 19:11:23 288 textfile1.txt
2015-06-22 19:11:23 144 textfile2.txt
2015-10-19 19:12:16 707 TL.txt
2016-01-13 18:35:17 1030 tl64.txt
2016-01-13 18:36:48 974 tl64_2.txt
2016-01-13 18:45:16 943 tl64_3.txt
2016-01-13 18:37:21 707 tl_1.txt
2016-01-13 18:37:30 707 tl_2.txt
2016-01-13 18:45:50 707 tl_3.txt
2015-06-22 19:11:24 42 tmp.txt
2015-06-22 19:11:24 541553 toc-z.txt
2015-08-31 20:59:25 17442083 tree.txt
2015-06-22 19:11:24 304 tsc_call_layout.txt
_