Windowsバッチスクリプトで日付と時刻をフォーマットする
Windows（Windows XP）バッチスクリプトでは、後でファイル名などに使用するために現在の日付と時刻をフォーマットする必要があります。
Stack Overflow questionバッチファイルに日付を追加する方法と似ていますが、同様に。
私はこれをこれまで持っています：
echo %DATE%
echo %TIME%
set datetimef=%date:~-4%_%date:~3,2%_%date:~0,2%__%time:~0,2%_%time:~3,2%_%time:~6,2%
echo %datetimef%
これは、
28/07/2009
8:35:31.01
2009_07_28__ 8_36_01
％TIME％で1桁の時間を許可する方法はありますか？その場合、次のようになります。
2009_07_28__08_36_01
私はこのスクリプトで終わった：
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set hour=0%hour:~1,1%
echo hour=%hour%
set min=%time:~3,2%
if "%min:~0,1%" == " " set min=0%min:~1,1%
echo min=%min%
set secs=%time:~6,2%
if "%secs:~0,1%" == " " set secs=0%secs:~1,1%
echo secs=%secs%
set year=%date:~-4%
echo year=%year%
:: WIN2008R2について私はあなたの 'set month =％date：〜3,2％'を以下のようにする必要がありました：そうでなければ00がMONTHに現れます
set month=%date:~4,2%
if "%month:~0,1%" == " " set month=0%month:~1,1%
echo month=%month%
set day=%date:~0,2%
if "%day:~0,1%" == " " set day=0%day:~1,1%
echo day=%day%
set datetimef=%year%%month%%day%_%hour%%min%%secs%
echo datetimef=%datetimef%
@ECHO OFF
: Sets the proper date and time stamp with 24Hr Time for log file naming
: convention
SET HOUR=%time:~0,2%
SET dtStamp9=%date:~-4%%date:~4,2%%date:~7,2%_0%time:~1,1%%time:~3,2%%time:~6,2%
SET dtStamp24=%date:~-4%%date:~4,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%
if "%HOUR:~0,1%" == " " (SET dtStamp=%dtStamp9%) else (SET dtStamp=%dtStamp24%)
ECHO %dtStamp%
PAUSE
ログファイル名を生成する方法は次のとおりです（ http://ss64.com/nt/syntax-getdate.html に基づく）。
@ECHO OFF
:: Check WMIC is available
WMIC.EXE Alias /? >NUL 2>&1 || GOTO s_error
:: Use WMIC to retrieve date and time
FOR /F "skip=1 tokens=1-6" %%G IN ('WMIC Path Win32_LocalTime Get Day^,Hour^,Minute^,Month^,Second^,Year /Format:table') DO (
IF "%%~L"=="" goto s_done
Set _yyyy=%%L
Set _mm=00%%J
Set _dd=00%%G
Set _hour=00%%H
SET _minute=00%%I
SET _second=00%%K
)
:s_done
:: Pad digits with leading zeros
Set _mm=%_mm:~-2%
Set _dd=%_dd:~-2%
Set _hour=%_hour:~-2%
Set _minute=%_minute:~-2%
Set _second=%_second:~-2%
Set logtimestamp=%_yyyy%-%_mm%-%_dd%_%_hour%_%_minute%_%_second%
goto make_dump
:s_error
echo WMIC is not available, using default log filename
Set logtimestamp=_
:make_dump
set FILENAME=database_dump_%logtimestamp%.sql
...
PowerShellがインストールされている場合は、好きな形式で日付と時刻を簡単かつ確実に取得できます。次に例を示します。
for /f %%a in ('powershell -Command "Get-Date -format yyyy_MM_dd__HH_mm_ss"') do set datetime=%%a
move "%oldfile%" "backup-%datetime%"
もちろん、今日ではPowerShellは常にインストールされていますが、Windows XPでは、PSが利用可能であることがわかっている既知の環境でバッチスクリプトを使用している場合にのみ使用します。 PowerShellが利用できる場合はバッチファイル...）
あなたは合理的に尋ねることができます：あなたが日付/時刻を得るためにPowerShellを使うことができるならなぜバッチファイルを使うのか、なぜか私は明白な理由があると思います。バッチファイルでは昔ながらのやり方なのか、（b）古いスクリプトを更新していて、全部をPSに移植したくないのか。
私は通常、日付/時刻文字列が必要なときはいつでもこのようにします。
set dt=%DATE:~6,4%_%DATE:~3,2%_%DATE:~0,2%__%TIME:~0,2%_%TIME:~3,2%_%TIME:~6,2%
set dt=%dt: =0%
これはドイツの日付/時刻形式（dd.mm.yyyy hh：mm：ss）用です。基本的に私は部分文字列を連結し、最後にすべてのスペースをゼロに置き換えます。
部分文字列の仕組みの簡単な説明
%VARIABLE:~num_chars_to_skip,num_chars_to_keep%
そのため、 "29.03.2018"のような日付からちょうど1年を取得するには、次のようにします。
%DATE:~6,4%
^-----skip 6 characters
^---keep 4 characters
私は今日この問題に遭遇し、それを使ってそれを解決しました：
SET LOGTIME=%TIME: =0%
スペースを0に置き換え、基本的にその時間をゼロで埋めます。
ちょっとした検索の後、コマンド拡張が必要かどうかわかりませんでした（まだSETLOCAL DISABLEEXTENSIONSで動作しました）。
すでに述べたように、日付と時刻の解析は、現在のユーザーが使用している形式を知っている場合にのみ役に立ちます（たとえば、2つの名前を付けるにはMM/dd/yyまたはdd-MM-yyyy）。これは決まっているかもしれませんが、あなたがすべてのストレスとパースをする時までに、あなたはまだ予期しないフォーマットが使われているいくつかの状況で終わるでしょう、そしてもっと微調整が必要になるでしょう。
日付スラッグを好みの形式で返す外部プログラムを使用することもできますが、ユーティリティプログラムをスクリプト/バッチと一緒に配布する必要があるという欠点があります。
CMOSクロックを生のままで使用するバッチトリックもありますが、これはほとんどの人にとって裸線には近すぎ、また日付/時刻を取得するのに適した場所とは限りません。
以下は上記の問題を回避する解決策です。はい、それは他のいくつかの問題を紹介します、しかし私の目的のために私はこれが現代のWindowsシステムのための.batファイルに日付スタンプを作成するための最も簡単で最も明快で最もポータブルな解決策であると思いました。これはほんの一例ですが、他の日付や時刻のフォーマットなどに変更する方法がわかるでしょう。
reg copy "HKCU\Control Panel\International" "HKCU\Control Panel\International-Temp" /f
reg add "HKCU\Control Panel\International" /v sShortDate /d "yyMMdd" /f
@REM reg query "HKCU\Control Panel\International" /v sShortDate
set LogDate=%date%
reg copy "HKCU\Control Panel\International-Temp" "HKCU\Control Panel\International" /f
次は直接的な答えではなく、近い答えかもしれません。
set hour=%time:~0,2%
if "%hour:~0,1%" == " " set datetimef=%date:~-4%_%date:~3,2%_%date:~0,2%__0%time:~1,2%_%time:~3,2%_%time:~6,2%
else set datetimef=%date:~-4%_%date:~3,2%_%date:~0,2%__%time:~0,2%_%time:~3,2%_%time:~6,2%
少なくともそれは刺激的かもしれません。
あなたがこのフォーマットを正確に必要としないならば：
2009_07_28__08_36_01
次に、％date％と％time％を使用する次の3行のコードを使用できます。
set mydate=%date:/=%
set mytime=%time::=%
set mytimestamp=%mydate: =_%_%mytime:.=_%
注：文字/と:は削除され、文字.とスペースはアンダースコアに置き換えられます。
出力例（水曜日の8/5/15 12:49 PM、50秒、93ミリ秒）
echo %mytimestamp%
Wed_08052015_124950_93
REM Assumes UK style date format for date environment variable (DD/MM/YYYY).
REM Assumes times before 10:00:00 (10am) displayed padded with a space instead of a zero.
REM If first character of time is a space (less than 1) then set DATETIME to:
REM YYYY-MM-DD-0h-mm-ss
REM Otherwise, set DATETIME to:
REM YYYY-MM-DD-HH-mm-ss
REM Year, month, day format provides better filename sorting (otherwise, days grouped
REM together when sorted alphabetically).
IF "%time:~0,1%" LSS "1" (
SET DATETIME=%date:~6,4%-%date:~3,2%-%date:~0,2%-0%time:~1,1%-%time:~3,2%-%time:~6,2%
) ELSE (
SET DATETIME=%date:~6,4%-%date:~3,2%-%date:~0,2%-%time:~0,2%-%time:~3,2%-%time:~6,2%
)
ECHO %DATETIME%
WindowsのSETコマンドでサポートされているoffset:lengthフォーマットでは、興味のあるように0を埋め込むことはできません。
ただし、BATCHスクリプトをコーディングして、時間が10以下であることを確認することができます。
それに応じて別のecho文字列を埋め込みます。
このリンク上のSETコマンドに関する 情報がいくつかあります 。
ここに来るために他のプログラミング方法に変更することもできます。
UNIX bash（Windows上のCygwinで利用可能）では、次のように言うだけです。
date +%Y_%m_%d__%H_%M_%S
そして、それは常に正しくパッドを入れます。
私はこうやった：
REM Generate FileName from date and time in format YYYYMMTTHHMM
Time /T > Time.dat
set /P ftime= < Time.dat
set FileName=LogFile%date:~6%%date:~3,2%%date:~0,2%%ftime:~0,2%%ftime:~3,2%.log
echo %FileName%
LogFile201310170928.log
::========================================================================
::== CREATE UNIQUE DATETIME STRING IN FORMAT YYYYMMDD-HHMMSS
::======= ================================================================
FOR /f %%a IN ('WMIC OS GET LocalDateTime ^| FIND "."') DO SET DTS=%%a
SET DATETIME=%DTS:~0,8%-%DTS:~8,6%
最初の行は常にタイムゾーンに関してこのフォーマットで出力されます。
20150515150941.077000 + 120
これはあなたの望みに合うように出力をフォーマットすることだけをあなたに残します。
私は本当にバッチファイルに慣れていない、これは私のコードです！ （なぜかわかりませんが、date/tとtime/tを組み合わせることができず、できませんでした。 ％date％および％time％を変数なしで直接使用する...）
@ECHO OFF
set ldt=%date% %time%
echo %ldt%>> logs.txt
EXIT
それは他人から再利用されたようなものです（問題はファイル名として使用するためにフォーマットされた日付を取得することでした）。
YYYY-MM-DD hh:mm:ss（24時間）タイムスタンプを生成するには、次のようにします。
SET CURRENTTIME=%TIME%
IF "%CURRENTTIME:~0,1%"==" " (SET CURRENTTIME=0%CURRENTTIME:~1%)
FOR /F "tokens=2-4 delims=/ " %%A IN ('DATE /T') DO (SET TIMESTAMP=%%C-%%A-%%B %CURRENTTIME%)
もう1つ簡単な方法があります。
set HH=%time:~0,2%
if %HH% LEQ 9 (
set HH=%time:~1,1%
)
set hourstr = %time:~0,2%
if "%time:~0,1%"==" " (set hourstr=0%time:~1,1%)
set datetimestr=%date:~0,4%%date:~5,2%%date:~8,2%-%hourstr%%time:~3,2%%time:~6,2%
このバッチスクリプトは、O.P。が望んでいることを正確に実行します（Windows XP SP3でテスト済み）。
また、以前に「jph」で説明した巧妙なレジストリトリックを使用しました。これは、新しいまたは古いWindowsシステムで"yyyy_MM_dd"に日付を100％一貫してフォーマットする最も簡単な方法です。これを行うための1つのレジストリ値への変更は、一時的な一時的なものです。すぐに元に戻るまでに数ミリ秒しか続きません。
このバッチファイルをダブルクリックすると、インスタントデモが表示され、コマンドプロンプトウィンドウがポップアップしてタイムスタンプが表示されます。 。 。 。 。
@ECHO OFF
SETLOCAL & MODE CON:COLS=80 LINES=15 & COLOR 0A
TITLE GENERATE A CUSTOM FORMATTED TIMESTAMP USING %%DATE%% AND %%TIME%% COMMANDS
:: --- CHANGE THE COMPUTER DATE FORMAT TEMPORARILY TO MY PREFERENCE "yyyy_MM_dd",
REG COPY "HKCU\Control Panel\International" "HKCU\Control Panel\International-Temp" /f 2>nul >nul
REG ADD "HKCU\Control Panel\International" /v sShortDate /d "yyyy_MM_dd" /f 2>nul >nul
SET MYDATE=%date%
:: --- REVERT COMPUTER DATE BACK TO SYSTEM PREFERENCE
REG COPY "HKCU\Control Panel\International-Temp" "HKCU\Control Panel\International" /f 2>nul >nul
REG DELETE "HKCU\Control Panel\International-Temp" /f 2>nul >nul
:: --- SPLIT THE TIME DIGITS TO THREE BLOCKS [H] [MM] [SS.SS]
FOR /F "tokens=1-3 delims=:" %%A IN ('echo %time%') DO SET HOUR=%%A& SET MINUTES=%%B& SET SECONDS=%%C
:: --- YOUR CHOICE - FOR 4 DIGIT SECONDS - REMOVES THE DOT FROM THE SECONDS BLOCK [SS.SS]
:: SET SECONDS=%SECONDS:.=%
:: --- YOUR CHOICE - FOR 2 DIGIT SECONDS - GETS THE FIRST TWO DIGITS FROM THE SECONDS BLOCK [SS.SS]
SET SECONDS=%SECONDS:~0,2%
:: --- GET THE "AM PM" STRING TO CHECK THE HOUR BLOCK
FOR /F "tokens=1,2 delims= " %%A IN ('time /t') DO SET AM_PM=%%B
:: --- CONVERT THE HOUR BLOCK [H] TO "24 HOUR" FORMAT [HH]
IF %AM_PM%==PM (
IF %HOUR%==01 (SET HOUR=13)
IF %HOUR%==02 (SET HOUR=14)
IF %HOUR%==03 (SET HOUR=15)
IF %HOUR%==04 (SET HOUR=16)
IF %HOUR%==05 (SET HOUR=17)
IF %HOUR%==06 (SET HOUR=18)
IF %HOUR%==07 (SET HOUR=19)
IF %HOUR%==08 (SET HOUR=20)
IF %HOUR%==09 (SET HOUR=21)
IF %HOUR%==10 (SET HOUR=22)
IF %HOUR%==11 (SET HOUR=23)
) ELSE (
IF %HOUR%==12 (SET HOUR=00)
IF %HOUR%==1 (SET HOUR=01)
IF %HOUR%==2 (SET HOUR=02)
IF %HOUR%==3 (SET HOUR=03)
IF %HOUR%==4 (SET HOUR=04)
IF %HOUR%==5 (SET HOUR=05)
IF %HOUR%==6 (SET HOUR=06)
IF %HOUR%==7 (SET HOUR=07)
IF %HOUR%==8 (SET HOUR=08)
IF %HOUR%==9 (SET HOUR=09)
)
:: --- GENERATE OUR WANTED TIMESTAMP
ECHO. & ECHO.
SET TIMESTAMP=%MYDATE%__%HOUR%_%MINUTES%_%SECONDS%
ECHO Your timestamp is: %TIMESTAMP%
:: --- WAIT - VIEW THE RESULT IN THE CONSOLE SCREEN
ECHO. & ECHO.
ECHO Job is done. Press any key to exit . . .
PAUSE > NUL
EXIT
このbatファイル（datetimestr.batとして保存）は、（1）曜日と曜日を含む長い日時文字列、（2）それらを含まない短い日時文字列、（3）コードの短いバージョンの3つの日時文字列を生成します。
@echo off
REM "%date: =0%" replaces spaces with zeros
set d=%date: =0%
REM "set yyyy=%d:~-4%" pulls the last 4 characters
set yyyy=%d:~-4%
set mm=%d:~4,2%
set dd=%d:~7,2%
set dow=%d:~0,3%
set d=%yyyy%-%mm%-%dd%_%dow%
set t=%TIME: =0%
REM "%t::=%" removes semi-colons
REM Instead of above, you could use "%t::=-%" to
REM replace semi-colons with hyphens (or any
REM non-special character)
set t=%t::=%
set t=%t:.=%
set datetimestr=%d%_%t%
@echo Long date time str = %datetimestr%
set d=%d:~0,10%
set t=%t:~0,4%
set datetimestr=%d%_%t%
@echo Short date time str = %datetimestr%
@REM Short version of the code above
set d=%date: =0%
set t=%TIME: =0%
set datetimestr=%d:~-4%-%d:~4,2%-%d:~7,2%_%d:~0,3%_%t:~0,2%%t:~3,2%%t:~6,2%%t:~9,2%
@echo Datetimestr = %datetimestr%
pause
適切な称号を与えるために、私はPeter Mortensen（14年6月18日21時02分）とopello（8月25日11時14分27秒）の概念をマージしました。
これをもっと短く書くことができますが、この長いバージョンはコードの読みと理解を容易にします。
"search_files.bat"という名前のファイルを作成し、以下の内容をファイルに配置します。それをダブルクリックしてください。 AMを適切に処理するために、一時的な％THH％変数が配置されました。時間の最初の2桁に0がある場合、WindowsはLOGファイルのファイル名の残りを無視します。
CD .
SET THH=%time:~0,2%
SET THH=%THH: =0%
dir /s /b *.* > %date:~10,4%-%date:~4,2%-%date:~7,2%@%THH%.%time:~3,2%.%time:~6,2%.LOG
私は@The loraxの上の短い版が好きです、しかし他の言語設定のためにそれはわずかに異なるかもしれません。
たとえば、ドイツ語の設定（自然な日付形式：dd.mm.yyyy）では、月のクエリを4,2から3,2に変更する必要があります。
@ECHO OFF
: Sets the proper date and time stamp with 24h time for log file naming convention i.e.
SET HOUR=%time:~0,2%
SET dtStamp9=%date:~-4%%date:~3,2%%date:~7,2%_0%time:~1,1%%time:~3,2%%time:~6,2%
SET dtStamp24=%date:~-4%%date:~3,2%%date:~7,2%_%time:~0,2%%time:~3,2%%time:~6,2%
if "%HOUR:~0,1%" == " " (SET dtStamp=%dtStamp9%) else (SET dtStamp=%dtStamp24%)
ECHO %dtStamp%
: Outputs= 20160727_081040
: (format: YYYYMMDD_HHmmss; e.g.: the date-output of this post timestamp)
PAUSE
このような状況では、単純で標準的なプログラミングアプローチを使用します。未知のエンティティを解析するために多大な労力を費やす代わりに、現在の設定を保存し、既知の状態にリセットし、情報を抽出して元の状態に戻します。標準のWindowsリソースのみを使用してください。
具体的には、日付と時刻の形式は、レジストリキーHKCU\Control Panel\International \の[MS definition] "values"： "sTimeFormat"および "sShortDate"に格納されています。 Regは、すべてのWindowsバージョンに含まれているコンソールレジストリエディタです。 HKCUキーを変更するために高い特権は必要ありません
Prompt $N:$D $T$G
::Save current config to a temporary (unique name) subkey, Exit if copy fails
Set DateTime=
Set ran=%Random%
Reg copy "HKCU\Control Panel\International" "HKCU\Control Panel\International-Temp%ran%" /f
If ErrorLevel 1 GoTO :EOF
::Reset the date format to your desired output format (take effect immediately)
::Resetting the time format is useless as it only affect subsequent console windows
::Reg add "HKCU\Control Panel\International" /v sTimeFormat /d "HH_mm_ss" /f
Reg add "HKCU\Control Panel\International" /v sShortDate /d "yyyy_MM_dd" /f
::Concatenate the time and (reformatted) date strings, replace any embedded blanks with zeros
Set DateTime=%date%__%time:~0,2%_%time:~3,2%_%time:~6,2%
Set DateTime=%DateTime: =0%
::Restore the original config and delete the temp subkey, Exit if restore fails
Reg copy "HKCU\Control Panel\International-Temp%ran%" "HKCU\Control Panel\International" /f
If ErrorLevel 1 GoTO :EOF
Reg delete "HKCU\Control Panel\International-Temp%ran%" /f
シンプルでわかりやすく、すべての地域で機能するはずです。
わかりませんが、コンソールウィンドウで "sShortDate"値をリセットしてもすぐに有効になりますが、非常によく似た "sTimeFormat"値をリセットしてもNOT新しいコンソールウィンドウが開くまで有効になります。ただし、変更可能な唯一のものは区切り文字です - ディジット位置は固定されています。同様に "HH"タイムトークンは先行ゼロを付加することになっていますが、そうではありません。幸いなことに、回避策は簡単です。
私は受け入れられた答えを試みました、そしてそれはかなりうまくいきます。残念ながら、米国の時刻形式はH：MM：SS.CSであるように見えます。そして、正面に0が欠けていると、午前10時前に解析問題が発生していました。このハードルを乗り越え、世界のほとんどの時間フォーマットの解析を可能にするために、私はこの単純なルーチンを思いついた。
:ParseTime
rem The format of %%TIME%% is H:MM:SS.CS or (HH:MM:SS,CS) for example 0:01:23.45 or 23:59:59,99
FOR /F "tokens=1,2,3,4 delims=:.," %%a IN ("%1") DO SET /A "%2=(%%a * 360000) + (%%b * 6000) + (%%c * 100) + %%d"
GOTO :EOF
このルーチンのいいところは、時間文字列を最初のパラメータとして渡し、時間を含める環境変数の名前を2番目のパラメータとして渡すことです。例えば：
CALL :ParseTime %START_TIME% START_CS
CALL :ParseTime %TIME% END_CS
SET /A DURATION=%END_CS% - %START_CS%
（*クリス*）
多分このようなもの：
@call:DateTime
@for %%? in (
"Year :Y"
"Month :M"
"Day :D"
"Hour :H"
"Minutes:I"
"Seconds:S"
) do @for /f "tokens=1-2 delims=:" %%# in (%%?) do @for /f "delims=" %%_ in ('echo %%_DT_%%$_%%') do @echo %%# : _DT_%%$_ : %%_
:: OUTPUT
:: Year : _DT_Y_ : 2014
:: Month : _DT_M_ : 12
:: Day : _DT_D_ : 17
:: Hour : _DT_H_ : 09
:: Minutes : _DT_I_ : 04
:: Seconds : _DT_S_ : 35
@pause>nul
@goto:eof
:DateTime
@verify errorlevel 2>nul & @wmics Alias /? >nul 2>&1
@if not errorlevel 1 (
@for /f "skip=1 tokens=1-6" %%a in ('wmic path win32_localtime get day^,hour^,minute^,month^,second^,year /format:table') do @if not "%%f"=="" ( set "_DT_D_=%%a" & set "_DT_H_=%%b" & set "_DT_I_=%%c" & set "_DT_M_=%%d" & set "_DT_S_=%%e" & set "_DT_Y_=%%f" )
) else (
@set "_DT_T_=1234567890 "
)
@if errorlevel 1 (
@for %%? in ("iDate" "sDate" "iTime" "sTime" "F" "Y" "M" "D" "H" "I" "S") do @set "_DT_%%~?_=%%~?"
@for %%? in ("Date" "Time") do @for /f "skip=2 tokens=1,3" %%a in ('reg query "HKCU\Control Panel\International" /v ?%%~? 2^>nul') do @for /f %%x in ('echo:%%_DT_%%a_%%') do @if "%%x"=="%%a" set "_DT_%%a_=%%b"
@for /f "tokens=1-3 delims=%_DT_T_%" %%a in ("%time%") do @set "_DT_T_=%%a%%b%%c"
)
@if errorlevel 1 (
@if "%_DT_iDate_%"=="0" (set "_DT_F_=_DT_D_ _DT_Y_ _DT_M_") else if "%_DT_iDate_%"=="1" (set "_DT_F_=_DT_D_ _DT_M_ _DT_Y_") else if "%_DT_iDate_%"=="2" (set "_DT_F_=_DT_Y_ _DT_M_ _DT_D_")
@for /f "tokens=1-4* delims=%_DT_sDate_%" %%a in ('date/t') do @for /f "tokens=1-3" %%x in ('echo:%%_DT_F_%%') do @set "%%x=%%a" & set "%%y=%%b" & set "%%z=%%c"
@for /f "tokens=1-3 delims=%_DT_T_%" %%a in ("%time%") do @set "_DT_H_=%%a" & set "_DT_I_=%%b" & set "_DT_S_=%%c"
@for %%? in ("iDate" "sDate" "iTime" "sTime" "F" "T") do @set "_DT_%%~?_="
)
@for %%i in ("Y" ) do @for /f %%j in ('echo:"%%_DT_%%~i_%%"') do @set /a _DT_%%~i_+= 0 & @for /f %%k in ('echo:"%%_DT_%%~i_:~-4%%"') do @set "_DT_%%~i_=%%~k"
@for %%i in ("M" "D" "H" "I" "S") do @for /f %%j in ('echo:"%%_DT_%%~i_%%"') do @set /a _DT_%%~i_+=100 & @for /f %%k in ('echo:"%%_DT_%%~i_:~-2%%"') do @set "_DT_%%~i_=%%~k"
@exit/b
これはadatetime stringに対する私の2セントです。 MM DD YYYYシステムでは、1番目と2番目の%DATE:~エントリを切り替えます。
REM ====================================================================================
REM CREATE UNIQUE DATETIME STRING FOR ADDING TO FILENAME
REM ====================================================================================
REM Can handle dd DDxMMxYYYY and DDxMMxYYYY > CREATES YYYYMMDDHHMMSS (x= any character)
REM ====================================================================================
REM CHECK for SHORTDATE dd DDxMMxYYYY
IF "%DATE:~0,1%" GTR "3" (
SET DATETIME=%DATE:~9,4%%DATE:~6,2%%DATE:~3,2%%TIME:~0,2%%TIME:~3,2%%TIME:~6,2%
) ELSE (
REM ASSUMES SHORTDATE DDxMMxYYYY
SET DATETIME=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%%TIME:~0,2%%TIME:~3,2%%TIME:~6,2%
)
REM CORRECT FOR HOURS BELOW 10
IF %DATETIME:~8,2% LSS 10 SET DATETIME=%DATETIME:~0,8%0%DATETIME:~9,5%
ECHO %DATETIME%
ファイル名で使用する数値日付の非常に簡単な解決策として、次のコードを使用してください。
set month=%date:~4,2%
set day=%date:~7,2%
set curTimestamp=%month%%day%%year%
rem then the you can add a prefix and a file extension easily like this
echo updates%curTimestamp%.txt
このスクリプトは、Windows XP Professional（Home Editionもサポートされていますが、このツールはデフォルトではインストールされていません）以来、Windowsの不可欠な部分であるWMICツールを介してプライマリにアクセスするWMIインタフェースを使用します。このスクリプトは、WMIインターフェイスにアクセスしてWMICツールが提供するのと同じ形式でコンソール出力に書き込むためのWSH vbscriptを作成して呼び出すことで、不足しているWMICツールの回避策も実装します。
@ECHO OFF
REM Returns: RETURN
REM Modify: RETURN, StdOut
REM Required - mandatory: none
REM Required - optionaly: format strings delimited by a space to format an output delimited by predefined delimiter
REM YYYY = 4-digit year
REM MM = 2-digit month
REM DD = 2-digit day
REM hh = 2-digit hour
REM mm = 2-digit minute
REM ss = 2-digit second
REM ms = 3-digit millisecond
CALL :getTime %*
ECHO %RETURN%
GOTO :EOF
REM SUBROUTINE
REM Returns: RETURN
REM Modify: RETURN
REM Required - mandatory: none
REM Required - optionaly: format strings delimited by a space to format an output delimited by predefined delimiter
REM YYYY = 4-digit year
REM MM = 2-digit month
REM DD = 2-digit day
REM hh = 2-digit hour
REM mm = 2-digit minute
REM ss = 2-digit second
REM ms = 3-digit millisecond
:getTime
SETLOCAL EnableDelayedExpansion
SET DELIM=-
WHERE /Q wmic.exe
IF NOT ERRORLEVEL 1 FOR /F "usebackq skip=1 tokens=*" %%x IN (`wmic.exe os get LocalDateTime`) DO (SET DT=%%x & GOTO getTime_Parse)
SET _TMP=%TEMP:"=%
ECHO Wscript.StdOut.WriteLine (GetObject("winmgmts:root\cimv2:Win32_OperatingSystem=@").LocalDateTime)>"%_TMP%\get_time_local-helper.vbs"
FOR /F "usebackq tokens=*" %%x IN (`cscript //B //NoLogo "%_TMP%\get_time_local-helper.vbs"`) DO (SET DT=%%x & GOTO getTime_Parse)
:getTime_Parse
SET _RET=
IF "%1" EQU "" (
SET _RET=%DT:~0,4%%DELIM%%DT:~4,2%%DELIM%%DT:~6,2%%DELIM%%DT:~8,2%%DELIM%%DT:~10,2%%DELIM%%DT:~12,2%%DELIM%%DT:~15,3%
) ELSE (
REM Not recognized format strings are ignored during parsing - no error is reported.
:getTime_ParseLoop
SET _VAL=
IF "%1" EQU "YYYY" SET _VAL=%DT:~0,4%
IF "%1" EQU "MM" SET _VAL=%DT:~4,2%
IF "%1" EQU "DD" SET _VAL=%DT:~6,2%
IF "%1" EQU "hh" SET _VAL=%DT:~8,2%
IF "%1" EQU "mm" SET _VAL=%DT:~10,2%
IF "%1" EQU "ss" SET _VAL=%DT:~12,2%
IF "%1" EQU "ms" SET _VAL=%DT:~15,3%
IF DEFINED _VAL (
IF DEFINED _RET (
SET _RET=!_RET!%DELIM%!_VAL!
) ELSE (
SET _RET=!_VAL!
)
)
SHIFT
IF "%1" NEQ "" GOTO getTime_ParseLoop
)
ENDLOCAL & SET RETURN=%_RET%
GOTO :EOF
:: =============================================================
:: Batch file to display Date and Time seprated by undescore.
:: =============================================================
:: Read the system date.
:: =============================================================
@SET MyDate=%DATE%
@SET MyDate=%MyDate:/=:%
@SET MyDate=%MyDate:-=:%
@SET MyDate=%MyDate: =:%
@SET MyDate=%MyDate:\=:%
@SET MyDate=%MyDate::=_%
:: =============================================================
:: Read the system time.
:: =============================================================
@SET MyTime=%TIME%
@SET MyTime=%MyTime: =0%
@SET MyTime=%MyTime:.=:%
@SET MyTime=%MyTime::=_%
:: =============================================================
:: Build the DateTime string.
:: =============================================================
@SET DateTime=%MyDate%_%MyTime%
:: =============================================================
:: Display the Date and Time as it is now.
:: =============================================================
@ECHO MyDate="%MyDate%" MyTime="%MyTime%" DateTime="%DateTime%"
:: =============================================================
:: Wait before close.
:: =============================================================
@PAUSE
:: =============================================================
％を使用すると、時間の値が7から9のときに16進数の操作エラーが発生します。これを避けるには、DelayedExpansionを使用し、！min：〜1！で時間値を取得します。
PowerShellがある場合の代替方法は、次のように呼び出すことです。
for /F "usebackq delims=Z" %%i IN (`powershell Get-Date -format u`) do (set server-time=%%i)
Dateコマンドの結果をスラッシュで分割してから、各トークンを適切な変数に移動できます。
FOR /F "tokens=1-3 delims=/" %%a IN ("%date:~4%") DO (
SET _Month=%%a
SET _Day=%%b
SET _Year=%%c
)
ECHO Month %_Month%
ECHO Day %_Day%
ECHO Year %_Year%
初期の変数展開を避けるための良い一行トリックはcmd /c echo ^%time^%を使うことです
cmd /c echo ^%time^% & dir /s somelongcommand & cmd /c echo ^%time^%
REGを使用して、batファイルに最も有用な値を保存/変更/復元します。これはwindows 7です。他のバージョンでは別のキー名が必要かもしれません。
reg save "HKEY_CURRENT_USER\Control Panel\International" _tmp.reg /y
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /d "yyyy-MM-dd" /f
set file=%DATE%-%TIME: =0%
reg restore "HKEY_CURRENT_USER\Control Panel\International" _tmp.reg
set file=%file::=-%
set file=%file:.=-%
set file