web-dev-qa-db-ja.com

IPのネットワークインターフェイスを検索するコマンド

ipconfigを使用すると、ネットワークアダプターとその設定のリストを表示できます。 IPアドレス。

特定のIPアドレスのネットワークアダプターの名前を表示する逆引きコマンドを探しています。

ipconfigの出力をipconfig | find "192.168.2.4"のようなコマンドでフィルタリングしようとしましたが、アダプター名がなくなりました。

ipconfigの出力は次のとおりです（注意が必要な部分は、ここでは1つのアダプターに複数のアドレスがあるようです）。

Windows IP Configuration


Ethernet adapter Local Area Connection:

   Connection-specific DNS Suffix  . :
   Link-local IPv6 Address . . . . . : fe80::xxxx:xxxx:xxxx:xxxx%11
   IPv4 Address. . . . . . . . . . . : 192.168.2.4
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   IPv4 Address. . . . . . . . . . . : 192.168.178.20
   Subnet Mask . . . . . . . . . . . : 255.255.255.0
   Default Gateway . . . . . . . . . : 192.168.178.1
                                       192.168.2.1

Ethernet adapter VMware Network Adapter VMnet1:
...
windowsnetworkingipbatch-fileip-address
13
Thomas Weller

特定のIPアドレスのネットワークアダプターの名前を表示するにはどうすればよいですか？

このソリューションでは、外部コマンド（pcre2grep、sedなど）は必要ありません。

次のバッチファイル（getname.cmd）を使用します。

@echo off
setlocal
setlocal enabledelayedexpansion
set "_adapter="
set "_ip="
for /f "tokens=1* delims=:" %%g in ('ipconfig /all') do (
  set "_tmp=%%~g"
  if "!_tmp:adapter=!"=="!_tmp!" (
    if not "!_tmp:IPv4 Address=!"=="!_tmp!" (
      for %%i in (%%~h) do (
      if not "%%~i"=="" set "_ip=%%~i"
      )
    set "_ip=!_ip:(Preferred)=!"
    if "!_ip!"=="%1" (
        @echo !_adapter!
      )
    )
  ) else (
    set "_ip="
    set "_adapter=!_tmp:*adapter =!"
  )
)
endlocal

使用法：

getname ipaddress

例：

F:\test>getname 192.168.42.78
Local Area Connection 2
F:\test>

参考文献

8
DavidPostill

このPS 1ライナーを使用できます。

$addr='192.168.2.4'; get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr} |select Description |% {$_.Description}

コマンドラインから直接使用するには：

powershell "$addr='192.168.2.4'; get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr} |select Description |% {$_.Description}"

または、再利用したい場合は、スクリプトに入れてアドレスをパラメーターにします

編集：Win/Ipconfigに表示される名前を取得するには：

$addr='192.168.2.4'; 
$netconf = get-wmiobject Win32_NetworkAdapterConfiguration |? {$_.ipaddress -contains $addr};
$netconf |% {$_.GetRelated("win32_NetworkAdapter")} | select NetConnectionID |%{$_.NetConnectionID}

（中間変数への割り当ては、それをもう少し読みやすくするためだけです）

6
wmz

特定のIPアドレスのネットワークアダプターの名前を表示する逆引きコマンドを探しています。

私が試したすべてに基づいて、これは機能するはずですが、この情報は、例ですでに指定しているIPアドレスからのみ取得する必要があると言えます。

ネットワーク接続名を取得するためのIPアドレスの対話型プロンプト

（WMICおよびいくつかのバッチFORループtokenおよびdelim解析を使用して、指定したIPアドレスのネットワーク接続名を取得します。）

（結果の値はコマンドウィンドウとメッセージボックスウィンドウにエコーされます。これはすべてバッチスクリプトですが、動的にいくつかのVBSスクリプト関数を構築して、必要な人のためのプロセスを簡略化します。）

@ECHO ON

