Lync 2013 Standardのサイレントインストール
私は、Windows 7/Office 2010を搭載したコンピューターにLync 2013の標準クライアントと基本クライアントをサイレントに展開し、いくつかの障害を回避するための良い方法を見つけようとしています。
1）標準クライアント（VLからダウンロード）のインストールは成功しましたが、自動的にインストールすると、「このインストールパッケージの言語はシステムでサポートされていません」というエラーが表示されます。私は構文を使用しています：
setup.exe/adminfile lyncstd.msp/config lync.ww\config.xml
MSPはsetup/adminを使用して作成し、フルインストールしました。また、config.mxlファイルを次の構文で作成しました。
<Configuration Product="Lync">
<Display Level="none" CompletionNotice="yes" SuppressModal="yes" AcceptEula="yes" />
<Logging Type="verbose" Path="%temp%" Template="Microsoft Office Lync Setup(*).txt" />
<USERNAME Value="Me" />
<COMPANYNAME Value="My company" />
<INSTALLLOCATION Value="%programfiles%\Microsoft Office" />
<DistributionPoint Location="\\vm-fs\public\Lync\Standard" />
<OptionState Id="LOBiMain" State="absent" Children="force" /> -->
<Setting Id="SETUP_REBOOT" Value="IfNeeded" />
だから、これは私には意味がありません-なぜGUIからインストールしてもそのような問題が生じないのと同じように、自動化は突然灼熱の痔を引き起こします。インストールログに、最後の方にメッセージが表示されます：このインストールパッケージの言語はお使いのシステムでサポートされていません。 Microsoft Office Multi-language User Interface Pack」の概要。
2）またはGPO [コンピューターの構成]> [ポリシー]> [Windowsの設定]> [スクリプト]でバッチファイルを実行してインストールし、setup.exeを使用してサイレントインストールを実行する唯一の方法です。 adminfile＆configfileタグ？
ありがとう！
MSPファイルを使用した展開の問題を回避するために、起動スクリプトを使用して直接exeを呼び出し、追加のパラメーター/ログにxml構成を利用できます。
開始するには、共有フォルダーを作成し、Lync 2013ファイルをそのフォルダーに配置します。このフォルダに対する読み取りと書き込み（ログが必要な場合は書き込み）を行う「ドメインコンピュータ」権限を付与し、NTFSと共有の両方のアクセス許可を付与してください。
ロギングが必要な場合は（そうする場合）、Installフォルダーにログ用のフォルダーを作成します。私はInstallLogFilesと名付けました（うん、とてもクリエイティブです）。
インストールフォルダーには、lync.wwwフォルダとconfig.xmlファイル。ファイルを編集して、以下を含めます。
<Display Level="none" CompletionNotice="no" SuppressModal="yes" AcceptEula="yes" />
<Logging Type="standard" Path="\\SERVER\SHARE\InstallLogFiles" Template="%computername%-Install_Log.txt" />
<!-- <USERNAME Value="Customer" /> -->
<!-- <COMPANYNAME Value="MyCompany" /> -->
<!-- <INSTALLLOCATION Value="%programfiles%\Microsoft Office" /> -->
<!-- <LIS CACHEACTION="CacheOnly" /> -->
<LIS SOURCELIST="\\SERVER\SHARE" />
<DistributionPoint Location="\\SERVER\SHARE" />
<!-- <OptionState Id="OptionID" State="absent" Children="force" /> -->
<Setting Id="SETUP_REBOOT" Value="never" />
<!-- <Command Path="%windir%\system32\msiexec.exe" Args="/i \\server\share\my.msi" QuietArg="/q" ChainPosition="after" Execute="install" /> -->
必要に応じて他の値を変更できますが、\ SERVER\SHARE \の行はインストールフォルダーを指す必要があります。
次に、インストールを呼び出すためにワークステーションで実行する起動スクリプトが必要です。次のコードを必要に応じて編集し、.batファイルとして保存します。次に、ファイルをスタートアップスクリプトとしてグループポリシーに追加する必要があります。展開を簡単にするために、ADグループのみが読み取り可能となるようにポリシーの範囲を設定できます。次に、インストールを取得するコンピューターをADグループに追加できます。
コード：
setlocal
REM *********************************************************************
REM Environment customization begins here. Modify variables below.
REM *********************************************************************
REM Get ProductName from the Office product's core Setup.xml file, and then add "office15." as a prefix.
set ProductName=Office15.LYNC
REM Set DeployServer to a network-accessible location containing the Office source files.
set DeployServer=\\SERVER\SHARE
REM Set ConfigFile to the configuration file to be used for deployment (required)
set ConfigFile=\\SERVER\SHARE\lync.WW\config.xml
REM Set LogLocation to a central directory to collect log files.
set LogLocation=\\SERVER\SHARE\InstallLogFiles
REM *********************************************************************
REM Deployment code begins here. Do not modify anything below this line.
REM *********************************************************************
REM Skip install if OS is not Win 7 or above
IF NOT "%ProgramFiles(x86)%"=="" (goto Office2013) else (goto XP)
:Office2013
REM Check to see if Office 2013 is installed, if so Exit
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Office15.PROPLUS
echo %date% %time% Checking if Office 2013 is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto ARP64) else (goto End)
REM Operating system is X64. Check if Lync is already installed in emulated Wow6432 uninstall key
:ARP64
reg query HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432NODE\Microsoft\Windows\CurrentVersion\Uninstall\%ProductName%
echo %date% %time% Checking if Lync is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto Office) else (goto End)
REM Check to see if Office 2013 is installed, if so Exit
reg query HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\Office15.PROPLUS
echo %date% %time% Checking if Office 2013 is installed code is %errorlevel%.>> %LogLocation%\%computername%.txt
if %errorlevel%==1 (goto Office) else (goto End)
REM If 1 returned, the product was not found. Run setup here.
:Office
echo %date% %time% Deployment triggered on %computername%.>> %LogLocation%\%computername%.txt
start /wait %DeployServer%\setup.exe /config %ConfigFile%
echo %date% %time% Setup ended with error code %errorlevel%. >> %LogLocation%\%computername%.txt
exit
:XP
echo %date% %time% Machine is Windows XP - Exiting >> %LogLocation%\%computername%.txt
exit
REM If 0 or other was returned, the product was found or another error occurred. Do nothing.
:End
exit
Endlocal
上記のコードは、マシンがXPかどうか、exit/logかどうかを確認します。
Office 2013が既にインストールされているかどうかを確認し、インストールされている場合は終了/ログします。
Lync 2013 Standaloneがすでにインストールされているかどうかを確認し、インストールされている場合は終了します。
そうでない場合は、インストールを開始し、ステップを記録します。実際のソフトウェアインストールログも存在し、どちらも%computername%変数は、問題の追跡に役立ちます。
この方法で、何百ものマシンにLyncを問題なく展開しました。