web-dev-qa-db-ja.com

Windowsに更新プログラムの確認を強制するにはどうすればよいですか。

Windowsを新規インストールした後（XPまたは7）、どうすればWindowsの更新プログラムを "強制"できますか？

1週間後に「古い」Windowsの更新をしたくない場合は、「1ステップ」で実行できますか。 Windowsに更新プログラムのチェックを強制する "魔法の"コマンドはありますか。存在する場合はそれらをインストールしますか？

windowswindows-update
25
LanceBaynes

スクリプトを使用してアップデートを自動的に確認してインストールできます。これはXPまたはWindows 7で動作します。

ダウンロード可能なスクリプトがいくつかあります。 これが私のものです 。

' Written in 2007 by Harry Johnston, University of Waikato, New Zealand.
' This code has been placed in the public domain.  It may be freely
' used, modified, and distributed.  However it is provided with no
' warranty, either express or implied.
'
' Exit Codes:
'   0 = scripting failure
'   1 = error obtaining or installing updates
'   2 = installation successful, no further updates to install
'   3 = reboot needed; rerun script after reboot
'
' Note that exit code 0 has to indicate failure because that is what
' is returned if a scripting error is raised.
'

Set updateSession = CreateObject("Microsoft.Update.Session")

Set updateSearcher = updateSession.CreateUpdateSearcher()
Set updateDownloader = updateSession.CreateUpdateDownloader()
Set updateInstaller = updateSession.CreateUpdateInstaller()

Do

  WScript.Echo
  WScript.Echo "Searching for approved updates ..."
  WScript.Echo

  Set updateSearch = updateSearcher.Search("IsInstalled=0")

  If updateSearch.ResultCode <> 2 Then

    WScript.Echo "Search failed with result code", updateSearch.ResultCode
    WScript.Quit 1

  End If

  If updateSearch.Updates.Count = 0 Then

    WScript.Echo "There are no updates to install."
    WScript.Quit 2

  End If

  Set updateList = updateSearch.Updates

  For I = 0 to updateSearch.Updates.Count - 1

    Set update = updateList.Item(I)

    WScript.Echo "Update found:", update.Title

  Next

  WScript.Echo

  updateDownloader.Updates = updateList
  updateDownloader.Priority = 3

  Set downloadResult = updateDownloader.Download()

  If downloadResult.ResultCode <> 2 Then

    WScript.Echo "Download failed with result code", downloadResult.ResultCode
    WScript.Echo

    WScript.Quit 1

  End If

  WScript.Echo "Download complete.  Installing updates ..."
  WScript.Echo

  updateInstaller.Updates = updateList

  Set installationResult = updateInstaller.Install()

  If installationResult.ResultCode <> 2 Then

    WScript.Echo "Installation failed with result code", installationResult.ResultCode

    For I = 0 to updateList.Count - 1

      Set updateInstallationResult = installationResult.GetUpdateResult(I)
      WScript.Echo "Result for " & updateList.Item(I).Title & " is " & installationResult.GetUpdateResult(I).ResultCode

    Next

    WScript.Quit 1

  End If

  If installationResult.RebootRequired Then

    WScript.Echo "The system must be rebooted to complete installation."

    WScript.Quit 3

  End If

  WScript.Echo "Installation complete."

Loop

このようにコマンドラインからこれを実行します。

cscript wsusupdate.vbs

私のスクリプトは最低限の機能しか持っていませんが、それでも役に立つかもしれません。他にも多くの機能を備えたスクリプトがあります。Google検索を試してください。

12
Harry Johnston

Windows Updateを使用する通常の方法以外に、コマンドラインからチェックを強制することができます。

管理者コマンドプロンプトを開き、次のコマンドを実行します。

C:\> %windir%\system32\wuauclt.exe /detectnow

Wuauclt.exeは、Windows Updateの自動更新クライアントで、Microsoft Updateから入手可能な更新プログラム（さまざまなバージョンのMS Windowsプラットフォーム用）を確認するために使用されます。

これでインストールは強制されません。

40
Ƭᴇcʜιᴇ007

更新を確認するには、[コントロールパネル]、[セキュリティ]、[Windows Update]の順に選択し、[更新を確認]をクリックします。

enter image description here

5
surfasb

更新プログラムを強制的に再スキャンするもう1つの方法は、％windir％\ Windows\SoftwareDistribution\Downloadに保存されているすべての更新プログラムを削除して、スレートをきれいに拭くことです。

    NET STOP wuauserv
    RD /S /Q %windir%\SoftwareDistribution\Download
    NET START wuauserv

次に、Windows Updateに進み、「更新プログラムの確認」に進みます。システムボリューム上のすべての更新可能ファイルがチェックされるため、1時間かかることがあります（それ以降の "更新のチェック"は高速になります）。この方法では、少なくともMSが認識する限り、エラー、更新の煩雑さを排除し、クリーンで最新のシステムを実現できます。

2
rajah

私は新鮮なウィンドウズのインストールを更新するために wuinstall と呼ばれる第二者のツールを使っています。これにより、自動再起動を含む更新プロセス全体を自動化できます。私はそれがユーザーの参加なしで最新の新鮮な窓を手に入れるための最も速い方法の1つであると思います。

1
hansi

Windows 7への新規インストールの一環として、IEをアップグレードしたか、まだ[IE]を実行していないにもかかわらず最初の質問に回答していない場合エラーを出します。また、GUIを介さずにWindows UpdateをMicrosoft Updateに切り替える方法がないため、手動でIEを起動し、初期化してからGUIを介してWindows Updateをセットアップするので、Microsoft Updateに切り替えて回避することができます。初期エラーあなたのマイレージは異なる場合があります。

0
Kent

この ポスト の手順に従って、 IE8 ＆をインストールすることで、成功しました。 WI4.5 、ダウンロードを開始するための自動アップデートを開始します。

0
checksum