:SetTempFiles
SET tmpIPaddr=%tmp%\~tmpipaddress.vbs
SET tmpNetConName1=%tmp%\~tmpNetConName1.txt
SET tmpNetConName2=%tmp%\~tmpNetConName2.txt
SET tmpBatFile=%tmp%\~tmpBatch.cmd
SET tmpVBNetCon=%tmp%\~tmpVBNetCon.vbs

IF EXIST "%tmpIPaddr%" DEL /F /Q "%tmpIPaddr%"
IF EXIST "%tmpNetConName1%" DEL /Q /F "%tmpNetConName1%"
IF EXIST "%tmpNetConName2%" DEL /Q /F "%tmpNetConName2%"
IF EXIST "%tmpBatFile%" DEL /Q /F "%tmpBatFile%"
IF EXIST "%tmpVBNetCon%" DEL /Q /F "%tmpVBNetCon%"

:InputBox
SET msgboxTitle=IP ADDRESS
SET msgboxLine1=Enter the IP address to get its Windows connection name
>"%tmpIPaddr%" ECHO wsh.echo inputbox("%msgboxLine1%","%msgboxTitle%")
FOR /F "tokens=*" %%N IN ('cscript //nologo "%tmpIPaddr%"') DO CALL :setvariables %%N
GOTO EOF

