web-dev-qa-db-ja.com

Windowsで壊れたシンボリックリンクを自動的に見つけるにはどうすればよいですか？

これが悪いスタイルかどうかはわかりませんが、他の場所で答えが見つからなかったので、ここでこの質問をして、自分で1つの解決策を考え出しました。他の人の解決策を見てみたいと思いますが、数日後に自分の解決策を投稿します。

私の特定のケースでは、私はWindows 7で実行していますが、他のバージョンまたは古いバージョンのWindowsの回答に興味があります。 1つの答えは「Unix検索のバージョンをインストールしてから NIXの場合は解決 」であることに気づきましたが、より「ネイティブな」ソリューションが必要でした。

EDIT 2012-07-17：明確化：「自動で」理想的には、GUIツールではなく、スクリプトの一部として実行できるものを意味します。私はこれを無人で行いたいので、ボタンを押すだけですべての作業を行います。

windowssymbolic-link
11
HughG

多少遅れますが、これが私の質問に対する私自身の回答です。これは基本的にUnixでの通常のアプローチと同じです。すべてのリンクを見つけて、壊れたリンクを処理します。それほど簡潔ではありません。以下のスクリプトは、壊れたシンボリックリンクについて、それらに関する情報をダンプした後に削除します。

@echo off

rem Grab the list of directories to scan, before we "pushd to dir containing this script",
rem so that we can have the default be "dir from which we ran this script".
setlocal
if x%CD%==x (echo Command Extensions must be enabled. && goto :eof)
set ORIGINAL_DIR=%CD%

pushd %~dp0

set DIRS_TO_CHECK=%*
if x%DIRS_TO_CHECK%==x (
    set DIRS_TO_CHECK=.
)

rem Find all the files which are both links (/al) and directories (/ad).
rem (We use "delims=" in case any paths have a space; space is a delim by default.)
rem If not, delete it (and assume something else will fix it later :-).
echo Deleting broken symlinks ...
echo.
for %%D in (%ORIGINAL_DIR%\%DIRS_TO_CHECK%) do (
    echo Checking %%D
    echo.
    pushd %%D
    if errorlevel 1 (
        echo Cannot find "%%D"
        echo.
        goto :Next_Dir
    )
    rem Clean up broken directory links.
    for /f "usebackq delims=" %%L in (`dir /adl /b`) do (
        rem Check the directory link works.
        rem Redirecting to nul just to hide "The system cannot find the file specified." message.
        pushd "%%L" >nul 2>&1
        if errorlevel 1 (
            echo Deleting broken directory symlink "%%L".
            rem First dump out some info on the link, before we delete it.
            rem I'd rather a more human-readable form, but don't know how to get that.
            fsutil reparsepoint query "%%L"
            rmdir "%%L"
            echo.
        ) else (
            popd
        )
    )
    rem Clean up broken file (non-directory) links.
    for /f "usebackq delims=" %%L in (`dir /a-dl /b`) do (
        rem Check the file link works.
        rem Redirecting to nul just to hide "The system cannot find the file specified." message.
        copy "%%L" nul >nul 2>&1
        if errorlevel 1 (
            echo Deleting broken file symlink "%%L".
            rem First dump out some info on the link, before we delete it.
            rem I'd rather a more human-readable form, but don't know how to get that.
            fsutil reparsepoint query "%%L"
            rm "%%L"
            echo.
        ) else (
            popd
        )
    )
    popd
    :Next_Dir
    rem Putting a label on the line immediately before a ')' causes a batch file parse error, hence this comment.
)
echo Deleting broken symlinks ... done.

:Finally
popd
4
HughG

以下のツールは、Windowsでシンボリックリンクを見つけて削除するのに役立ちます

  1. ジャンクションリンクマジック
  2. Diskjunction
3
Abhijeet Kasurde

SageLinks という名前のオープンソースユーティリティを試すこともできます。これは、Windows NTFSジャンクション、シンボリックリンク、さらにはショートカットを表示およびチェックします。

2
Nikolay Raspopov

Cygwin64（find、xargs、sh、ls）を使用（win7でNTFSのハードリンクが停止している場合のテスト）

c:\>   find ./ -type l |  xargs -I % sh -c "ls % > /dev/null 2>&1 || echo %"

注：test -eは、デッドntfsハードリンクでは期待どおりに機能しません。

0
mosh