web-dev-qa-db-ja.com

マルチパートRARを抽出し、抽出されたパーツを削除します

私は80GBのマルチパートRARを開梱しています。 5GBの空き容量があり、RARアーカイブのすべての部分が2GBです。

私が探しているのは、1つの部分を抽出し、それを削除し、次の部分を抽出するなど、抽出プロセスで最大5 GBを使用し、すべてのディスク領域を使い果たしないようにすることです。

windowscompressionrar
3
m fran

重要：

  • このスクリプト[〜＃〜] will [〜＃〜]最終結果に関係なく、抽出が完了したパーツを削除するため、欠落または破損したパーツが原因でプロセスが停止すると、開始できなくなります。以上
  • メモ帳を開き、次のコードを貼り付けて、rarファイルと同じフォルダーに_ unrar.vbsとして保存します。
  • nRAR_Full_Path、First_PartおよびTarget_Folderを設定し、引用符を保持するようにしてください。

スクリプト：

UnRAR_Full_Path = "c:\program files\winrar\unrar.exe"
First_Part = "YourArchiveName.part001.rar"
Target_Folder = "ExtractedFiles\"

mf_command = AddQuotes(UnRAR_Full_Path) & " x " & AddQuotes(First_Part) & " " & AddQuotes(Target_Folder)
mf_LZerosSplit = Split(First_Part, ".")
mf_LZerosPart = Mid(mf_LZerosSplit(UBound(mf_LZerosSplit)-1), 5)
If UBound(mf_LZerosSplit) > 3 Then
    WScript.Echo ("Too Lazy to deal with names the contains dots, only 2 are allowed. one before 'part' and one before 'rar'")
    WScript.Quit 1
End If
mf_LZ_UnderTen = ""
mf_LZ_UnderHundred = ""
mf_LZ_UnderThousand = ""

If Len(mf_LZerosPart) = 2 Then
    mf_LZ_UnderTen = "0"

ElseIf Len(mf_LZerosPart) = 3 Then
    mf_LZ_UnderTen = "00"
    mf_LZ_UnderHundred = "0"

ElseIf Len(mf_LZerosPart) = 4 Then
    mf_LZ_UnderTen = "000"
    mf_LZ_UnderHundred = "00"
    mf_LZ_UnderThousand = "0"
End If 
Set objShell = CreateObject("WScript.Shell")
Set objWshScriptExec = objShell.Exec(mf_command)
Set objStdOut = objWshScriptExec.StdOut

While Not objStdOut.AtEndOfStream
    strLine = objStdOut.ReadLine

    'WScript.Echo (strLine)

        If InStr(strLine,"Extracting from") Then
            mf_filename = Mid(strLine, 17)
            mf_partnameSplit = Split(mf_filename, ".")
            mf_partname = mf_partnameSplit(1)
            mf_partnumber = Mid(mf_partname , 5)
            If mf_partnumber > 1 Then
                mf_numtodel = mf_partnumber-1
                mf_LeadingZeros = ""
                If mf_numtodel < 10 Then
                    mf_LeadingZeros = mf_LZ_UnderTen
                ElseIf mf_numtodel < 100  Then
                    mf_LeadingZeros = mf_LZ_UnderHundred
                ElseIf mf_numtodel < 1000  Then
                    mf_LeadingZeros = mf_LZ_UnderThousand
                End If
                mf_filetodel = mf_partnameSplit(0) & ".part" & mf_LeadingZeros & mf_numtodel & ".rar"

                'WScript.Echo ("NOW DELETING: " & mf_filetodel)

                Set obj = CreateObject("Scripting.FileSystemObject")
                obj.DeleteFile(mf_filetodel)
            End If
        ElseIf InStr(strLine,"All OK") Then
            WScript.Echo ("looks like All Ok, Delete the Last part and Have a Nice day :)")
        End If
Wend

Function AddQuotes(strInput)
    AddQuotes = Chr(34) & strInput & Chr(34)
End Function

オプション1：サイレント

_ unrar.vbsファイルをダブルクリックして実行します

オプション2：推奨

の先頭から'を削除します

'WScript.Echo (strLine)

'WScript.Echo ("Deleting: " & mf_filetodel)

cmdを開き、フォルダに直接移動して、次のように入力します"cscript _unrar.vbs"

  • WScript.Echoを使用せずにcscriptを使用すると、迷惑なメッセージボックスがポップアップしすぎます

このスクリプトは、UnRAR.exeの標準出力を読み取ることで機能します。

編集

スクリプトが改善され、任意の名前構造と最大9999パーツまでの任意の数のパーツで自動的に機能するようになりました。先行ゼロを含まないレガシーアーカイブを操作するため。

3
Maher Fattouh