:setvariables
SET IPAddress=%~1
FOR /F "USEBACKQ TOKENS=3 DELIMS=," %%A IN (`"WMIC NICCONFIG GET IPADDRESS,MACADDRESS /FORMAT:CSV | FIND /I "%IPAddress%""`) DO (SET MACAddress=%%~A)
FOR /F "USEBACKQ TOKENS=3 DELIMS=," %%B IN (`"WMIC NIC GET MACADDRESS,NETCONNECTIONID /FORMAT:CSV | FIND /I "%MACAddress%""`) DO ECHO(%%~B>>"%tmpNetConName1%"

::: Parse Empty Lines
FINDSTR "." "%tmpNetConName1%">"%tmpNetConName2%"

::: Build Dynamic Batch with ECHO'd Network Connection Value
FOR /F "tokens=*" %%C IN (%tmpNetConName2%) DO ECHO ECHO %%~C>>"%tmpBatFile%"
IF NOT EXIST "%tmpBatFile%" GOTO :NullExit
START "" "%tmpBatFile%"

::: Build Dynamic VBS with Message Box Network Connection Value
FOR /F "tokens=*" %%C IN (%tmpNetConName2%) DO (SET vbNetconName=%%~C)
ECHO msgbox "%vbNetconName%",0,"%vbNetconName%">"%tmpVBNetCon%"
START /B "" "%tmpVBNetCon%"
EXIT /B

:NullExit
ECHO msgbox "Cannot find MAC Address, check to confirm IP Address was correct.",0,"Invalid IP">"%tmpVBNetCon%"
START /B "" "%tmpVBNetCon%"
EXIT /B

オールワンライナー

NESTIVE WINDOWSは、NETSHのすべてのインターフェイス（すべてのIPv4アドレス）でのみ使用できます

NETSH INT IP SHOW CONFIG | FINDSTR /R "Configuration for interface.* Address.*[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"

enter image description here

ネイティブWindowsはIPCONFIGすべてのインターフェース（すべてのIPv4アドレス）でのみ使用できます

IPCONFIG | FINDSTR /R "Ethernet* Address.*[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*"

enter image description here

PCRE2GREPの使用（@SalvoFごと）

単一のIPアドレスが指定されました

netsh interface ipv4 show address | pcre2grep -B2 "192\.168\.2\.4" | FIND /V "DHCP"

すべてのIPアドレスを検索

netsh interface ip show config | pcre2grep -B2 ^(?:[0-9]{1,3}\.){3}[0-9]{1,3}$ | FIND /V "DHCP" | FIND /V "Gate" | FIND /V "Metric" | FIND /V "Subnet"

Find ALL IP ADDRESSES（Cleaned Up Regex（per @SalvoF））

netsh interface ip show config | pcre2grep "^[A-Z]|IP.*([0-9]{1,3}(\.|)){4}"

pcre2grep私が試したのは@SalvoFあたりです[+1]彼が提案したとおりですが、.... FIND /VDHCPを含む上記の行を削除すると、説明したように目的の出力が得られるようです。 NETSHではなくIPCONFIGも使用しました。

4
Pimp Juice IT

より正確には、OPの例に従って、sedを使用します。これは、 この圧縮ファイルの\usr\local\wbinフォルダーの下にあります （UnxUtilsプロジェクト）。

ipconfig | sed -rn "/^[A-Z]/h;/192.168.2.4/{g;s/.* adapter (.*):/\1/p;}"

-nは、一致しない行を抑制します。最初のパターンは大文字で始まるすべての行を見つけ、次にhはそれを保留スペースに置きます。 2番目の一致は必要なIP番号にあります。この時点で、インターフェイス名を保持する行が呼び出され（g）、余分な先行テキストが削除され（s）、印刷されます（p） 。

3
SΛLVΘ

参考までに、ここに別のバッチソリューションがあります。これは、%ERRORLEVEL%システム変数の遅延展開を利用します。

@echo off
setlocal EnableDelayedExpansion
for /f "delims=" %%L in ('ipconfig') do (
    echo %%L | findstr /r "^[A-Z]" 1>NUL
    if !errorlevel! == 0 set "_int=%%L"
    echo %%L | findstr /c:%1 1>NUL
    if !errorlevel! == 0 (
       set "_int=!_int::=!"
       echo !_int:* adapter =!
       goto:eof
    )
)

この方法で呼び出すことができます：find_int.cmd 192.168.1.100

2
SΛLVΘ

皆さんの努力に感謝します。いくつかのハードルがあるようです：

  • アダプターに割り当てられたIPアドレスの数
  • oSの言語

全ての -BxとRegexのものは簡単に壊れるように見えるので、自分で実装できるものを探して、IPアドレスをパラメーターとして取る次のC＃プログラムを考えました（IP2Adapter <IP>）：

using System;
using System.Net.NetworkInformation;
using System.Net.Sockets;

namespace IP2Adapter
{
    class Program
    {
        static void Main(string[] args)
        {
            var adapters = NetworkInterface.GetAllNetworkInterfaces();
            foreach (var adapter in adapters)
            {
                var ipProps = adapter.GetIPProperties();
                foreach (var ip in ipProps.UnicastAddresses)
                {
                    if ((adapter.OperationalStatus == OperationalStatus.Up)
                        && (ip.Address.AddressFamily == AddressFamily.InterNetwork))
                    {
                        if (ip.Address.ToString() == args[0])
                        Console.Out.WriteLine(adapter.Name);
                    }
                }
            }
        }
    }
}
1
Thomas Weller

Windows 10 Powershellでは、これは次のようにして実現できます。

_Get-NetIPAddress -IPAddress '192.168.2.4' | %{$_.InterfaceAlias};
_

これにより、_Wi-Fi_などの結果が得られます。

他のオブジェクトプロパティの代わりにInterfaceAliasを使用できます。

すべてのプロパティを取得するには、パイプを省略して、_Get-NetIPAddress -IPAddress '192.168.2.4'_を実行します。

その他のネットワークアダプター関連のプロパティ（説明など）は通常、InterfaceAliasまたはInterfaceIndexに基づいて照会できます。例：

_Get-NetAdapter -InterfaceAlias Wi-Fi | %{$_.InterfaceDescription};
_

これはIntel(R) Dual Band Wireless-AC 8265のようなものになります。

ドキュメントの詳細をご覧ください： https://docs.Microsoft.com/en-us/powershell/module/nettcpip/get-netipaddress?view=win10-ps

0
MrMeszaros