web-dev-qa-db-ja.com

Windows 7でVimdiff（7.4）を実行できない

最近、Windows 7マシンに7.4バージョンのgVimをインストールしました。 Windowsエクスプローラーの状況依存メニューから2つのファイルを比較しようとすると、エラーメッセージが表示され続けます。

E810：一時ファイルを読み書きできません
E97：差分を作成できません

選択した2つのファイルが2ペインのgVimビューで開かれ、エディターは差分モードのように見えますが、実際の違いは強調表示されていません。

%TEMP%および%TMP%環境変数には、有効なディレクトリ名が入力されています。

通常のgVimセッションでファイルを開き、コマンドプロンプトで:diffthisと入力しても、同じ応答が返されます。

これは以前はVim 7.3で適切に機能していましたが、v7.4で変更されたように見えました。

2つのファイルを比較するにはどうすればよいですか？

windows-7vimgvimvimdiff
29
ysap

この問題は、Windowsのインストーラーによって作成されたデフォルトの_vimrcファイルが原因である可能性があります。そのデフォルトファイルをまだ使用している場合、またはある時点でコピーした場合は、diffexprオプションに割り当てた関数を確認してください。 Vim 7.3と7.4の間のパッチの1つで、Windowsのcmd.exeシェルに新しいデフォルトの引用ルールが導入されました。このパッチは、パッチによって解決された同じ問題を修正するために設計されたMyDiff（）関数の回避策を壊しました。

MyDiff（）関数は、インストーラーを修正することにより、バージョン7.4.103で修正されました。これは、_vimrcにコピーするだけの場合に、最新のインストーラーが作成するMyDiff（）関数です。

 function MyDiff()
   let opt = '-a --binary '
   if &diffopt =~ 'icase' | let opt = opt . '-i ' | endif
   if &diffopt =~ 'iwhite' | let opt = opt . '-b ' | endif
   let arg1 = v:fname_in
   if arg1 =~ ' ' | let arg1 = '"' . arg1 . '"' | endif
   let arg2 = v:fname_new
   if arg2 =~ ' ' | let arg2 = '"' . arg2 . '"' | endif
   let arg3 = v:fname_out
   if arg3 =~ ' ' | let arg3 = '"' . arg3 . '"' | endif
   if $VIMRUNTIME =~ ' '
     if &sh =~ '\<cmd'
       if empty(&shellxquote)
         let l:shxq_sav = ''
         set shellxquote&
       endif
       let cmd = '"' . $VIMRUNTIME . '\diff"'
     else
       let cmd = substitute($VIMRUNTIME, ' ', '" ', '') . '\diff"'
     endif
   else
     let cmd = $VIMRUNTIME . '\diff'
   endif
   silent execute '!' . cmd . ' ' . opt . arg1 . ' ' . arg2 . ' > ' . arg3
   if exists('l:shxq_sav')
     let &shellxquote=l:shxq_sav
   endif
 endfunction

:versionまたは:introコマンドを使用するか、起動時のスプラッシュスクリーンで、Vimでフルバージョンを確認できます。

残念ながら、公式インストーラーが必要な場合は、8.0まで待つか、 nightly build をインストールする必要があります。それでも、 他の場所からVimをインストールする または 独自のVimを構築する を使用できます。

スタックオーバーフローで重複 （通常、両方のサイトでトピック）、この回答が更新された場合、他の回答も更新されます。

45
Ben